summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorMike Frysinger <vapier@chromium.org>2020-05-21 13:17:39 -0400
committerMike Frysinger <vapier@gentoo.org>2020-05-21 13:23:49 -0400
commit72f17f05fead2ac67b606bf1f1f7d1c6a6f2aff2 (patch)
tree44fdaafe7e7a957281f2ee3946d4abb924c2ed59
parentdev-ml/num: use CFLAGS (diff)
downloadgentoo-72f17f05fead2ac67b606bf1f1f7d1c6a6f2aff2.tar.gz
gentoo-72f17f05fead2ac67b606bf1f1f7d1c6a6f2aff2.tar.bz2
gentoo-72f17f05fead2ac67b606bf1f1f7d1c6a6f2aff2.zip
dev-embedded/u-boot-tools: switch build-only tools to BDEPEND
Signed-off-by: Mike Frysinger <vapier@gentoo.org>
-rw-r--r--dev-embedded/u-boot-tools/u-boot-tools-2020.04-r1.ebuild58
1 files changed, 58 insertions, 0 deletions
diff --git a/dev-embedded/u-boot-tools/u-boot-tools-2020.04-r1.ebuild b/dev-embedded/u-boot-tools/u-boot-tools-2020.04-r1.ebuild
new file mode 100644
index 00000000000..480bbd0f2a4
--- /dev/null
+++ b/dev-embedded/u-boot-tools/u-boot-tools-2020.04-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+inherit toolchain-funcs
+
+MY_P="u-boot-${PV/_/-}"
+DESCRIPTION="utilities for working with Das U-Boot"
+HOMEPAGE="https://www.denx.de/wiki/U-Boot/WebHome"
+SRC_URI="ftp://ftp.denx.de/pub/u-boot/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+BDEPEND="
+ sys-devel/bison
+ sys-devel/flex
+"
+
+S=${WORKDIR}/${MY_P}
+
+src_compile() {
+ # Unset a few KBUILD variables. Bug #540476
+ unset KBUILD_OUTPUT KBUILD_SRC
+
+ emake \
+ V=1 \
+ HOSTCC="$(tc-getCC)" \
+ HOSTCFLAGS="${CFLAGS} ${CPPFLAGS}"' $(HOSTCPPFLAGS)' \
+ HOSTLDFLAGS="${LDFLAGS}" \
+ tools-only_defconfig
+
+ emake \
+ V=1 \
+ NO_SDL=1 \
+ HOSTSTRIP=: \
+ STRIP=: \
+ HOSTCC="$(tc-getCC)" \
+ HOSTCFLAGS="${CFLAGS} ${CPPFLAGS}"' $(HOSTCPPFLAGS)' \
+ HOSTLDFLAGS="${LDFLAGS}" \
+ CONFIG_ENV_OVERWRITE=y \
+ tools-all
+}
+
+src_test() { :; }
+
+src_install() {
+ cd tools || die
+ dobin bmp_logo dumpimage fdtgrep gen_eth_addr img2srec mkenvimage mkimage
+ dobin env/fw_printenv
+ dosym fw_printenv /usr/bin/fw_setenv
+ insinto /etc
+ doins env/fw_env.config
+ doman "${S}"/doc/mkimage.1
+}