# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit kde subversion

ESVN_REPO_URI="svn://anonsvn.kde.org/home/kde/trunk/extragear/pim/kdebluetooth"
ESVN_STORE_DIR="${PORTAGE_ACTUAL_DISTDIR-${DISTDIR}}/svn-src/"

S=${WORKDIR}/${PN}

DESCRIPTION="KDE Bluetooth Framework"
HOMEPAGE="http://kde-bluetooth.sourceforge.net/"
LICENSE="GPL-2"

SLOT="0"

IUSE="xmms irmc"
KEYWORDS="-*"

DEPEND=">=dev-libs/openobex-1.1
        >=net-wireless/bluez-libs-2.15
        >=media-libs/libvorbis-1.0
        xmms? ( >=media-sound/xmms-1.2.10 )
        irmc? ( || ( >=kde-base/kitchensync-3.4_beta1 >=kde-base/kdepim-3.4_beta1 ) )"

RDEPEND="${DEPEND}
        || ( ( kde-base/kdialog kde-base/konqueror )  kde-base/kdebase )
        net-wireless/bluez-utils"

need-kde 3.4

src_unpack() {
	eerror ''
	eerror 'DISCLAIMER: This is a live ebuild. It might break your system.'
	eerror 'Press CTRL + C now or remain silent forever!'
	eerror ''
	ewarn ''
	ewarn 'If you spot any mistake in this ebuild, notify deathwing00.'
	ewarn ''
	epause 10

	ESVN_UPDATE_CMD="svn update -N"
	ESVN_FETCH_CMD="svn checkout -N"
	ESVN_REPO_URI=`dirname ${ESVN_REPO_URI}`
	subversion_src_unpack

	S=${WORKDIR}/${PN}/admin
	ESVN_REPO_URI="svn://anonsvn.kde.org/home/kde/branches/KDE/3.5/kde-common/admin"
	subversion_src_unpack

	ESVN_UPDATE_CMD="svn up"
	ESVN_FETCH_CMD="svn checkout"
	S=${WORKDIR}/${PN}/${PN}
	ESVN_REPO_URI="svn://anonsvn.kde.org/home/kde/trunk/extragear/pim/kdebluetooth"
	subversion_src_unpack
}

src_compile() {
	# Change defaults to match our bluez-utils setup
	sed -i -e 's,/etc/init\.d/bluez-utils,/etc/init\.d/bluetooth,' \
		"${S}/kdebluetooth/kbluetoothd/kcm_btpaired/pairedtab.cpp" || die
	
	local myconf="$(use_with xmms) $(use_enable irmc irmcsynckonnector)"
	
	kde_src_compile
}

pkg_postinst() {
	einfo ''
	einfo 'This new version of kde-bluetooth provides a replacement for the'
	einfo 'standard bluepin program "kbluepin". If you want to use this version,'
	einfo 'you have to edit "/etc/bluetooth/hcid.conf" and change the line'
	einfo '"pin_helper oldbluepin;" to "pin_helper /usr/lib/kdebluetooth/kbluepin;".'
	einfo 'Then restart hcid to make the change take effect.'
	einfo ''
	einfo 'The bemused server (avaible with the "xmms" USE flag enabled) only works with'
	einfo 'Symbian OS phones'
	einfo ''
	ewarn ''
	ewarn 'If you spot any mistake in this ebuild, notify deathwing00.'
	ewarn ''
}