blob: 5565e12f1c47697bb4caec62d6a4f7c9427f6b48 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
|
# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
GNOME2_LA_PUNT="yes"
inherit gnome-meson multilib-minimal virtualx
DESCRIPTION="Network-related giomodules for glib"
HOMEPAGE="https://git.gnome.org/browse/glib-networking/"
LICENSE="LGPL-2+"
SLOT="0"
IUSE="+gnome +libproxy smartcard test"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
RDEPEND="
>=dev-libs/glib-2.56.0:2[${MULTILIB_USEDEP}]
app-misc/ca-certificates
>=net-libs/gnutls-3:=[${MULTILIB_USEDEP}]
gnome? ( gnome-base/gsettings-desktop-schemas )
libproxy? ( >=net-libs/libproxy-0.4.11-r1:=[${MULTILIB_USEDEP}] )
smartcard? (
>=app-crypt/p11-kit-0.18.4[${MULTILIB_USEDEP}]
>=net-libs/gnutls-3:=[pkcs11,${MULTILIB_USEDEP}] )
"
DEPEND="${RDEPEND}
>=sys-devel/gettext-0.19.4
>=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
test? ( sys-apps/dbus[X] )
"
PATCHES=(
"${FILESDIR}"/2.56.0-Fix-building-tls-plugin-without-pkcs11.patch
)
src_prepare() {
default
# Disable SSLv3 requiring fallback test, which fails with net-libs/gnutls[-sslv3], bug 595952
# https://bugzilla.gnome.org/show_bug.cgi?id=782853
sed -i -e '/\/tls\/connection\/fallback\/SSL/d' "${S}"/tls/tests/connection.c || die
}
multilib_src_configure() {
gnome-meson_src_configure \
-Dstatic_modules=false \
-Dca_certificates_path="${EPREFIX}"/etc/ssl/certs/ca-certificates.crt \
$(meson_use gnome gnome_proxy_support) \
$(meson_use libproxy libproxy_support) \
$(meson_use smartcard pkcs11_support)
# TODO gnutls is mandatory with meson
}
multilib_src_compile() {
gnome-meson_src_compile
}
multilib_src_test() {
# XXX: non-native tests fail if glib-networking is already installed.
# have no idea what's wrong. would appreciate some help.
multilib_is_native_abi || return 0
virtx meson_src_test
}
multilib_src_install() {
gnome-meson_src_install
}
pkg_postinst() {
gnome-meson_pkg_postinst
multilib_pkg_postinst() {
gnome2_giomodule_cache_update \
|| die "Update GIO modules cache failed (for ${ABI})"
}
multilib_foreach_abi multilib_pkg_postinst
}
pkg_postrm() {
gnome-meson_pkg_postrm
multilib_pkg_postrm() {
gnome2_giomodule_cache_update \
|| die "Update GIO modules cache failed (for ${ABI})"
}
multilib_foreach_abi multilib_pkg_postrm
}
|
GitWeb