summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorDavid Seifert <soap@gentoo.org>2019-04-16 11:50:19 +0200
committerDavid Seifert <soap@gentoo.org>2019-04-16 11:50:19 +0200
commit387d59f210b1b228193b462b3c2c5668eca0f38d (patch)
treee13acdd7541c99e37a37f02b195f997bb7f733c2
parentnet-libs/http-parser: Old (diff)
downloadgentoo-387d59f210b1b228193b462b3c2c5668eca0f38d.tar.gz
gentoo-387d59f210b1b228193b462b3c2c5668eca0f38d.tar.bz2
gentoo-387d59f210b1b228193b462b3c2c5668eca0f38d.zip
net-mail/libpst: Revbump for Boost::Python changes
Bug: https://bugs.gentoo.org/683378 Package-Manager: Portage-2.3.62, Repoman-2.3.12 Signed-off-by: David Seifert <soap@gentoo.org>
-rw-r--r--net-mail/libpst/libpst-0.6.66-r2.ebuild70
-rw-r--r--profiles/package.mask1
2 files changed, 71 insertions, 0 deletions
diff --git a/net-mail/libpst/libpst-0.6.66-r2.ebuild b/net-mail/libpst/libpst-0.6.66-r2.ebuild
new file mode 100644
index 00000000000..bb12628b7a3
--- /dev/null
+++ b/net-mail/libpst/libpst-0.6.66-r2.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit autotools python-single-r1
+
+DESCRIPTION="Tools and library for reading Outlook files (.pst format)"
+HOMEPAGE="https://www.five-ten-sg.com/libpst/"
+SRC_URI="https://www.five-ten-sg.com/${PN}/packages/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="debug dii doc python static-libs"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+ gnome-extra/libgsf:=
+ dii? ( media-gfx/imagemagick:=[png] )
+ python? (
+ ${PYTHON_DEPS}
+ >=dev-libs/boost-1.70:=[python,${PYTHON_USEDEP}]
+ )"
+DEPEND="${RDEPEND}
+ virtual/libiconv
+ virtual/pkgconfig
+ dii? ( media-libs/gd[png] )"
+
+pkg_setup() {
+ use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+ # don't build the static python library
+ eapply "${FILESDIR}"/${PN}-0.6.52-no-static-python-lib.patch
+
+ # fix pkgconfig file for static linking
+ eapply "${FILESDIR}"/${PN}-0.6.53-pkgconfig-static.patch
+
+ # conditionally install the extra documentation
+ if ! use doc; then
+ sed -i -e "/SUBDIRS/s: html::" Makefile.am || die
+ fi
+
+ # don't install duplicate docs
+ sed -i -e "/^html_DATA =/d" Makefile.am || die
+
+ eapply_user
+
+ mv configure.{in,ac} || die
+ eautoreconf
+}
+
+src_configure() {
+ econf \
+ --enable-libpst-shared \
+ $(use_enable debug pst-debug) \
+ $(use_enable dii) \
+ $(use_enable python) \
+ $(use_enable static-libs static) \
+ $(use_with python boost-python "boost_${EPYTHON/./}")
+}
+
+src_install() {
+ default
+ find "${D}" -name '*.la' -delete || die
+}
diff --git a/profiles/package.mask b/profiles/package.mask
index d686f7d4241..75602025ead 100644
--- a/profiles/package.mask
+++ b/profiles/package.mask
@@ -60,6 +60,7 @@ dev-util/cucumber-expressions:5.0
# Masked for testing, Bug #653878.
>=dev-libs/boost-1.70.0
>=dev-util/boost-build-1.70.0
+>=net-mail/libpst-0.6.66-r2
# Patrice Clement <monsieurp@gentoo.org> (14 Apr 2019)
# Old, unmaintained and sometimes abandoned Java libraries/programs.