summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAndreas Sturmlechner <asturm@gentoo.org>2017-12-27 22:31:20 +0100
committerAndreas Sturmlechner <asturm@gentoo.org>2017-12-28 00:25:13 +0100
commit08329f9a4969ee02b02e9d052e47a850106018f2 (patch)
treeb42b8cc1db9fbc99b13cf619ccbf0d0f13693fd7
parentdev-libs/quazip: Prepare rdeps for USE=qt4,qt5 removal (diff)
downloadgentoo-08329f9a4969ee02b02e9d052e47a850106018f2.tar.gz
gentoo-08329f9a4969ee02b02e9d052e47a850106018f2.tar.bz2
gentoo-08329f9a4969ee02b02e9d052e47a850106018f2.zip
dev-libs/quazip: Drop USE=qt4,qt5,test
Bug: https://bugs.gentoo.org/641222 Package-Manager: Portage-2.3.19, Repoman-2.3.6
-rw-r--r--dev-libs/quazip/quazip-0.7.3-r1.ebuild51
1 files changed, 51 insertions, 0 deletions
diff --git a/dev-libs/quazip/quazip-0.7.3-r1.ebuild b/dev-libs/quazip/quazip-0.7.3-r1.ebuild
new file mode 100644
index 00000000000..831f129d5a6
--- /dev/null
+++ b/dev-libs/quazip/quazip-0.7.3-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils flag-o-matic qmake-utils
+
+DESCRIPTION="Simple C++ wrapper over Gilles Vollant's ZIP/UNZIP package"
+HOMEPAGE="http://quazip.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1-with-linking-exception"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="static-libs"
+
+RDEPEND="
+ dev-qt/qtcore:5
+ dev-qt/qtnetwork:5
+ sys-libs/zlib[minizip]
+"
+DEPEND="${RDEPEND}"
+
+DOCS=( NEWS.txt README.txt )
+HTML_DOCS=( doc/html/. )
+
+src_prepare() {
+ if ! use static-libs ; then
+ sed -e "/^install/ s/quazip_static//" -i quazip/CMakeLists.txt || die
+ fi
+ cmake-utils_src_prepare
+}
+
+src_configure() {
+ local libdir=$(get_libdir)
+ local -x CXXFLAGS="${CXXFLAGS}"
+ append-cxxflags -std=c++11 -fPIC
+
+ local mycmakeargs=(
+ -DBUILD_WITH_QT4=OFF
+ -DLIB_SUFFIX=${libdir/lib/}
+ )
+ cmake-utils_src_configure
+}
+
+src_install() {
+ cmake-utils_src_install
+
+ # compatibility with not yet fixed rdeps (Gentoo bug #598136)
+ dosym libquazip5.so /usr/$(get_libdir)/libquazip.so
+}