From e1d259fa37e81fbff05fdd0e19dafe76f30d5a11 Mon Sep 17 00:00:00 2001
From: Justin Lecher <jlec@gentoo.org>
Date: Fri, 30 Oct 2015 14:39:28 +0100
Subject: dev-python/nbconvert: Version Bump

Package-Manager: portage-2.2.23
Signed-off-by: Justin Lecher <jlec@gentoo.org>
---
 dev-python/nbconvert/Manifest               |  1 +
 dev-python/nbconvert/nbconvert-4.1.0.ebuild | 78 +++++++++++++++++++++++++++++
 2 files changed, 79 insertions(+)
 create mode 100644 dev-python/nbconvert/nbconvert-4.1.0.ebuild

diff --git a/dev-python/nbconvert/Manifest b/dev-python/nbconvert/Manifest
index 688b474dc..e1ad5fef7 100644
--- a/dev-python/nbconvert/Manifest
+++ b/dev-python/nbconvert/Manifest
@@ -1 +1,2 @@
 DIST nbconvert-4.0.0.tar.gz 260424 SHA256 472ad15d1a71f1ef00c4094c11bb93638858fc89fb2c5838b3aa6b67d981b437 SHA512 0f495d75121815282ffe9f67ebf0818ca09790e2d8745e04635c368932d11db07a07d91410b81366a29d3d17ffb98b1ac1bbae18268d448ba494ca2685ec85e6 WHIRLPOOL 1de760f6fc5392fa0dd50834fbf8417c5c3389f904724ba3c4d68df24e44ed84789256193c2fb625527caec2f45893f521e9f86de64a8e3686beef6fb824386e
+DIST nbconvert-4.1.0.tar.gz 263948 SHA256 e0296e45293dd127d028f678e3b6aba3f1db3283a134178bdb49eea402d4cf1c SHA512 9761cf8cdf206bd8f27c666d7b520cbd7d805353cf46b212b46ee6053b47ec6728a5926dfe59acef109c8770580c41d51aa5b943a27e72bccecc68a7d7b68bfb WHIRLPOOL 9cc27a45b00ee9914674cd14a279be1691eb8a8538803bdda127513f56dd0ce53b10745f305f8fb82abd2d19efe7c1b0284bf05f8088360d2def6c97db0c1c6e
diff --git a/dev-python/nbconvert/nbconvert-4.1.0.ebuild b/dev-python/nbconvert/nbconvert-4.1.0.ebuild
new file mode 100644
index 000000000..0eab8bc2a
--- /dev/null
+++ b/dev-python/nbconvert/nbconvert-4.1.0.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 python3_{3,4,5} )
+
+inherit distutils-r1
+
+MY_PN="nbconvert"
+
+DESCRIPTION="Converting Jupyter Notebooks"
+HOMEPAGE="http://jupyter.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+KEYWORDS="~amd64 ~x86"
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="doc test"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-4.0.0-docs-Makefile.patch
+)
+
+RDEPEND="
+	dev-python/jupyter_core[${PYTHON_USEDEP}]
+	dev-python/nbformat[${PYTHON_USEDEP}]
+	dev-python/mistune[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/traitlets[${PYTHON_USEDEP}]
+	"
+DEPEND="${RDEPEND}
+	doc? (
+		dev-python/ipython[${PYTHON_USEDEP}]
+		dev-python/jupyter_client[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		app-text/pandoc
+	)
+	test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/coverage[${PYTHON_USEDEP}]
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+	)
+	"
+
+python_prepare_all() {
+	# Prevent un-needed download during build
+	if use doc; then
+		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	distutils_install_for_testing
+	cd "${TEST_DIR}"/lib || die
+	nosetests --with-coverage --cover-package=nbconvert nbconvert || die
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( docs/build/html/. )
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	if ! has_version app-text/pandoc ; then
+		einfo "Pandoc is required for converting to formats other than Python,"
+		einfo "HTML, and Markdown. If you need this functionality, install"
+		einfo "app-text/pandoc."
+	fi
+}
-- 
cgit v1.2.3-65-gdbad