aboutsummaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAndreas Sturmlechner <asturm@gentoo.org>2021-09-21 20:05:52 +0200
committerAndreas Sturmlechner <asturm@gentoo.org>2021-09-21 20:26:00 +0200
commit991edf3a948b62e7342d9d3bcf793070b9ea92cf (patch)
treea46abd436db3363d22f698b500388bc92fba8d49 /kde-plasma
parentkde-plasma/plasma-meta: 5.22.90 version bump (diff)
downloadkde-991edf3a948b62e7342d9d3bcf793070b9ea92cf.tar.gz
kde-991edf3a948b62e7342d9d3bcf793070b9ea92cf.tar.bz2
kde-991edf3a948b62e7342d9d3bcf793070b9ea92cf.zip
kde-plasma/plasma-nm: 5.22.90 version bump
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
Diffstat (limited to 'kde-plasma')
-rw-r--r--kde-plasma/plasma-nm/Manifest1
-rw-r--r--kde-plasma/plasma-nm/plasma-nm-5.22.90.ebuild90
2 files changed, 91 insertions, 0 deletions
diff --git a/kde-plasma/plasma-nm/Manifest b/kde-plasma/plasma-nm/Manifest
new file mode 100644
index 0000000000..226169a2fe
--- /dev/null
+++ b/kde-plasma/plasma-nm/Manifest
@@ -0,0 +1 @@
+DIST plasma-nm-5.22.90.tar.xz 918272 BLAKE2B 081c4478e5e91fc21a5607a67fa0f94a6b8fe22ff9f02ff06a324e6aab9ce556fce82f1232eb9fec8fea6680519281ae10b4758b13ee74dfb5bef443168d5898 SHA512 51dad2ecc4af9fda99cc85fc1169a1f2d9476b8a54dc6a22b7a38a51d3bfa1997d110ab957b7b18f6863373b770df7951fc90f81695961b5ff378e60006e3157
diff --git a/kde-plasma/plasma-nm/plasma-nm-5.22.90.ebuild b/kde-plasma/plasma-nm/plasma-nm-5.22.90.ebuild
new file mode 100644
index 0000000000..0ac6235da1
--- /dev/null
+++ b/kde-plasma/plasma-nm/plasma-nm-5.22.90.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="true"
+KFMIN=5.86.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.2
+inherit ecm kde.org
+
+DESCRIPTION="KDE Plasma applet for NetworkManager"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="modemmanager openconnect teamd"
+
+DEPEND="
+ >=app-crypt/qca-2.3.0:2
+ >=dev-qt/qtdbus-${QTMIN}:5
+ >=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
+ >=dev-qt/qtgui-${QTMIN}:5
+ >=dev-qt/qtnetwork-${QTMIN}:5
+ >=dev-qt/qtwidgets-${QTMIN}:5
+ >=kde-frameworks/kcompletion-${KFMIN}:5
+ >=kde-frameworks/kconfig-${KFMIN}:5
+ >=kde-frameworks/kconfigwidgets-${KFMIN}:5
+ >=kde-frameworks/kcoreaddons-${KFMIN}:5
+ >=kde-frameworks/kdbusaddons-${KFMIN}:5
+ >=kde-frameworks/kdeclarative-${KFMIN}:5
+ >=kde-frameworks/ki18n-${KFMIN}:5
+ >=kde-frameworks/kio-${KFMIN}:5
+ >=kde-frameworks/kitemviews-${KFMIN}:5
+ >=kde-frameworks/knotifications-${KFMIN}:5
+ >=kde-frameworks/kservice-${KFMIN}:5
+ >=kde-frameworks/kwallet-${KFMIN}:5
+ >=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+ >=kde-frameworks/kwindowsystem-${KFMIN}:5
+ >=kde-frameworks/kxmlgui-${KFMIN}:5
+ >=kde-frameworks/networkmanager-qt-${KFMIN}:5[teamd=]
+ >=kde-frameworks/plasma-${KFMIN}:5
+ >=kde-frameworks/solid-${KFMIN}:5
+ net-misc/networkmanager[teamd=]
+ modemmanager? (
+ >=dev-qt/qtxml-${QTMIN}:5
+ >=kde-frameworks/modemmanager-qt-${KFMIN}:5
+ net-misc/mobile-broadband-provider-info
+ )
+ openconnect? (
+ >=dev-qt/qtxml-${QTMIN}:5
+ net-vpn/networkmanager-openconnect
+ net-vpn/openconnect:=
+ )
+"
+RDEPEND="${DEPEND}
+ >=dev-qt/qtquickcontrols-${QTMIN}:5
+ >=dev-qt/qtquickcontrols2-${QTMIN}:5
+ >=kde-frameworks/kirigami-${KFMIN}:5
+ >=kde-plasma/kde-cli-tools-${PVCUT}:5
+"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+ ecm_src_prepare
+
+ # TODO: try to get a build switch upstreamed
+ if ! use openconnect; then
+ sed -e "s/^pkg_check_modules.*openconnect/#&/" -i CMakeLists.txt || die
+ fi
+}
+
+src_configure() {
+ local mycmakeargs=(
+ -DDISABLE_MODEMMANAGER_SUPPORT=$(usex !modemmanager)
+ $(cmake_use_find_package modemmanager KF5ModemManagerQt)
+ )
+
+ ecm_src_configure
+}
+
+pkg_postinst() {
+ ecm_pkg_postinst
+
+ if ! has_version "kde-plasma/plasma-workspace:5"; then
+ elog "${PN} is not terribly useful without kde-plasma/plasma-workspace:5."
+ elog "However, the networkmanagement KCM can be called from either systemsettings"
+ elog "or manually: $ kcmshell5 kcm_networkmanagement"
+ fi
+}