net-libs/libqmi: 1.26.6 version bump

Closes: https://bugs.gentoo.org/710788
Closes: https://bugs.gentoo.org/762032
Signed-off-by: Craig Andrews <candrews@gentoo.org>
Signed-off-by: Matt Turner <mattst88@gentoo.org>

3 files changed, 67 insertions, 18 deletions

diff --git a/net-libs/libqmi/Manifest b/net-libs/libqmi/Manifest
index 073fbca7bb34..9b7652c8348e 100644
--- a/net-libs/libqmi/Manifest
+++ b/net-libs/libqmi/Manifest
@@ -8,3 +8,4 @@ DIST libqmi-1.18.2.tar.xz 845560 BLAKE2B 732c7385d149073a9cf89a58f0e2977fff593b0
 DIST libqmi-1.20.0.tar.xz 859464 BLAKE2B 146b07b47aa5d40d93ce381aca107ec554918a909aef85b28751228fdcb3a518ffa9479a88b1f17a94f9251a1cff1cb606c4cfd4689e8d5e813a6467f078e5cb SHA512 fceec9aff22942fa64f7a568527033354dc379f347b96c9b37844bbdfb7bfa0936f554402b855c4b191fd63ca488776b94ee69e84502a460e941caddbd648b63
 DIST libqmi-1.20.2.tar.xz 860408 BLAKE2B d6f757c7eb7d93101763714f32dee1bfc4de1f4b58fe2b6f457b938e42175da12ba6070395f06542f4edb9c6b3264ad74a718f7fc58ac25de4f4d5f2692ee123 SHA512 2d1ceda25ad995b27dc20d9b5d85ee23a841c43f33aa68b3543df10cc1da72062e648c1136a2706740659ae2cf8c17373d7c6c6f5f8d075864f47e4fb89d7b50
 DIST libqmi-1.22.2.tar.xz 947124 BLAKE2B 662cf58cb3fe48b5bbe167ac552b12ecff2944d1098e47b5a8c216a65c42c5e5c462f16625c4572e0e27e69a55cdfad76777468a42f8887f5b3984313c70747b SHA512 5785b56a60db8fb2566b6a712a18ec2ae74ce1da257473ab6b7cdea3163298ebee6c60a3158a7041aa759bd717eee4b16d9eeaa6b15d9b6e911bc8c8c44bd3d8
+DIST libqmi-1.26.6.tar.xz 1127552 BLAKE2B 1dba56c867c688c991fde7bb019234a05d77092f0725498d677a7ff620c56e58e17c873c773d96ee2131bfeac8cdbec86dadacd8fcc2f751f4e9a8d2c75efe5b SHA512 6c5e05fc158a085e1f652ff31cef65762c026cb09eb630153fddccb15e19187141e74c79818ebe00a058c5624891981cfce4d56545d4150ebb3b6e8d7bddb5ba
diff --git a/net-libs/libqmi/libqmi-1.26.6.ebuild b/net-libs/libqmi/libqmi-1.26.6.ebuild
new file mode 100644
index 000000000000..51ac0339e070
--- /dev/null
+++ b/net-libs/libqmi/libqmi-1.26.6.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit multilib
+if [[ ${PV} == "9999" ]] ; then
+	inherit git-r3 autotools
+	EGIT_REPO_URI="https://gitlab.freedesktop.org/mobile-broadband/libqmi.git"
+else
+	KEYWORDS="~amd64 ~arm ~arm64 ~mips ~ppc ~ppc64 ~x86"
+	SRC_URI="https://www.freedesktop.org/software/libqmi/${P}.tar.xz"
+fi
+
+DESCRIPTION="Qualcomm MSM (Mobile Station Modem) Interface (QMI) modem protocol library"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/libqmi/ https://gitlab.freedesktop.org/mobile-broadband/libqmi"
+
+LICENSE="LGPL-2"
+SLOT="0/5.7"	# soname of libqmi-glib.so
+IUSE="doc +mbim"
+
+RDEPEND=">=dev-libs/glib-2.48
+	dev-libs/libgudev
+	mbim? ( >=net-libs/libmbim-1.18.0 )"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( dev-util/gtk-doc )"
+[[ ${PV} == "9999" ]] && BDEPEND+=" dev-util/gtk-doc" #469214
+
+src_prepare() {
+	default
+	[[ ${PV} == "9999" ]] && eautoreconf
+}
+
+src_configure() {
+	econf \
+		--disable-Werror \
+		--disable-static \
+		$(use_enable mbim mbim-qmux) \
+		$(use_enable {,gtk-}doc)
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -delete || die
+}
diff --git a/net-libs/libqmi/libqmi-9999.ebuild b/net-libs/libqmi/libqmi-9999.ebuild
index 9ae85656240c..51ac0339e070 100644
--- a/net-libs/libqmi/libqmi-9999.ebuild
+++ b/net-libs/libqmi/libqmi-9999.ebuild
@@ -1,46 +1,47 @@
-# Copyright 1999-2019 Gentoo Authors
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI="6"
+EAPI=7
 
 inherit multilib
 if [[ ${PV} == "9999" ]] ; then
 	inherit git-r3 autotools
-	EGIT_REPO_URI="https://anongit.freedesktop.org/git/libqmi.git"
+	EGIT_REPO_URI="https://gitlab.freedesktop.org/mobile-broadband/libqmi.git"
 else
-	KEYWORDS="~amd64 ~arm ~arm64 ~mips ~x86"
+	KEYWORDS="~amd64 ~arm ~arm64 ~mips ~ppc ~ppc64 ~x86"
 	SRC_URI="https://www.freedesktop.org/software/libqmi/${P}.tar.xz"
 fi
 
-DESCRIPTION="Qualcomm MSM (Mobile Station Modem) Interface (QMI) modem protocol helper library"
-HOMEPAGE="https://cgit.freedesktop.org/libqmi/"
+DESCRIPTION="Qualcomm MSM (Mobile Station Modem) Interface (QMI) modem protocol library"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/libqmi/ https://gitlab.freedesktop.org/mobile-broadband/libqmi"
 
 LICENSE="LGPL-2"
-SLOT="0/5.1"	# soname of libqmi-glib.so
-IUSE="doc +mbim static-libs"
+SLOT="0/5.7"	# soname of libqmi-glib.so
+IUSE="doc +mbim"
 
-RDEPEND=">=dev-libs/glib-2.36
+RDEPEND=">=dev-libs/glib-2.48
 	dev-libs/libgudev
-	mbim? ( >=net-libs/libmbim-1.14.0 )"
-DEPEND="${RDEPEND}
-	doc? ( dev-util/gtk-doc )
-	virtual/pkgconfig"
-[[ ${PV} == "9999" ]] && DEPEND+=" dev-util/gtk-doc" #469214
+	mbim? ( >=net-libs/libmbim-1.18.0 )"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( dev-util/gtk-doc )"
+[[ ${PV} == "9999" ]] && BDEPEND+=" dev-util/gtk-doc" #469214
 
 src_prepare() {
 	default
-	[[ -e configure ]] || eautoreconf
+	[[ ${PV} == "9999" ]] && eautoreconf
 }
 
 src_configure() {
 	econf \
-		--disable-more-warnings \
+		--disable-Werror \
+		--disable-static \
 		$(use_enable mbim mbim-qmux) \
-		$(use_enable static{-libs,}) \
 		$(use_enable {,gtk-}doc)
 }
 
 src_install() {
 	default
-	use static-libs || rm -f "${ED}/usr/$(get_libdir)/${PN}-glib.la"
+	find "${ED}" -name '*.la' -delete || die
 }