# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

PYTHON_COMPAT=( python2_7 pypy )
inherit check-reqs pax-utils python-any-r1 toolchain-funcs

# note: remember to update this to newest dev-lang/python:2.7 on bump
CPY_PATCHSET_VERSION="2.7.15"
MY_P=pypy2.7-v${PV}

DESCRIPTION="A fast, compliant alternative implementation of the Python language"
HOMEPAGE="http://pypy.org/"
SRC_URI="https://bitbucket.org/pypy/pypy/downloads/${MY_P}-src.tar.bz2"

LICENSE="MIT"
# pypy -c 'import sysconfig; print sysconfig.get_config_var("SOABI")'
# pypy 7.0.0: install directory changed to 'pypy2.7'
SLOT="0/41-py27"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="bzip2 +jit libressl low-memory ncurses sandbox cpu_flags_x86_sse2 test"

DEPEND=">=sys-libs/zlib-1.1.3:0=
	virtual/libffi:0=
	virtual/libintl:0=
	dev-libs/expat:0=
	bzip2? ( app-arch/bzip2:0= )
	!libressl? ( dev-libs/openssl:0=[-bindist] )
	libressl? ( dev-libs/libressl:0= )
	ncurses? ( sys-libs/ncurses:0= )
	app-arch/lzip
	${PYTHON_DEPS}"

S="${WORKDIR}/${MY_P}-src"

pkg_pretend() {
	if [[ ${MERGE_TYPE} != binary ]]; then
		if use low-memory; then
			if ! python_is_installed pypy; then
				eerror "USE=low-memory requires a (possibly old) version of dev-python/pypy"
				eerror "or dev-python/pypy-bin being installed. Please install it using e.g.:"
				eerror
				eerror "  $ emerge -1v dev-python/pypy-bin"
				eerror
				eerror "before attempting to build dev-python/pypy[low-memory]."
				die "dev-python/pypy-bin (or dev-python/pypy) needs to be installed for USE=low-memory"
			fi

			CHECKREQS_MEMORY="1750M"
			use amd64 && CHECKREQS_MEMORY="3500M"
		else
			CHECKREQS_MEMORY="3G"
			use amd64 && CHECKREQS_MEMORY="6G"
		fi

		check-reqs_pkg_pretend
	fi

	[[ ${PYPY_BINPKG_STORE} ]] || die 'PYPY_BINPKG_STORE unset, wtf?!'
}

pkg_setup() {
	if [[ ${MERGE_TYPE} != binary ]]; then
		pkg_pretend

		if python_is_installed pypy; then
			if [[ ! ${EPYTHON} || ${EPYTHON} == pypy ]] || use low-memory; then
				einfo "Using already-installed PyPy to perform the translation."
				local EPYTHON=pypy
			else
				einfo "Using ${EPYTHON} to perform the translation. Please note that upstream"
				einfo "recommends using PyPy for that. If you wish to do so, please unset"
				einfo "the EPYTHON variable."
			fi
		fi

		python-any-r1_pkg_setup

		local cpu
		if use amd64; then
			# common denominator between Intel & AMD
			cpu='x86-64'
		elif use x86; then
			if use cpu_flags_x86_sse2; then
				# lowest with SSE2
				cpu='pentium-m'
			else
				# lowest with SSE, compat. with athlon-xp
				# TODO: do we want to support something older?
				cpu='pentium3'
			fi
		else
			die "Unsupported arch ${ARCH}"
		fi

		export CFLAGS="-march=${cpu} -mtune=generic -O2 -pipe"
		export CXXFLAGS=${CFLAGS}

		elog "CFLAGS: ${CFLAGS}"
	fi
}

src_prepare() {
	eapply "${FILESDIR}"/5.9.0-shared-lib.patch	# 517002

	eapply_user
}

src_configure() {
	tc-export CC

	local jit_backend
	if use jit; then
		jit_backend='--jit-backend='

		# We only need the explicit sse2 switch for x86.
		# On other arches we can rely on autodetection which uses
		# compiler macros. Plus, --jit-backend= doesn't accept all
		# the modern values...

		if use x86; then
			if use cpu_flags_x86_sse2; then
				jit_backend+=x86
			else
				jit_backend+=x86-without-sse2
			fi
		else
			jit_backend+=auto
		fi
	fi

	local args=(
		--shared
		$(usex jit -Ojit -O2)
		$(usex sandbox --sandbox '')

		${jit_backend}

		pypy/goal/targetpypystandalone
	)

	# Avoid linking against libraries disabled by use flags
	local opts=(
		bzip2:bz2
		ncurses:_minimal_curses
	)

	local opt
	for opt in "${opts[@]}"; do
		local flag=${opt%:*}
		local mod=${opt#*:}

		args+=(
			$(usex ${flag} --withmod --withoutmod)-${mod}
		)
	done

	local interp=( "${PYTHON}" )
	if use low-memory; then
		interp=( env PYPY_GC_MAX_DELTA=200MB
			"${PYTHON}" --jit loop_longevity=300 )
	fi

	# translate into the C sources
	# we're going to make them ourselves since otherwise pypy does not
	# free up the unneeded memory before spawning the compiler
	set -- "${interp[@]}" rpython/bin/rpython --batch --source "${args[@]}"
	echo -e "\033[1m${@}\033[0m"
	"${@}" || die "translation failed"
}

src_compile() {
	emake -C "${T}"/usession*-0/testing_1

	# copy back to make sys.prefix happy
	cp -p "${T}"/usession*-0/testing_1/{pypy-c,libpypy-c.so} . || die
	pax-mark m pypy-c libpypy-c.so
}

src_install() {
	local flags=( bzip2 jit libressl ncurses sandbox )
	use x86 && flags+=( cpu_flags_x86_sse2 )
	local f suffix="-${ARCH}"

	for f in ${flags[@]}; do
		use ${f} && suffix+="+${f#cpu_flags_x86_}"
	done

	local BIN_P=pypy-bin-${PV}

	einfo "Zipping PyPy ..."
	mkdir "${BIN_P}${suffix}"{,/include} || die
	mv pypy-c libpypy-c.so "${BIN_P}${suffix}"/ || die
	mv include/pypy_* "${BIN_P}${suffix}"/include/ || die
	chmod +x "${BIN_P}${suffix}"/pypy-c || die

	tar -cf "${BIN_P}${suffix}.tar" "${BIN_P}${suffix}" || die
	lzip -v9 "${BIN_P}${suffix}.tar" || die
}

# Yup, very hacky.
pkg_preinst() {
	# integrity check.
	[[ ${PYPY_BINPKG_STORE} ]] || die 'PYPY_BINPKG_STORE unset, wtf?!'
	mkdir -p "${ROOT%/}${PYPY_BINPKG_STORE}" || die
	mv "${S}"/*.tar.lz "${ROOT%/}${PYPY_BINPKG_STORE}" || die
}