kde-plasma/plasma-firewall: 5.24.1 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 65 insertions, 0 deletions

diff --git a/kde-plasma/plasma-firewall/Manifest b/kde-plasma/plasma-firewall/Manifest
index d34adfc24a3b..2eaa6be5ff7e 100644
--- a/kde-plasma/plasma-firewall/Manifest
+++ b/kde-plasma/plasma-firewall/Manifest
@@ -1,2 +1,3 @@
 DIST plasma-firewall-5.23.5.tar.xz 344132 BLAKE2B 3277329f223f5b4afe33bcf663b8c9f999a8dda4cab593e04d57fb8b2d6d4d899f76f803ca6cc8e3ef718bbcb09f2cb6d24dbaa1c3abcbfa5e163dd791f066ca SHA512 c18b25ad85f57da80edfc03cd445d317162ad2f952fe7ecd09f43af274798acd965de0f8643a636bee74e3572f0ab66f3db876126009b9c98f486a1cfe0e386e
 DIST plasma-firewall-5.24.0.tar.xz 344992 BLAKE2B 593b8e1133b9c3e6778f3d95d87ee0c3dda9888ab3ab170f78ee1160207054b609933638c12ba88052c13f8204ce894201bf8a005364587cba509d6f0e04706f SHA512 6b07149dc4c2e20d901327ea8e99d85ddcddc006df3354ad57660280d54d1d8164e8862f145b2ca232e054c440602ba61fbe249cd0c29781fb2cc2c6adf7730c
+DIST plasma-firewall-5.24.1.tar.xz 345020 BLAKE2B b60bd851016ae73f2775f419052ea79c9ad4915029279fc54956b4f70be529ed93038f3e8d70da7b4d6cc506b71278608719f0ab1f266decdb162fa4bd7b4076 SHA512 8d3d0ed7a07ea3c9a0e23d9b3965f6e800c13b14188ad29e3201e88daa72ceee348ea84d8ca18be128fd1836502676168719d4a0f91e3092d57254fa14075c69
diff --git a/kde-plasma/plasma-firewall/plasma-firewall-5.24.1.ebuild b/kde-plasma/plasma-firewall/plasma-firewall-5.24.1.ebuild
new file mode 100644
index 000000000000..5ac26b7e39d1
--- /dev/null
+++ b/kde-plasma/plasma-firewall/plasma-firewall-5.24.1.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+KFMIN=5.90.0
+QTMIN=5.15.2
+inherit ecm kde.org python-single-r1
+
+DESCRIPTION="Plasma frontend for Firewalld or UFW"
+HOMEPAGE="https://invent.kde.org/network/plasma-firewall"
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="firewalld +ufw"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE} || ( firewalld ufw )"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+	${PYTHON_DEPS}
+	firewalld? ( net-firewall/firewalld )
+	ufw? ( net-firewall/ufw )
+"
+
+src_prepare() {
+	ecm_src_prepare
+	# this kind of cmake magic doesn't work for us at all.
+	sed -e "1 s:^.*$:\#\!/usr/bin/env ${EPYTHON}:" \
+		-i kcm/backends/ufw/helper/kcm_ufw_helper.py.cmake || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_FIREWALLD_BACKEND=$(usex firewalld)
+		-DBUILD_UFW_BACKEND=$(usex ufw)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst () {
+	ecm_pkg_postinst
+
+	if ! has_version sys-apps/systemd; then
+		ewarn "${PN} is not functional without sys-apps/systemd at this point."
+		ewarn "See also: https://bugs.gentoo.org/778527"
+	fi
+}