app-cdr/dolphin-plugins-mountiso: 20.08.3 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 66 insertions, 0 deletions

diff --git a/app-cdr/dolphin-plugins-mountiso/Manifest b/app-cdr/dolphin-plugins-mountiso/Manifest
index 39d905585ff6..ef12cb01045d 100644
--- a/app-cdr/dolphin-plugins-mountiso/Manifest
+++ b/app-cdr/dolphin-plugins-mountiso/Manifest
@@ -1 +1,2 @@
 DIST dolphin-plugins-20.08.2.tar.xz 229440 BLAKE2B 53d8c1c16a9ba5abcb3164cd4d30769506c4dfaaab148eed070185b17d00fc5583b5dbb28b163794e187da8e0d64435d904fb8ffc99e8625b8096bd96dbd94ab SHA512 c854c3a7c918c9a8be1da41d9d4f8039b9c8e38ba4782ae064ea688fed51966b9749ce009b2f96bcac0f92dbe36e5f826a45265eb29e3f2ec4740902485099d7
+DIST dolphin-plugins-20.08.3.tar.xz 230272 BLAKE2B 1978ffebe88d95350cac0892c56e127507b6ddd6d5675bca8f420990552e20ff271e6f5742a2bdeff685c82464e70177ac83e5e9368547eb175a3e8133d77624 SHA512 2010be567ef025375caac92e90c0259faea1eb58bdbc55e441e42a10af68b6313391707a7f6b6b10285ba80dcbdee92468fa5088970eb98d4ea8afea145976d9
diff --git a/app-cdr/dolphin-plugins-mountiso/dolphin-plugins-mountiso-20.08.3.ebuild b/app-cdr/dolphin-plugins-mountiso/dolphin-plugins-mountiso-20.08.3.ebuild
new file mode 100644
index 000000000000..b3a107999f79
--- /dev/null
+++ b/app-cdr/dolphin-plugins-mountiso/dolphin-plugins-mountiso-20.08.3.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="false"
+KDE_RELEASE_SERVICE="true"
+KDE_ORG_CATEGORY="sdk"
+KDE_ORG_NAME="dolphin-plugins"
+MY_PLUGIN_NAME="mountiso"
+KFMIN=5.74.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.1
+inherit ecm kde.org
+
+DESCRIPTION="Dolphin plugin for ISO loopback device mounting"
+HOMEPAGE="https://apps.kde.org/en/dolphin_plugins"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-apps/dolphin-${PVCUT}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	ecm_src_prepare
+	# kxmlgui, qtnetwork only required by dropbox
+	ecm_punt_bogus_dep Qt5 Network
+	ecm_punt_bogus_dep KF5 XmlGui
+	# delete non-${PN} translations
+	if [[ ${KDE_BUILD_TYPE} = release ]]; then
+		find po -type f -name "*po" -and -not -name "*${MY_PLUGIN_NAME}plugin" -delete || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_${MY_PLUGIN_NAME}=ON
+		-DBUILD_bazaar=OFF
+		-DBUILD_dropbox=OFF
+		-DBUILD_git=OFF
+		-DBUILD_hg=OFF
+		-DBUILD_svn=OFF
+	)
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+	rm "${D}"/usr/share/metainfo/org.kde.dolphin-plugins.metainfo.xml || die
+}