games-board/kaya/kaya-0.4.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-board/kaya/kaya-0.4.ebuild,v 1.3 2011/08/20 19:05:34 dilfridge Exp $

EAPI=3
USE_RUBY="ruby18"
CMAKE_IN_SOURCE_BUILD=1

# Could in principle also work with other ruby implementations,
# but kdebindings is ruby18-only atm...

inherit kde4-base ruby-ng

DESCRIPTION="Board game suite for KDE"
HOMEPAGE="http://pcapriotti.github.com/kaya/"
SRC_URI="http://cloud.github.com/downloads/pcapriotti/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

DEPEND=""
RDEPEND=""
ruby_add_rdepend "|| ( kde-base/kdebindings-ruby kde-base/korundum )"
ruby_add_rdepend "dev-ruby/builder"

pkg_setup() {
	ruby-ng_pkg_setup
	kde4-base_pkg_setup
}

src_unpack() {
	kde4-base_src_unpack

	cd "${WORKDIR}"
	mkdir all
	mv ${P} all/ || die "Could not move sources"
}

all_ruby_prepare() {
	kde4-base_src_prepare
}

all_ruby_configure() {
	CMAKE_USE_DIR=${S}
	kde4-base_src_configure
}

all_ruby_compile() {
	CMAKE_USE_DIR=${S}
	kde4-base_src_compile
}

all_ruby_install() {
	CMAKE_USE_DIR=${S}
	kde4-base_src_install
}

pkg_postinst() {
	kde4-base_pkg_postinst
	elog "To be able to use the kaya board game front-end, you need to install at least one"
	elog "of the following game engines: "
	elog "    games-board/gnuchess"
	elog "    games-board/gnushogi"
}