summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorMichał Górny <mgorny@gentoo.org>2022-03-19 18:32:45 +0100
committerMichał Górny <mgorny@gentoo.org>2022-03-19 19:49:19 +0100
commit39ec8df77b77081bd75b011dcda188568fb07de2 (patch)
tree18f9c4aaca2f9830ff06dc54b6ef2361d18b139b
parentsys-kernel/vanilla-kernel: Bump to 5.10.107 (diff)
downloadgentoo-39ec8df77b77081bd75b011dcda188568fb07de2.tar.gz
gentoo-39ec8df77b77081bd75b011dcda188568fb07de2.tar.bz2
gentoo-39ec8df77b77081bd75b011dcda188568fb07de2.zip
sys-kernel/gentoo-kernel: Bump to 5.10.107
Signed-off-by: Michał Górny <mgorny@gentoo.org>
-rw-r--r--sys-kernel/gentoo-kernel/Manifest2
-rw-r--r--sys-kernel/gentoo-kernel/gentoo-kernel-5.10.107.ebuild131
2 files changed, 133 insertions, 0 deletions
diff --git a/sys-kernel/gentoo-kernel/Manifest b/sys-kernel/gentoo-kernel/Manifest
index aa12070febb4..5d457d1b9fbb 100644
--- a/sys-kernel/gentoo-kernel/Manifest
+++ b/sys-kernel/gentoo-kernel/Manifest
@@ -6,6 +6,8 @@ DIST genpatches-5.10-112.base.tar.xz 3129120 BLAKE2B 89e3a95facb0b67c8d4a9157c8e
DIST genpatches-5.10-112.extras.tar.xz 3876 BLAKE2B 3a5372d5e9a4105d6f7fea19c5defdc823430c823bf89131990c9af1785e8943dd3d9175a5cf591f335bcfd3bc23be1ce928d95f574b895e5a3c949c65e858ef SHA512 69950dc907bc047052e13ce01f1b1eb465d58d101bee75789300cc8f41f3d11632be220831f4b908b48659eac2b13867ef8d77eb3564dc7fc7d712ef23e313cc
DIST genpatches-5.10-114.base.tar.xz 3146016 BLAKE2B 838970c9a36b0d50d50b3142c156535f4431cf1af871e689fcbf8be0a5d51e8113d11ddd49467af5959032787c19810b9b114b4b9742ab616a7018b02d8b5a33 SHA512 b4b8ce4fa4f98acc3a4a9f7529322deda0e9d5848fb3d957153d305e2d013883fa4518e12f4cc8579076325b62b267df8cc1844cbd3634151df9212729cc0480
DIST genpatches-5.10-114.extras.tar.xz 3876 BLAKE2B facdf4de4c5eeaa5a419a23d9254633bac3f51ae545fdbdfa46a312fc63cb7af80fb11685198a463d4543ea86925c3c51402c95528682b6cdc951399d8eb12c4 SHA512 30fe543625734215cae6eb2cc5c3fc24d80207cd9b5145f4f7fbf65f11c31fbba1b21c034f53a20ee724998987a2223be39272590fbaef49bb61136de471dcc6
+DIST genpatches-5.10-115.base.tar.xz 3150232 BLAKE2B 1cfcbf4855ac4eea3331ab7696d68b435a8bf9e72df78ed4f8497e81086688fcf9502817651ad39b1b83e507881d90a5ddf791e2e3882c9166e45fbb8fd0420a SHA512 51bcb051cb3b4120f4286873527d0e3782e63fb0ffb1e3032ada4d4b55e655f00d42021a5ac5b9fde12d7467c175d3d1ec74b9876f7f39d14f0727d61cce5ff9
+DIST genpatches-5.10-115.extras.tar.xz 3872 BLAKE2B ec14f023762a3c235648ec52e895c27cd472c4a9c2304ce0519b3526aedd8ae83b98600f4b0724730d34aec02bd4e00857289007894dff282e2eaed107431359 SHA512 cacc5aafb79c02e32059fb0f820897a1c688e93aca64ac4c8c3e700dca747a052541c678dc5acb51f65bb343cb1ab9dc359109b4fcc30b08a28fd852673bd104
DIST genpatches-5.15-27.base.tar.xz 1109928 BLAKE2B 4f6113b0b1c378bec52a94c420265c3454b4b46dca3ebe25cf9bbd3d65761ac2d1bf14a5f60afcd974ceb319036c4e84adf247632bd93174dc144779d1169f8d SHA512 77f39c84e78e64ed221a813292a3391ba1252c7bb5206d78f2e2c4b8fa3e6f082cd327ac45c30851840e62288f2958470d271d9ad2afbda2fa9f21d4b4f07c56
DIST genpatches-5.15-27.extras.tar.xz 3872 BLAKE2B fc757f0d4fcba7b53aea34736b7a0cc0a7ca14b73bd9c249ad2c89b283475f3b53e4391870a239bd329f00e55c056f05cfc270ad00d57acd69cc26331cc20931 SHA512 102dc6ec977e184ec07cc3cdc2a39285f291bd3e3a344b5e53935f90319efcb5ca70ea1936d5d37ffe03f66148aad4e240508e3cf212d483abe145c21e6818c3
DIST genpatches-5.15-29.base.tar.xz 1228644 BLAKE2B af3556b699c911adc605d438be870f2bba25e79c24908cc8ef6e130e238ada7f415faab020a2cad99780c99e9ce0e8d2f69784883a7ad6596f76db55f0b32f93 SHA512 ee152e485e0fd21b9f350fae7d492a72408b6b16f2abbdc73f62d22ce402e59e83e2ce23c4940dcfc914c8f2ee411524b590745693cebcf60237c64b0fc7a76e
diff --git a/sys-kernel/gentoo-kernel/gentoo-kernel-5.10.107.ebuild b/sys-kernel/gentoo-kernel/gentoo-kernel-5.10.107.ebuild
new file mode 100644
index 000000000000..ed8b3a5c0422
--- /dev/null
+++ b/sys-kernel/gentoo-kernel/gentoo-kernel-5.10.107.ebuild
@@ -0,0 +1,131 @@
+# Copyright 2020-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-build toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 8 ))
+# https://koji.fedoraproject.org/koji/packageinfo?packageID=8
+CONFIG_VER=5.10.12
+CONFIG_HASH=836165dd2dff34e4f2c47ca8f9c803002c1e6530
+GENTOO_CONFIG_VER=g1
+
+DESCRIPTION="Linux kernel built with Gentoo patches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+ https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+ https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+ https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+ https://github.com/mgorny/gentoo-kernel-config/archive/${GENTOO_CONFIG_VER}.tar.gz
+ -> gentoo-kernel-config-${GENTOO_CONFIG_VER}.tar.gz
+ amd64? (
+ https://src.fedoraproject.org/rpms/kernel/raw/${CONFIG_HASH}/f/kernel-x86_64-fedora.config
+ -> kernel-x86_64-fedora.config.${CONFIG_VER}
+ )
+ arm64? (
+ https://src.fedoraproject.org/rpms/kernel/raw/${CONFIG_HASH}/f/kernel-aarch64-fedora.config
+ -> kernel-aarch64-fedora.config.${CONFIG_VER}
+ )
+ ppc64? (
+ https://src.fedoraproject.org/rpms/kernel/raw/${CONFIG_HASH}/f/kernel-ppc64le-fedora.config
+ -> kernel-ppc64le-fedora.config.${CONFIG_VER}
+ )
+ x86? (
+ https://src.fedoraproject.org/rpms/kernel/raw/${CONFIG_HASH}/f/kernel-i686-fedora.config
+ -> kernel-i686-fedora.config.${CONFIG_VER}
+ )
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="debug hardened"
+REQUIRED_USE="arm? ( savedconfig )"
+
+RDEPEND="
+ !sys-kernel/gentoo-kernel-bin:${SLOT}
+"
+BDEPEND="
+ debug? ( dev-util/pahole )
+"
+PDEPEND="
+ >=virtual/dist-kernel-${PV}
+"
+
+QA_FLAGS_IGNORED="
+ usr/src/linux-.*/scripts/gcc-plugins/.*.so
+ usr/src/linux-.*/vmlinux
+"
+
+src_prepare() {
+ local PATCHES=(
+ # meh, genpatches have no directory
+ "${WORKDIR}"/*.patch
+ )
+ default
+
+ local biendian=false
+
+ # prepare the default config
+ case ${ARCH} in
+ amd64)
+ cp "${DISTDIR}/kernel-x86_64-fedora.config.${CONFIG_VER}" .config || die
+ ;;
+ arm)
+ return
+ ;;
+ arm64)
+ cp "${DISTDIR}/kernel-aarch64-fedora.config.${CONFIG_VER}" .config || die
+ biendian=true
+ ;;
+ hppa)
+ return
+ ;;
+ ppc)
+ # assume powermac/powerbook defconfig
+ # we still package.use.force savedconfig
+ cp "${WORKDIR}/${MY_P}/arch/powerpc/configs/pmac32_defconfig" .config || die
+ ;;
+ ppc64)
+ cp "${DISTDIR}/kernel-ppc64le-fedora.config.${CONFIG_VER}" .config || die
+ biendian=true
+ ;;
+ x86)
+ cp "${DISTDIR}/kernel-i686-fedora.config.${CONFIG_VER}" .config || die
+ ;;
+ *)
+ die "Unsupported arch ${ARCH}"
+ ;;
+ esac
+
+ local myversion="-gentoo-dist"
+ use hardened && myversion+="-hardened"
+ echo "CONFIG_LOCALVERSION=\"${myversion}\"" > "${T}"/version.config || die
+ local dist_conf_path="${WORKDIR}/gentoo-kernel-config-${GENTOO_CONFIG_VER}"
+
+ local merge_configs=(
+ "${T}"/version.config
+ "${dist_conf_path}"/base.config
+ )
+ use debug || merge_configs+=(
+ "${dist_conf_path}"/no-debug.config
+ )
+ if use hardened; then
+ merge_configs+=( "${dist_conf_path}"/hardened-base.config )
+
+ tc-is-gcc && merge_configs+=( "${dist_conf_path}"/hardened-gcc-plugins.config )
+
+ if [[ -f "${dist_conf_path}/hardened-${ARCH}.config" ]]; then
+ merge_configs+=( "${dist_conf_path}/hardened-${ARCH}.config" )
+ fi
+ fi
+
+ # this covers ppc64 and aarch64_be only for now
+ if [[ ${biendian} == true && $(tc-endian) == big ]]; then
+ merge_configs+=( "${dist_conf_path}/big-endian.config" )
+ fi
+
+ kernel-build_merge_configs "${merge_configs[@]}"
+}