blob: 47f0bb087951a1ea9ad8c3e4eb006e4e9b24ed41 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
|
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $
EAPI="5"
GCONF_DEBUG="no"
GNOME2_LA_PUNT="yes"
inherit eutils flag-o-matic readme.gentoo gnome2
if [[ ${PV} = 9999 ]]; then
inherit gnome2-live
fi
DESCRIPTION="Integrated mail, addressbook and calendaring functionality"
HOMEPAGE="https://wiki.gnome.org/Apps/Evolution"
# Note: explicitly "|| ( LGPL-2 LGPL-3 )", not "LGPL-2+".
LICENSE="|| ( LGPL-2 LGPL-3 ) CC-BY-SA-3.0 FDL-1.3+ OPENLDAP"
SLOT="2.0"
IUSE="+bogofilter crypt highlight ldap map spamassassin spell ssl +weather"
if [[ ${PV} = 9999 ]]; then
IUSE="${IUSE} doc"
KEYWORDS=""
else
#need x11-libs/libcryptui keyworded
#KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
KEYWORDS="~amd64 ~x86 ~x86-fbsd"
fi
# We need a graphical pinentry frontend to be able to ask for the GPG
# password from inside evolution, bug 160302
PINENTRY_DEPEND="|| ( app-crypt/pinentry[gtk] app-crypt/pinentry[qt4] )"
# glade-3 support is for maintainers only per configure.ac
# pst is not mature enough and changes API/ABI frequently
# google tasks requires >=libgdata-0.15.1
# gnome-desktop support is optional with --enable-gnome-desktop
# gnome-autoar (currently disabled because no release has been made)
COMMON_DEPEND="
>=app-crypt/gcr-3.4
>=app-text/enchant-1.1.7
>=dev-libs/dbus-glib-0.6
>=dev-libs/glib-2.40:2
>=dev-libs/libgdata-0.10:=
>=dev-libs/libxml2-2.7.3:2
>=gnome-base/gnome-desktop-2.91.3:3=
>=gnome-base/gsettings-desktop-schemas-2.91.92
>=gnome-extra/evolution-data-server-${PV}:=[gtk,weather?]
>=media-libs/libcanberra-0.25[gtk3]
>=net-libs/libsoup-2.42:2.4
>=net-libs/webkit-gtk-2.2.0:3
>=x11-libs/cairo-1.9.15:=[glib]
>=x11-libs/gdk-pixbuf-2.24:2
>=x11-libs/gtk+-3.10.0:3
>=x11-libs/libnotify-0.7:=
>=x11-misc/shared-mime-info-0.22
app-text/iso-codes
dev-libs/atk
gnome-base/dconf
x11-libs/libSM
x11-libs/libICE
x11-themes/gnome-icon-theme
crypt? (
x11-libs/libcryptui:=
|| (
( >=app-crypt/gnupg-2.0.1-r2 ${PINENTRY_DEPEND} )
=app-crypt/gnupg-1.4* ) )
map? (
>=media-libs/libchamplain-0.12:0.12[gtk]
>=media-libs/clutter-1.0.0:1.0
>=media-libs/clutter-gtk-0.90:1.0
>=sci-geosciences/geocode-glib-3.10.0
x11-libs/mx:1.0 )
spell? ( app-text/gtkspell:3 )
ldap? ( >=net-nds/openldap-2:= )
ssl? (
>=dev-libs/nspr-4.6.1:=
>=dev-libs/nss-3.11:= )
weather? ( >=dev-libs/libgweather-3.8:2= )
"
DEPEND="${COMMON_DEPEND}
app-text/docbook-xml-dtd:4.1.2
dev-util/gtk-doc-am
>=dev-util/intltool-0.40.0
virtual/pkgconfig
"
# eautoreconf needs:
# app-text/yelp-tools
# >=gnome-base/gnome-common-2.12
RDEPEND="${COMMON_DEPEND}
bogofilter? ( mail-filter/bogofilter )
highlight? ( app-text/highlight )
spamassassin? ( mail-filter/spamassassin )
!gnome-extra/evolution-exchange
"
if [[ ${PV} = 9999 ]]; then
DEPEND="${DEPEND}
app-text/yelp-tools
doc? ( >=dev-util/gtk-doc-1.14 )"
fi
DISABLE_AUTOFORMATTING="yes"
DOC_CONTENTS="To change the default browser if you are not using GNOME, edit
~/.local/share/applications/mimeapps.list so it includes the
following content:
[Default Applications]
x-scheme-handler/http=firefox.desktop
x-scheme-handler/https=firefox.desktop
(replace firefox.desktop with the name of the appropriate .desktop
file from /usr/share/applications if you use a different browser)."
src_prepare() {
# Fix relink issues in src_install
ELTCONF="--reverse-deps"
gnome2_src_prepare
}
src_configure() {
# Use NSS/NSPR only if 'ssl' is enabled.
local myconf
[[ ${PV} != 9999 ]] && myconf="${myconf} ITSTOOL=$(type -P true)"
gnome2_src_configure \
--without-glade-catalog \
--disable-autoar \
--disable-code-coverage \
--disable-installed-tests \
--disable-pst-import \
--enable-canberra \
$(use_enable crypt libcryptui) \
$(use_enable highlight text-highlight) \
$(use_enable map contact-maps) \
$(use_enable spell gtkspell) \
$(use_enable ssl nss) \
$(use_enable ssl smime) \
$(use_with bogofilter) \
$(use_with ldap openldap) \
$(use_with spamassassin) \
$(usex ssl --enable-nss=yes "--without-nspr-libs
--without-nspr-includes
--without-nss-libs
--without-nss-includes") \
$(use_enable weather) \
${myconf}
}
src_install() {
DOCS="AUTHORS ChangeLog* HACKING MAINTAINERS NEWS* README"
gnome2_src_install
# Problems with prelink:
# https://bugzilla.gnome.org/show_bug.cgi?id=731680
# https://bugzilla.gnome.org/show_bug.cgi?id=732148
# https://bugzilla.redhat.com/show_bug.cgi?id=1114538
echo PRELINK_PATH_MASK=/usr/bin/evolution > ${T}/99${PN}
doenvd "${T}"/99${PN}
readme.gentoo_create_doc
}
pkg_postinst() {
gnome2_pkg_postinst
readme.gentoo_print_elog
}
|
GitWeb