app-crypt/swtpm: Bump to 0.5.2

Package-Manager: Portage-3.0.9, Repoman-3.0.2
Signed-off-by: Salah Coronya <salah.coronya@gmail.com>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

2 files changed, 93 insertions, 0 deletions

diff --git a/app-crypt/swtpm/Manifest b/app-crypt/swtpm/Manifest
index f4465c11d3c8..d2aba5213420 100644
--- a/app-crypt/swtpm/Manifest
+++ b/app-crypt/swtpm/Manifest
@@ -1 +1,2 @@
 DIST swtpm-0.5.1.tar.gz 309464 BLAKE2B 630a9add9a17e016f0158666bd3f4eafa773b7a2645820346d5f2847023310f8df4c2491184c5f5d02a83aa2bb53f8c266e5f2a6b07ab92502f08c7f1fa697ea SHA512 8a034b1da916797b9869a4ff478a4c7093b1343ce2556054d2228214520f0e2a63a1d69709bf2cc62fe45710dd9a41c0eee488af9396e8baf8099e697593638c
+DIST swtpm-0.5.2.tar.gz 309436 BLAKE2B 0518e59b052c9224d5db1c2720f74ff15717468f73b1665e67c017581dd2b52d7a4cf28f94a932eb6068de3bc50f2e5710b8c447e4a08e6b4a31019db542d910 SHA512 4554f1b7a534829f9fbef4a09e190f1d5e91692d270f4f668bd6ef79799a4186a38db172e37a18be9f203466e2d7c9cdf3a350c0020d25ff6126128085ebe3a3
diff --git a/app-crypt/swtpm/swtpm-0.5.2.ebuild b/app-crypt/swtpm/swtpm-0.5.2.ebuild
new file mode 100644
index 000000000000..7cf67bd70dff
--- /dev/null
+++ b/app-crypt/swtpm/swtpm-0.5.2.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+
+inherit autotools distutils-r1
+
+DESCRIPTION="Libtpms-based TPM emulator"
+HOMEPAGE="https://github.com/stefanberger/swtpm"
+SRC_URI="https://github.com/stefanberger/swtpm/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="fuse gnutls libressl seccomp test"
+RESTRICT="!test? ( test )"
+
+COMMON_DEPEND="
+	fuse? (
+		dev-libs/glib:2
+		sys-fs/fuse:0
+	)
+	gnutls? (
+		dev-libs/libtasn1:=
+		>=net-libs/gnutls-3.1.0[tools]
+	)
+	!libressl? (
+		dev-libs/openssl:0=
+		dev-libs/libtpms[-libressl]
+	)
+	libressl? (
+		dev-libs/libressl:0=
+		dev-libs/libtpms[libressl]
+	)
+	seccomp? ( sys-libs/libseccomp )
+"
+
+DEPEND="${COMMON_DEPEND}
+	test? (
+		net-misc/socat
+		dev-tcltk/expect
+	)
+"
+
+RDEPEND="${COMMON_DEPEND}
+	acct-group/tss
+	acct-user/tss
+	dev-python/cryptography[${PYTHON_USEDEP}]
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.5.0-fix-localca-path.patch"
+	"${FILESDIR}/${PN}-0.5.0-build-sys-Remove-WError.patch"
+)
+
+src_prepare() {
+	use test || eapply "${FILESDIR}/${PN}-0.5.0-disable-test-dependencies.patch"
+	python_setup
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--disable-static \
+		--with-openssl \
+		--without-selinux \
+		$(use_with fuse cuse) \
+		$(use_with gnutls) \
+		$(use_with seccomp)
+}
+
+src_compile() {
+	# We want the default src_compile, not the version distutils-r1 exports
+	default
+}
+
+src_install() {
+	default
+	python_foreach_impl python_optimize
+	fowners -R tss:root /var/lib/swtpm-localca
+	fperms 750 /var/lib/swtpm-localca
+	keepdir /var/lib/swtpm-localca
+	find "${D}" -name '*.la' -delete || die
+}
+
+src_test() {
+	# We want the default src_test, not the version distutils-r1 exports
+	default
+}