summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorLars Wendler <polynomial-c@gentoo.org>2021-05-11 16:01:38 +0200
committerLars Wendler <polynomial-c@gentoo.org>2021-05-11 16:05:48 +0200
commit57f2bb88b147024eeef9631057fac59f0a77b50a (patch)
tree551d0bab6e589e5855f08857f09849dbe63c524a
parentsys-apps/hdparm: Removed old (diff)
downloadgentoo-57f2bb88b147024eeef9631057fac59f0a77b50a.tar.gz
gentoo-57f2bb88b147024eeef9631057fac59f0a77b50a.tar.bz2
gentoo-57f2bb88b147024eeef9631057fac59f0a77b50a.zip
sys-fs/btrfs-progs: Bump to version 5.12
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>
-rw-r--r--sys-fs/btrfs-progs/Manifest1
-rw-r--r--sys-fs/btrfs-progs/btrfs-progs-5.12.ebuild129
2 files changed, 130 insertions, 0 deletions
diff --git a/sys-fs/btrfs-progs/Manifest b/sys-fs/btrfs-progs/Manifest
index 9664a8a3d2b..24202c4bc5b 100644
--- a/sys-fs/btrfs-progs/Manifest
+++ b/sys-fs/btrfs-progs/Manifest
@@ -1,4 +1,5 @@
DIST btrfs-progs-v5.10.1.tar.xz 2204164 BLAKE2B ed83729754f9abd22d4d2e7ae9a7e90e80be9b63d49a4a9692e20e5939467dbd864834b71495661e1c7a1fca89e253a62fbda37f1d01d2eadecb13f5904f0dd0 SHA512 32e5b8bda1863e34613802db91946f240b2cde21288ff8f95c1807e7afd0a67c5a704aa4d2bc0d7b1ca094de6831adbfec83fe61f74e1caf6d1975be7d972f2d
DIST btrfs-progs-v5.11.1.tar.xz 2213548 BLAKE2B f428e8ffb62f60e6772102f4623b9965edc5d18fa60aa8cb60fd92b4867ee29e3067a6b9d0935c738acce5f0abfc4b88c900121ee233aa881857ed4690e38e3b SHA512 f93a54bd2256851a74fc8e52b26f697bd7bf788cb2481512c92ebf1b9a2f2968b62d680f9f000d6162bd6f22b5d632b2149a88adad8c489e1332f810b439da90
DIST btrfs-progs-v5.11.tar.xz 2212292 BLAKE2B e19933e1c0d3f80db931554c1cb4b1d25c5b2f2c5ea0ec19623696b24d696247536d615d569cc28c9a84b1484e38141945465251272b2d1df2cadde5af4dee88 SHA512 20b10ba0f6978d0cb202f055edf41abeb36b629fd6d5cc7cb9ebc82ef79d2bef31ff7c9681770c7ea7b126cfb4cafd6d610476fd5cc7506189f74dc214445cf0
+DIST btrfs-progs-v5.12.tar.xz 2220396 BLAKE2B be3eaadca7386ab1348c4bef6cf10270a42ac34c8e7e1cb54b9db600fde6a5958cff9453e6c287fba23f928116eeccca5d90f78f9c042b972a3ac66a31566e3b SHA512 af9ab8bf232e0c62cc093d848b95991924cc3a84020fb9c85765a63a1cc132403e784bf18f81b71b2af9daa0038a7b11e578ee7b50d90481a888f7a967a5b197
DIST btrfs-progs-v5.4.1.tar.xz 2107476 BLAKE2B 1ea58f49b0f8185e944010804e544643a2eafeea58fecb480b13095c362350c218f0602fbb43a96705a81befe88ec3e3abe35cc90d4732006479b059aa7fed32 SHA512 56381b37036aecea61b758fb4971abfeda24a387bb3a828f7d54eb068982a37763a8ebe2bcc6be61d6a8bc2057dddcd4754325b236e14d8ec02e58cf711f192f
diff --git a/sys-fs/btrfs-progs/btrfs-progs-5.12.ebuild b/sys-fs/btrfs-progs/btrfs-progs-5.12.ebuild
new file mode 100644
index 00000000000..e7da9aa59cf
--- /dev/null
+++ b/sys-fs/btrfs-progs/btrfs-progs-5.12.ebuild
@@ -0,0 +1,129 @@
+# Copyright 2008-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit bash-completion-r1 python-single-r1
+
+libbtrfs_soname=0
+
+if [[ ${PV} != 9999 ]]; then
+ MY_PV="v${PV/_/-}"
+ [[ "${PV}" = *_rc* ]] || \
+ KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+ SRC_URI="https://www.kernel.org/pub/linux/kernel/people/kdave/${PN}/${PN}-${MY_PV}.tar.xz"
+ S="${WORKDIR}/${PN}-${MY_PV}"
+else
+ WANT_LIBTOOL=none
+ inherit autotools git-r3
+ EGIT_REPO_URI="https://github.com/kdave/btrfs-progs.git"
+ EGIT_BRANCH="devel"
+fi
+
+DESCRIPTION="Btrfs filesystem utilities"
+HOMEPAGE="https://btrfs.wiki.kernel.org"
+
+LICENSE="GPL-2"
+SLOT="0/${libbtrfs_soname}"
+IUSE="+convert doc python reiserfs static static-libs +zstd"
+
+RESTRICT=test # tries to mount repared filesystems
+
+RDEPEND="
+ dev-libs/lzo:2=
+ sys-apps/util-linux:0=[static-libs(+)?]
+ sys-libs/zlib:0=
+ convert? (
+ sys-fs/e2fsprogs:0=
+ sys-libs/e2fsprogs-libs:0=
+ reiserfs? (
+ >=sys-fs/reiserfsprogs-3.6.27
+ )
+ )
+ python? ( ${PYTHON_DEPS} )
+ zstd? ( app-arch/zstd:0= )
+"
+DEPEND="${RDEPEND}
+ convert? ( sys-apps/acl )
+ python? (
+ $(python_gen_cond_dep '
+ dev-python/setuptools[${PYTHON_MULTI_USEDEP}]
+ ')
+ )
+ static? (
+ dev-libs/lzo:2[static-libs(+)]
+ sys-apps/util-linux:0[static-libs(+)]
+ sys-libs/zlib:0[static-libs(+)]
+ convert? (
+ sys-fs/e2fsprogs:0[static-libs(+)]
+ sys-libs/e2fsprogs-libs:0[static-libs(+)]
+ reiserfs? (
+ >=sys-fs/reiserfsprogs-3.6.27[static-libs(+)]
+ )
+ )
+ zstd? ( app-arch/zstd:0[static-libs(+)] )
+ )
+"
+BDEPEND="
+ doc? (
+ || ( >=app-text/asciidoc-8.6.0 dev-ruby/asciidoctor )
+ app-text/docbook-xml-dtd:4.5
+ app-text/xmlto
+ )
+"
+
+if [[ ${PV} == 9999 ]]; then
+ DEPEND+=" sys-devel/gnuconfig"
+fi
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+pkg_setup() {
+ use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+ default
+ if [[ ${PV} == 9999 ]]; then
+ AT_M4DIR=m4 eautoreconf
+ mkdir config || die
+ local automakedir="$(autotools_run_tool --at-output automake --print-libdir)"
+ [[ -e ${automakedir} ]] || die "Could not locate automake directory"
+ ln -s "${automakedir}"/install-sh config/install-sh || die
+ ln -s "${EPREFIX}"/usr/share/gnuconfig/config.guess config/config.guess || die
+ ln -s "${EPREFIX}"/usr/share/gnuconfig/config.sub config/config.sub || die
+ fi
+}
+
+src_configure() {
+ local myeconfargs=(
+ --bindir="${EPREFIX}"/sbin
+ $(use_enable convert)
+ $(use_enable doc documentation)
+ $(use_enable elibc_glibc backtrace)
+ $(use_enable python)
+ $(use_enable static-libs static)
+ $(use_enable zstd)
+ --with-convert=ext2$(usex reiserfs ',reiserfs' '')
+ )
+ econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+ emake V=1 all $(usev static)
+}
+
+src_install() {
+ local makeargs=(
+ $(usex python install_python '')
+ $(usex static install-static '')
+ )
+ emake V=1 DESTDIR="${D}" install "${makeargs[@]}"
+ newbashcomp btrfs-completion btrfs
+ use python && python_optimize
+
+ # install prebuilt subset of manuals
+ use doc || doman Documentation/*.[58]
+}