From 4f315eeddf92c89f519c7a9016887c4b841db036 Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Tue, 12 Jul 2022 13:24:34 +0200
Subject: kde-plasma/plasma-firewall: 5.25.3 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 kde-plasma/plasma-firewall/Manifest                |  1 +
 .../plasma-firewall/plasma-firewall-5.25.3.ebuild  | 63 ++++++++++++++++++++++
 2 files changed, 64 insertions(+)
 create mode 100644 kde-plasma/plasma-firewall/plasma-firewall-5.25.3.ebuild

(limited to 'kde-plasma/plasma-firewall')

diff --git a/kde-plasma/plasma-firewall/Manifest b/kde-plasma/plasma-firewall/Manifest
index bb160896e0..71e62dd37e 100644
--- a/kde-plasma/plasma-firewall/Manifest
+++ b/kde-plasma/plasma-firewall/Manifest
@@ -1 +1,2 @@
 DIST plasma-firewall-5.24.6.tar.xz 346668 BLAKE2B 857b90f383798961d32d9a65f65cec4f7b45dc17c56966bbe71ee4068c8bbadee941d0ce2a439dc99ec3a9327d5d1d4189d327a820ab618818090ff7661d4865 SHA512 b75442205d1b2eed986794ff6ea233e31e904de36e8acabc7ef2da83b94fdebcaf6a0fa26d5b0393921e9b0acc6d62bbd71f711e13f3e6ba455710970e5af26f
+DIST plasma-firewall-5.25.3.tar.xz 357288 BLAKE2B 41918e66e90d2c1bbd997e811439170d7f9a6a16991fd0bd7c4a77f33ddb859cc3fca50cf4880a44b1f8db2a09e53c371a57371d07718ebb45c11bb6a35b1d39 SHA512 53ea58dc5d2e9c2333054659720c6689710e4995f8da0390a14e11582cbd262dd585b4d829d9e38bde26ee0751e79ad89669f8134d44e8b7916a929cd076ee42
diff --git a/kde-plasma/plasma-firewall/plasma-firewall-5.25.3.ebuild b/kde-plasma/plasma-firewall/plasma-firewall-5.25.3.ebuild
new file mode 100644
index 0000000000..0161118e86
--- /dev/null
+++ b/kde-plasma/plasma-firewall/plasma-firewall-5.25.3.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+KFMIN=5.95.0
+QTMIN=5.15.5
+inherit ecm plasma.kde.org python-single-r1
+
+DESCRIPTION="Plasma frontend for Firewalld or UFW"
+HOMEPAGE="https://invent.kde.org/network/plasma-firewall"
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="firewalld +ufw"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE} || ( firewalld ufw )"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+	${PYTHON_DEPS}
+	firewalld? ( net-firewall/firewalld )
+	ufw? ( net-firewall/ufw )
+"
+
+src_prepare() {
+	ecm_src_prepare
+	# this kind of cmake magic doesn't work for us at all.
+	sed -e "1 s:^.*$:\#\!/usr/bin/env ${EPYTHON}:" \
+		-i kcm/backends/ufw/helper/kcm_ufw_helper.py.cmake || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_FIREWALLD_BACKEND=$(usex firewalld)
+		-DBUILD_UFW_BACKEND=$(usex ufw)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst () {
+	ecm_pkg_postinst
+
+	if ! has_version sys-apps/systemd; then
+		ewarn "${PN} is not functional without sys-apps/systemd at this point."
+		ewarn "See also: https://bugs.gentoo.org/778527"
+	fi
+}
-- 
cgit v1.2.3-65-gdbad