From b1fec3d4f763a0aaf466b696a8b3461a9e831d97 Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Wed, 10 Jan 2024 12:26:29 +0100
Subject: www-client/falkon: 24.01.90 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 www-client/falkon/Manifest               |  1 +
 www-client/falkon/falkon-24.01.90.ebuild | 82 ++++++++++++++++++++++++++++++++
 2 files changed, 83 insertions(+)
 create mode 100644 www-client/falkon/Manifest
 create mode 100644 www-client/falkon/falkon-24.01.90.ebuild

(limited to 'www-client')

diff --git a/www-client/falkon/Manifest b/www-client/falkon/Manifest
new file mode 100644
index 0000000000..4cfb66c585
--- /dev/null
+++ b/www-client/falkon/Manifest
@@ -0,0 +1 @@
+DIST falkon-24.01.90.tar.xz 2589652 BLAKE2B 2eb71127cfaf06b9978a339bb0a5d162e1ed259fe6a6135f045240a0797842a961456b69f32ed8da5217425dd71053d85bb31dab94978cb3642aa927a7895f2a SHA512 18a02ae6f63d52377aeb543524a07706b167f19349a93482cde9625b56c586fead02fd00b80741dfd9e63e2f57c00a26453492069a1dfda30711e0baf20b6672
diff --git a/www-client/falkon/falkon-24.01.90.ebuild b/www-client/falkon/falkon-24.01.90.ebuild
new file mode 100644
index 0000000000..336bec45c9
--- /dev/null
+++ b/www-client/falkon/falkon-24.01.90.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="true"
+KFMIN=5.248.0
+QTMIN=6.6.0
+PYTHON_COMPAT=( python3_{10..12} )
+inherit ecm gear.kde.org python-single-r1
+
+DESCRIPTION="Cross-platform web browser using QtWebEngine"
+HOMEPAGE="https://www.falkon.org/ https://apps.kde.org/falkon/"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="dbus kde python +X"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+RESTRICT="test" # bug 653046
+
+COMMON_DEPEND="
+	dev-libs/openssl:0=
+	>=dev-qt/qtbase-${QTMIN}:6[dbus?,gui,network,sql,sqlite,ssl,widgets]
+	>=dev-qt/qtdeclarative-${QTMIN}:6[widgets]
+	>=dev-qt/qtwebchannel-${QTMIN}:6
+	>=dev-qt/qtwebengine-${QTMIN}:6=[widgets]
+	>=kde-frameworks/karchive-${KFMIN}:6
+	virtual/libintl
+	kde? (
+		>=kde-frameworks/kcoreaddons-${KFMIN}:6
+		>=kde-frameworks/kcrash-${KFMIN}:6
+		>=kde-frameworks/kio-${KFMIN}:6
+		>=kde-frameworks/kjobwidgets-${KFMIN}:6
+		>=kde-frameworks/kwallet-${KFMIN}:6
+		>=kde-frameworks/purpose-${KFMIN}:6
+	)
+	python? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep "
+			>=dev-python/pyside6-${QTMIN}[designer,gui,webengine,widgets,\${PYTHON_USEDEP}] \
+			>=dev-python/shiboken6-${QTMIN}[\${PYTHON_USEDEP}]
+		")
+	)
+	X? (
+		x11-libs/libxcb:=
+		x11-libs/xcb-util
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtbase-${QTMIN}:6[concurrent]
+"
+if [[ ${KDE_BUILD_TYPE} != live ]]; then
+	DEPEND+=" >=kde-frameworks/ki18n-${KFMIN}:6"
+fi
+RDEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtsvg-${QTMIN}:6
+"
+BDEPEND=">=dev-qt/qttools-${QTMIN}:6[linguist]"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+	ecm_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_KEYRING=OFF
+		-DDISABLE_DBUS=$(usex !dbus)
+		$(cmake_use_find_package kde KF6Wallet)
+		$(cmake_use_find_package kde KF6KIO)
+		-DBUILD_PYTHON_SUPPORT=$(usex python)
+		-DNO_X11=$(usex !X)
+	)
+	use python && mycmakeargs+=(
+		-DPYTHON_CONFIG_SUFFIX="-${EPYTHON}" # shiboken_helpers.cmake quirk
+		-DPython3_INCLUDE_DIR=$(python_get_includedir)
+		-DPython3_LIBRARY=$(python_get_library_path)
+	)
+	ecm_src_configure
+}
-- 
cgit v1.2.3-65-gdbad