From 88e669a299fc88838b3c11b516fe738bf49071d5 Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Tue, 31 Jan 2023 11:15:54 +0100
Subject: kde-apps/umbrello: 22.12.2 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 kde-apps/umbrello/Manifest                |  1 +
 kde-apps/umbrello/umbrello-22.12.2.ebuild | 74 +++++++++++++++++++++++++++++++
 2 files changed, 75 insertions(+)
 create mode 100644 kde-apps/umbrello/Manifest
 create mode 100644 kde-apps/umbrello/umbrello-22.12.2.ebuild

diff --git a/kde-apps/umbrello/Manifest b/kde-apps/umbrello/Manifest
new file mode 100644
index 0000000000..ddc3706e59
--- /dev/null
+++ b/kde-apps/umbrello/Manifest
@@ -0,0 +1 @@
+DIST umbrello-22.12.2.tar.xz 5796792 BLAKE2B b9695cfa4c3f113ce55b672ddc0caf429a7f99f1a3d7e08999863bb11bd101e59a6a3bb7b513ebc876834c7e0dc3a5489087e869770134b12a8739d206a0db0b SHA512 2945c5859021a9fc62f9be291781d99657e16ab6544a0c253b11dc044fd0fb0da98a4879038ae3bd97a44e203c55ec65502b16b4f94110bec0e9c0d4992bfbe7
diff --git a/kde-apps/umbrello/umbrello-22.12.2.ebuild b/kde-apps/umbrello/umbrello-22.12.2.ebuild
new file mode 100644
index 0000000000..848a8c4755
--- /dev/null
+++ b/kde-apps/umbrello/umbrello-22.12.2.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_QTHELP="false" # TODO: figure out install error
+ECM_TEST="forceoptional"
+KFMIN=5.101.0
+QTMIN=5.15.5
+VIRTUALX_REQUIRED="test"
+inherit ecm gear.kde.org
+
+DESCRIPTION="KDE UML Modeller"
+HOMEPAGE="https://apps.kde.org/umbrello/ https://umbrello.kde.org"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="php"
+
+RDEPEND="
+	dev-libs/libxml2
+	dev-libs/libxslt
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdelibs4support-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/ktexteditor-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	php? (
+		dev-util/kdevelop:5=
+		dev-util/kdevelop-pg-qt:5
+		dev-util/kdevelop-php:5
+	)
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-20.08.3-gentoo-docbundledir.patch # fix hardcoded path
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_Doxygen=ON # broken, re-enable w/ ECM_QTHELP
+		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5WebKitWidgets=ON
+		-DBUILD_APIDOC=OFF
+		-DBUILD_KF5=ON
+		-DBUILD_PHP_IMPORT=$(usex php)
+		-DBUILD_unittests=$(usex test)
+	)
+	use test && mycmakeargs+=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_LLVM=ON
+		-DCMAKE_DISABLE_FIND_PACKAGE_Clang=ON
+		-DCMAKE_DISABLE_FIND_PACKAGE_CLANG=ON
+	)
+
+	ecm_src_configure
+}
-- 
cgit v1.2.3-65-gdbad