summaryrefslogtreecommitdiff
blob: 64089dc8a9b51a7ae5ce91384634cccc6cc70889 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=4
VALA_USE_DEPEND=vapigen

inherit autotools vala

DESCRIPTION="BAMF Application Matching Framework"
HOMEPAGE="https://launchpad.net/bamf"
SRC_URI="http://launchpad.net/${PN}/${PV%.*}/${PV}/+download/${P}.tar.gz"

LICENSE="GPL-3 LGPL-3"
SLOT="3"
KEYWORDS="~amd64 ~x86"
IUSE="+introspection"

RDEPEND="dev-libs/dbus-glib
	>=dev-libs/glib-2.30:2
	gnome-base/libgtop:2
	x11-libs/libX11
	x11-libs/gtk+:3
	x11-libs/libwnck:3"
DEPEND="${RDEPEND}
	$(vala_depend)
	virtual/pkgconfig"

src_prepare() {
	sed -i -e "s:-Wall -Werror::" configure.in || die
	eautoreconf

	vala_src_prepare
}

src_configure() {
	VALA_API_GEN="${VAPIGEN}" \
	econf \
		--with-gtk=3 \
		--disable-webapps \
		$(use_enable introspection)
}

src_install() {
	default
	find "${ED}" -name "*.la" -exec rm {} + || die
}