app-crypt/gcr: 3.10.1 → 3.12.0

Build now uses python based tool.

3 files changed, 100 insertions, 4 deletions

diff --git a/app-crypt/gcr/Manifest b/app-crypt/gcr/Manifest
new file mode 100644
index 00000000..d98aa19b
--- /dev/null
+++ b/app-crypt/gcr/Manifest
@@ -0,0 +1,11 @@
+-----BEGIN PGP SIGNED MESSAGE-----
+Hash: SHA512
+
+DIST gcr-3.12.0.tar.xz 1335728 SHA256 9d561d0b0a43aaad55fc1d464b3ee3e1687a5021e444f1bbdce3ae624518de77 SHA512 a38a7d084f77bff5b26546bc0bca61e53b0b0a0ae9470a42b61ac12c9a0b755a763171d27d01ffbeda3c04a3d6e9cadc61f5875576d02efacfab112427834990 WHIRLPOOL fc5743c81c4062b79a58c272265f2660be66739796e02eeb241d4340b3f31325fa58c49ed478fa5e9986465e895a1d316850dacfe9a94cc0472cdee0b39c8337
+-----BEGIN PGP SIGNATURE-----
+Version: GnuPG v2.0.22 (GNU/Linux)
+
+iEYEAREKAAYFAlNNmoMACgkQ1fmVwcYIWAakbgCePzHCyzlO5Ih/FER4XDdZONjo
+SYwAoKs5ciUROJeY3IIOlvfz3F/8cj10
+=778+
+-----END PGP SIGNATURE-----
diff --git a/app-crypt/gcr/gcr-3.12.0.ebuild b/app-crypt/gcr/gcr-3.12.0.ebuild
new file mode 100644
index 00000000..4c6a3772
--- /dev/null
+++ b/app-crypt/gcr/gcr-3.12.0.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="5"
+GCONF_DEBUG="no"
+VALA_MIN_API_VERSION="0.20"
+VALA_USE_DEPEND="vapigen"
+PYTHON_COMPAT=( python2_7 )
+
+inherit gnome2 python-any-r1 vala virtualx
+
+DESCRIPTION="Libraries for cryptographic UIs and accessing PKCS#11 modules"
+HOMEPAGE="https://developer.gnome.org/gcr/"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0/1" # subslot = suffix of libgcr-3
+IUSE="debug gtk +introspection vala"
+REQUIRED_USE="vala? ( introspection )"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~sparc-solaris ~x86-solaris"
+
+COMMON_DEPEND="
+	>=app-crypt/gnupg-2
+	>=app-crypt/p11-kit-0.19
+	>=dev-libs/glib-2.34:2
+	>=dev-libs/libgcrypt-1.2.2:0=
+	>=dev-libs/libtasn1-1:=
+	>=sys-apps/dbus-1
+	gtk? ( >=x11-libs/gtk+-3:3 )
+	introspection? ( >=dev-libs/gobject-introspection-1.34 )
+"
+RDEPEND="${COMMON_DEPEND}
+	!<gnome-base/gnome-keyring-3.3
+"
+# gcr was part of gnome-keyring until 3.3
+DEPEND="${COMMON_DEPEND}
+	${PYTHON_DEPS}
+	dev-libs/gobject-introspection-common
+	dev-libs/libxslt
+	dev-util/gdbus-codegen
+	>=dev-util/gtk-doc-am-1.9
+	>=dev-util/intltool-0.35
+	sys-devel/gettext
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+# eautoreconf needs:
+#	dev-libs/gobject-introspection-common
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	# Disable stupid flag changes
+	sed -e 's/CFLAGS="$CFLAGS -g"//' \
+		-e 's/CFLAGS="$CFLAGS -O0"//' \
+		-i configure.ac configure || die
+
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	DOCS="AUTHORS ChangeLog HACKING NEWS README"
+	gnome2_src_configure \
+		$(use_with gtk) \
+		$(use_enable introspection) \
+		$(use_enable vala) \
+		$(usex debug --enable-debug=yes --enable-debug=default) \
+		--disable-update-icon-cache \
+		--disable-update-mime
+}
+
+src_test() {
+	unset DBUS_SESSION_BUS_ADDRESS
+	Xemake check
+}
diff --git a/app-crypt/gcr/gcr-9999.ebuild b/app-crypt/gcr/gcr-9999.ebuild
index 4ddc6447..da0d1a47 100644
--- a/app-crypt/gcr/gcr-9999.ebuild
+++ b/app-crypt/gcr/gcr-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2013 Gentoo Foundation
+# Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 # $Header: $
 
@@ -6,8 +6,9 @@ EAPI="5"
 GCONF_DEBUG="no"
 VALA_MIN_API_VERSION="0.20"
 VALA_USE_DEPEND="vapigen"
+PYTHON_COMPAT=( python2_7 )
 
-inherit gnome2 vala virtualx
+inherit gnome2 python-any-r1 vala virtualx
 if [[ ${PV} = 9999 ]]; then
 	inherit gnome2-live
 fi
@@ -29,8 +30,8 @@ fi
 COMMON_DEPEND="
 	>=app-crypt/gnupg-2
 	>=app-crypt/p11-kit-0.19
-	>=dev-libs/glib-2.32:2
-	>=dev-libs/libgcrypt-1.2.2:=
+	>=dev-libs/glib-2.34:2
+	>=dev-libs/libgcrypt-1.2.2:0=
 	>=dev-libs/libtasn1-1:=
 	>=sys-apps/dbus-1
 	gtk? ( >=x11-libs/gtk+-3:3 )
@@ -41,7 +42,9 @@ RDEPEND="${COMMON_DEPEND}
 "
 # gcr was part of gnome-keyring until 3.3
 DEPEND="${COMMON_DEPEND}
+	${PYTHON_DEPS}
 	dev-libs/gobject-introspection-common
+	dev-libs/libxslt
 	dev-util/gdbus-codegen
 	>=dev-util/gtk-doc-am-1.9
 	>=dev-util/intltool-0.35
@@ -57,6 +60,10 @@ if [[ ${PV} = 9999 ]]; then
 		doc? ( >=dev-util/gtk-doc-1.9 )"
 fi
 
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
 src_prepare() {
 	# Disable stupid flag changes
 	sed -e 's/CFLAGS="$CFLAGS -g"//' \