1 files changed, 47 insertions, 0 deletions
diff --git a/dev-ruby/rubocop-ast/rubocop-ast-1.18.0.ebuild b/dev-ruby/rubocop-ast/rubocop-ast-1.18.0.ebuild
new file mode 100644
index 00000000..7f4cb3f1
--- /dev/null
+++ b/dev-ruby/rubocop-ast/rubocop-ast-1.18.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+USE_RUBY="ruby26 ruby27 ruby30"
+
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.md"
+
+RUBY_FAKEGEM_RECIPE_TEST="rspec3"
+
+RUBY_FAKEGEM_GEMSPEC="rubocop-ast.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="RuboCop's Node and NodePattern classes"
+HOMEPAGE="https://github.com/rubocop-hq/rubocop-ast"
+SRC_URI="https://github.com/rubocop-hq/rubocop-ast/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="1"
+KEYWORDS="~amd64"
+IUSE=""
+
+ruby_add_rdepend "
+	>=dev-ruby/parser-3.1.1.0
+"
+
+ruby_add_bdepend "dev-ruby/bundler >=dev-ruby/oedipus_lex-2.6.0 dev-ruby/racc dev-ruby/rspec:3"
+
+all_ruby_prepare() {
+	sed -i -e '3irequire "uri" ; gem "parser"' spec/spec_helper.rb || die
+	sed -i -e '1irequire "oedipus_lex"' tasks/compile.rake || die
+
+	# Avoid unneeded dependencies
+	rm -f tasks/cut_release.rake || die
+	sed -e "/\(gemspec\|bump\|pry\|'rubocop\|simplecov\)/ s:^:#:" \
+		-e '/rake/ s/~> 13.0/>= 12/' \
+		-i Gemfile || die
+}
+
+each_ruby_prepare() {
+	sed -i -e "s:bundle exec:${RUBY} -S:" tasks/compile.rake || die
+}
+
+each_ruby_compile() {
+	${RUBY} -S rake generate || die
+}