summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAlexey Shvetsov <alexxy@gentoo.org>2018-11-09 17:09:20 +0300
committerAlexey Shvetsov <alexxy@gentoo.org>2018-11-09 17:20:15 +0300
commit7533b9d8d1e7056eeaf99c39589ed2e31c1e9718 (patch)
tree848e676ca2d683064cf1d5e04f433b250b723c56
parentdev-python/pastedeploy: eapi6 + py3_7 (diff)
downloadgentoo-7533b9d8d1e7056eeaf99c39589ed2e31c1e9718.tar.gz
gentoo-7533b9d8d1e7056eeaf99c39589ed2e31c1e9718.tar.bz2
gentoo-7533b9d8d1e7056eeaf99c39589ed2e31c1e9718.zip
dev-python/webtest: eapi7 + py3_7
Package-Manager: Portage-2.3.51, Repoman-2.3.12 Signed-off-by: Alexey Shvetsov <alexxy@gentoo.org>
-rw-r--r--dev-python/webtest/webtest-2.0.29-r1.ebuild66
1 files changed, 66 insertions, 0 deletions
diff --git a/dev-python/webtest/webtest-2.0.29-r1.ebuild b/dev-python/webtest/webtest-2.0.29-r1.ebuild
new file mode 100644
index 00000000000..f7ea291c78c
--- /dev/null
+++ b/dev-python/webtest/webtest-2.0.29-r1.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{5,6,7} )
+
+inherit distutils-r1
+
+MY_PN="WebTest"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Helper to test WSGI applications"
+HOMEPAGE="https://pypi.org/project/WebTest/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc64 ~s390 ~sh ~sparc ~x86"
+IUSE="doc test"
+
+# nose<1.3.0 appears a leftover never updated in requires.txt. tests pass fine with latest
+RDEPEND="
+ dev-python/six[${PYTHON_USEDEP}]
+ >=dev-python/webob-1.2[${PYTHON_USEDEP}]
+ >=dev-python/waitress-0.8.5[${PYTHON_USEDEP}]
+ dev-python/beautifulsoup:4[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+ app-arch/unzip
+ dev-python/setuptools[${PYTHON_USEDEP}]
+ doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+ test? ( dev-python/nose[${PYTHON_USEDEP}]
+ dev-python/pyquery[${PYTHON_USEDEP}]
+ dev-python/pastedeploy[${PYTHON_USEDEP}]
+ dev-python/wsgiproxy2[${PYTHON_USEDEP}]
+ dev-python/coverage[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' python2_7 )
+ )"
+
+S="${WORKDIR}/${MY_P}"
+
+# Makes testing easier; otherwise we get errors from pkg_resources.
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_prepare_all() {
+ # Prevent un-needed d'loading during doc build
+ sed -s 's:intersphinx_mapping:_&:' -i docs/conf.py || die
+ distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+ if use doc; then
+ sphinx-build docs html || die
+ fi
+}
+
+python_test() {
+ # Tests raise ImportErrors with our default PYTHONPATH.
+ local -x PYTHONPATH=
+ nosetests || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+ use doc && local HTML_DOCS=( html/. )
+ distutils-r1_python_install_all
+}