# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=4
inherit eutils webapp

DESCRIPTION="An open source Google Code clone"
HOMEPAGE="http://www.indefero.net/"
SRC_URI="http://projects.ceondo.com/p/${PN}/downloads/get/${P}.zip"

LICENSE="GPL-2"
KEYWORDS="~amd64 ~x86"
IUSE="doc"

DEPEND="app-arch/unzip"
RDEPEND="${DEPEND}
	dev-lang/php[gd]
	dev-php/pluf
	"
S="${WORKDIR}/${PN}"

src_prepare(){
	#Expect pluf to be installed in the normal location and adjust the index.php
	#to be where we want it.
	epatch "${FILESDIR}/${PN}-gentoo.diff"
	cp "${FILESDIR}/dbsetup.sh" src/ || die
	cp "${FILESDIR}/bootstrap.php" . || die
	mv www/* . || die
}

src_compile(){ :; }

src_install(){
	webapp_src_preinst
	rm COPYING INSTALL.mdtext release-script run-tests .gitignore \
		.gitattributes Makefile || die
	dodoc doc/* NEWS.mdtext AUTHORS CONTRIBUTE.mdtext
	rm -rf test doc NEWS.mdtext AUTHORS CONTRIBUTE.mdtext || die

	mv src/IDF/conf/idf.php-dist src/IDF/conf/idf.php || die
	mv src/IDF/conf/path.php-dist src/IDF/conf/path.php || die

	insinto "${MY_HTDOCSDIR}"
	doins -R .

	webapp_configfile "${MY_HTDOCSDIR}/src/IDF/conf/idf.php"
	webapp_postinst_txt en "${FILESDIR}/postinstall-en-${PV}.txt"
	webapp_src_install
}

pkg_postinst(){
	elog "The postinstall document contains all of the information"
	elog "needed to get ${PN} running."
	webapp_pkg_postinst
}