summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAndreas Sturmlechner <asturm@gentoo.org>2018-11-24 22:45:14 +0100
committerAndreas Sturmlechner <asturm@gentoo.org>2018-11-25 00:17:05 +0100
commit4729f987cbd6a62987869470ea9b3f0d7381e235 (patch)
treeefdced8e5e70bf83148b3745a46270dc4e277e8e
parentmedia-plugins/audacious-plugins: Drop 3.10 (r0) (diff)
downloadgentoo-4729f987cbd6a62987869470ea9b3f0d7381e235.tar.gz
gentoo-4729f987cbd6a62987869470ea9b3f0d7381e235.tar.bz2
gentoo-4729f987cbd6a62987869470ea9b3f0d7381e235.zip
media-sound/audacious: Re-add USE qt5
Qt5 version is not yet feature complete. Disable po dir if USE !nls Closes: https://bugs.gentoo.org/512698 Package-Manager: Portage-2.3.52, Repoman-2.3.12 Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
-rw-r--r--media-sound/audacious/audacious-3.10-r1.ebuild98
-rw-r--r--media-sound/audacious/audacious-9999.ebuild11
2 files changed, 103 insertions, 6 deletions
diff --git a/media-sound/audacious/audacious-3.10-r1.ebuild b/media-sound/audacious/audacious-3.10-r1.ebuild
new file mode 100644
index 00000000000..624ecd083fa
--- /dev/null
+++ b/media-sound/audacious/audacious-3.10-r1.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+MY_P="${P/_/-}"
+
+if [[ ${PV} == *9999 ]]; then
+ inherit autotools git-r3
+ EGIT_REPO_URI="https://github.com/audacious-media-player/audacious.git"
+else
+ SRC_URI="https://distfiles.audacious-media-player.org/${MY_P}.tar.bz2"
+ KEYWORDS="~amd64 ~x86"
+fi
+inherit gnome2-utils xdg-utils
+
+DESCRIPTION="Lightweight and versatile audio player"
+HOMEPAGE="https://audacious-media-player.org/"
+SRC_URI+=" mirror://gentoo/gentoo_ice-xmms-0.2.tar.bz2"
+
+LICENSE="BSD-2"
+SLOT="0"
+IUSE="nls qt5"
+
+RDEPEND="
+ >=dev-libs/dbus-glib-0.60
+ >=dev-libs/glib-2.28
+ >=x11-libs/cairo-1.2.6
+ >=x11-libs/pango-1.8.0
+ virtual/freedesktop-icon-theme
+ !qt5? ( x11-libs/gtk+:2 )
+ qt5? (
+ dev-qt/qtcore:5
+ dev-qt/qtgui:5
+ dev-qt/qtwidgets:5
+ )
+"
+DEPEND="${RDEPEND}
+ virtual/pkgconfig
+ nls? ( dev-util/intltool )
+"
+PDEPEND="~media-plugins/audacious-plugins-${PV}"
+
+PATCHES=(
+ "${FILESDIR}/${P}-ui-freeze.patch"
+ "${FILESDIR}/${P}-dbus-crash.patch"
+ "${FILESDIR}/${P}-use-after-free.patch"
+ "${FILESDIR}/${P}-volume-slider-boundaries.patch"
+)
+
+S="${WORKDIR}/${MY_P}"
+
+src_unpack() {
+ default
+ [[ ${PV} == *9999 ]] && git-r3_src_unpack
+}
+
+src_prepare() {
+ default
+ if ! use nls; then
+ sed -e "/SUBDIRS/s/ po//" -i Makefile || die # bug #512698
+ fi
+ [[ ${PV} == *9999 ]] && eautoreconf
+}
+
+src_configure() {
+ # D-Bus is a mandatory dependency, remote control,
+ # session management and some plugins depend on this.
+ # Building without D-Bus is *unsupported* and a USE-flag
+ # will not be added due to the bug reports that will result.
+ # Bugs #197894, #199069, #207330, #208606
+ econf \
+ --disable-valgrind \
+ --enable-dbus \
+ $(use_enable nls) \
+ $(use_enable !qt5 gtk) \
+ $(use_enable qt5 qt)
+}
+
+src_install() {
+ default
+
+ # Gentoo_ice skin installation; bug #109772
+ insinto /usr/share/audacious/Skins/gentoo_ice
+ doins -r "${WORKDIR}"/gentoo_ice/.
+ docinto gentoo_ice
+ dodoc "${WORKDIR}"/README
+}
+
+pkg_postinst() {
+ xdg_desktop_database_update
+ gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+ xdg_desktop_database_update
+ gnome2_icon_cache_update
+}
diff --git a/media-sound/audacious/audacious-9999.ebuild b/media-sound/audacious/audacious-9999.ebuild
index 11547ce4fca..282261cbea5 100644
--- a/media-sound/audacious/audacious-9999.ebuild
+++ b/media-sound/audacious/audacious-9999.ebuild
@@ -3,13 +3,7 @@
EAPI=6
-inherit gnome2-utils xdg-utils
-
MY_P="${P/_/-}"
-S="${WORKDIR}/${MY_P}"
-
-DESCRIPTION="Lightweight and versatile audio player"
-HOMEPAGE="https://audacious-media-player.org/"
if [[ ${PV} == *9999 ]]; then
inherit autotools git-r3
@@ -18,7 +12,10 @@ else
SRC_URI="https://distfiles.audacious-media-player.org/${MY_P}.tar.bz2"
KEYWORDS="~amd64 ~x86"
fi
+inherit gnome2-utils xdg-utils
+DESCRIPTION="Lightweight and versatile audio player"
+HOMEPAGE="https://audacious-media-player.org/"
SRC_URI+=" mirror://gentoo/gentoo_ice-xmms-0.2.tar.bz2"
LICENSE="BSD-2"
@@ -44,6 +41,8 @@ DEPEND="${RDEPEND}
"
PDEPEND="~media-plugins/audacious-plugins-${PV}"
+S="${WORKDIR}/${MY_P}"
+
src_unpack() {
default
[[ ${PV} == *9999 ]] && git-r3_src_unpack