summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorMichael Seifert <m.seifert@digitalernachschub.de>2018-10-08 10:19:48 +0200
committerMichał Górny <mgorny@gentoo.org>2018-10-18 21:39:53 +0200
commit119ea925432aa8fe439415d0f6cc07906d634cba (patch)
treec043ea166ecc263956b850df8ef0a63fbcfd57e3
parentapp-emulation/fuse: remove old version 1.5.3 (diff)
downloadgentoo-119ea925432aa8fe439415d0f6cc07906d634cba.tar.gz
gentoo-119ea925432aa8fe439415d0f6cc07906d634cba.tar.bz2
gentoo-119ea925432aa8fe439415d0f6cc07906d634cba.zip
dev-python/argon2_cffi: New ebuild
Closes: https://bugs.gentoo.org/643904 Signed-off-by: Michael Seifert <m.seifert@digitalernachschub.de> Closes: https://github.com/gentoo/gentoo/pull/10104 Signed-off-by: Michał Górny <mgorny@gentoo.org>
-rw-r--r--dev-python/argon2_cffi/Manifest1
-rw-r--r--dev-python/argon2_cffi/argon2_cffi-18.3.0.ebuild51
-rw-r--r--dev-python/argon2_cffi/metadata.xml21
3 files changed, 73 insertions, 0 deletions
diff --git a/dev-python/argon2_cffi/Manifest b/dev-python/argon2_cffi/Manifest
new file mode 100644
index 00000000000..c1d9e9785d0
--- /dev/null
+++ b/dev-python/argon2_cffi/Manifest
@@ -0,0 +1 @@
+DIST argon2_cffi-18.3.0.tar.gz 1806363 BLAKE2B b60711ac929792ccd87a948f213288d4d47f45bf4bb52a1f6ac698d229e0953e37186c4e7d140231c205777be2fe31982a808cc676c13f12fe8602381665b74c SHA512 482a97ca17a23e4c1f93a0642e5aab1f2556d10f8a24d74afd051e6b58533c4767465abbfe8f1d39c150c5dbb191ad138d08e70633721753c7d317dbaf1cb375
diff --git a/dev-python/argon2_cffi/argon2_cffi-18.3.0.ebuild b/dev-python/argon2_cffi/argon2_cffi-18.3.0.ebuild
new file mode 100644
index 00000000000..14c6988af3e
--- /dev/null
+++ b/dev-python/argon2_cffi/argon2_cffi-18.3.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{2_7,3_{4,5,6,7}} pypy pypy3 )
+inherit distutils-r1
+
+DESCRIPTION="CFFI bindings to the Argon2 password hashing library"
+HOMEPAGE="https://github.com/hynek/argon2_cffi"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+COMMON_DEPEND="
+ ~app-crypt/argon2-20171227:=
+ dev-python/six[${PYTHON_USEDEP}]
+ virtual/python-cffi[${PYTHON_USEDEP}]
+ virtual/python-enum34[${PYTHON_USEDEP}]
+"
+RDEPEND="${COMMON_DEPEND}"
+DEPEND="${COMMON_DEPEND}
+ dev-python/setuptools[${PYTHON_USEDEP}]
+ doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+ test? (
+ dev-python/hypothesis[${PYTHON_USEDEP}]
+ >=dev-python/pytest-3.0[${PYTHON_USEDEP}]
+ )
+"
+
+DOCS=( AUTHORS.rst CHANGELOG.rst FAQ.rst README.rst )
+
+python_configure_all() {
+ export ARGON2_CFFI_USE_SYSTEM=1
+}
+
+python_compile_all() {
+ use doc && emake -C docs html
+}
+
+python_test() {
+ pytest -vv || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+ use doc && local HTML_DOCS=( docs/_build/html/. )
+ distutils-r1_python_install_all
+}
diff --git a/dev-python/argon2_cffi/metadata.xml b/dev-python/argon2_cffi/metadata.xml
new file mode 100644
index 00000000000..3404c181dec
--- /dev/null
+++ b/dev-python/argon2_cffi/metadata.xml
@@ -0,0 +1,21 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+ <maintainer type="person">
+ <email>m.seifert@digitalernachschub.de</email>
+ <name>Michael Seifert</name>
+ </maintainer>
+ <maintainer type="project">
+ <email>python@gentoo.org</email>
+ <name>Python</name>
+ </maintainer>
+ <maintainer type="project">
+ <email>proxy-maint@gentoo.org</email>
+ <name>Proxy Maintainers</name>
+ </maintainer>
+ <longdescription>CFFI bindings for the Argon2 password hashing library.</longdescription>
+ <upstream>
+ <remote-id type="pypi">argon2_cffi</remote-id>
+ <remote-id type="github">hynek/argon2_cffi</remote-id>
+ </upstream>
+</pkgmetadata>