1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
|
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $
EAPI="5"
GCONF_DEBUG="no"
PYTHON_COMPAT=( python{2_7,3_3,3_4} )
inherit gnome2 multilib python-r1 virtualx
if [[ ${PV} = 9999 ]]; then
inherit gnome2-live
fi
DESCRIPTION="A GObject plugins library"
HOMEPAGE="http://developer.gnome.org/libpeas/stable/"
LICENSE="LGPL-2+"
SLOT="0"
IUSE="+gtk glade jit lua +python"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} ?? ( $(python_gen_useflags 'python3*') ) )"
if [[ ${PV} = 9999 ]]; then
IUSE="${IUSE} doc"
KEYWORDS=""
else
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~ia64-linux ~x86-linux"
fi
RDEPEND="
>=dev-libs/glib-2.38:2
>=dev-libs/gobject-introspection-1.39
glade? ( >=dev-util/glade-3.9.1:3.10 )
gtk? ( >=x11-libs/gtk+-3:3[introspection] )
lua? (
dev-lua/lgi
jit? ( >=dev-lang/luajit-2:2 )
!jit? ( >=dev-lang/lua-5.1:0 ) )
python? (
${PYTHON_DEPS}
>=dev-python/pygobject-3.2:3[${PYTHON_USEDEP}] )
"
DEPEND="${RDEPEND}
>=dev-util/gtk-doc-am-1.11
>=dev-util/intltool-0.40
virtual/pkgconfig
"
if [[ ${PV} = 9999 ]]; then
DEPEND="${DEPEND} doc? ( >=dev-util/gtk-doc-1.11 )"
fi
src_configure() {
# Wtf, --disable-gcov, --enable-gcov=no, --enable-gcov, all enable gcov
# What do we do about gdb, valgrind, gcov, etc?
local myconf=(
$(use_enable glade glade-catalog)
$(use_enable gtk)
--disable-static
# possibly overriden below
--disable-python{2,3}
--disable-lua5.1
--disable-luajit
)
if use lua ; then
if use jit ; then
myconf+=( --enable-luajit )
else
myconf+=( --enable-lua5.1 )
fi
fi
python_configure() {
local v
python_is_python3 && v=3 || v=2
myconf+=(
"--enable-python${v}"
# it is just 'PYTHON' for py3 in the build system
"PYTHON${v#3}=${PYTHON}"
"PYTHON${v}_CONFIG=${PYTHON}-config"
)
}
use python && python_foreach_impl python_configure
gnome2_src_configure "${myconf[@]}"
}
src_test() {
# FIXME: Tests fail because of some bug involving Xvfb and Gtk.IconTheme
# DO NOT REPORT UPSTREAM, this is not a libpeas bug.
# To reproduce:
# >>> from gi.repository import Gtk
# >>> Gtk.IconTheme.get_default().has_icon("gtk-about")
# This should return True, it returns False for Xvfb
Xemake check
}
|
GitWeb