# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"
inherit linux-mod

DESCRIPTION="Compressed RAM as fast swap"
HOMEPAGE="http://compcache.googlecode.com/"
SRC_URI="http://compcache.googlecode.com/files/${P}.tar.gz"

LICENSE="GPL-2 LGPL-2.1"
KEYWORDS="~amd64 ~x86"
IUSE=""

DEPEND=">=virtual/linux-sources-2.6"
RDEPEND="${DEPEND}"

BUILD_PARAMS='KV_OUT_DIR="${KV_OUT_DIR}"'
BUILD_TARGETS="all"
CONFIG_CHECK="LZO_COMPRESS LZO_DECOMPRESS" # CRYPTO_LZO
MODULE_NAMES="ramzswap(compcache:${S}:${S})
	xvmalloc(:${S}:${S}/sub-projects/allocators/xvmalloc-kmod)"
MODULESD_RAMZSWAP_DOCS="Changelog README load_modules.sh unload_modules.sh"
MODULESD_RAMZSWAP_EXAMPLES=('NUM_DEVICES="1"')
MODULESD_XVMALLOC_ENABLED="no"

src_prepare() {
	find . -name Makefile -exec sed -i \
		-e 's:make:$(MAKE):g' \
		-e 's#/lib/modules/$(shell uname -r)/build#"$(KV_OUT_DIR)"#' \
		{} \; || die
}

src_install() {
	linux-mod_src_install

	dosbin sub-projects/rzscontrol/rzscontrol || die
	doman sub-projects/rzscontrol/man/rzscontrol.1 || die
}