kde-apps/konqueror: 22.08.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 93 insertions, 0 deletions

diff --git a/kde-apps/konqueror/Manifest b/kde-apps/konqueror/Manifest
index 3eb79a0ec60b..aad9fb4084c1 100644
--- a/kde-apps/konqueror/Manifest
+++ b/kde-apps/konqueror/Manifest
@@ -1 +1,2 @@
 DIST konqueror-22.04.3.tar.xz 7669364 BLAKE2B 9778cdb920854e6f76fad5fc8717263beaa3869ada35b96be68db5234a102f3a3b60f76d0171bff73136001b10114f6a2fce6b79eb6caf17f8be21679da10bd9 SHA512 e64115a083dddbe6a66c8cfdeb0b081d52068ae877cf51b09d8573e0ba87cb3665421175d915b51f6532be5199e9667f11fe5dd8c0765c4f434b9a65f218a2c6
+DIST konqueror-22.08.0.tar.xz 7668492 BLAKE2B 9646d591ee3a740e952172c6a2ed9ade39e7a6582c6338005b2cacb5c0b305cc19cc8b5f193d7f188dedad0cbc61aaeac06596928ad97e59d874ba9ae417836c SHA512 c9c16f22667616c794762dd71d8a341a878e59692bc78aca83f68d80e93231776a598d04ded606832038e7e9c4b48c6bfbffa02985729640ddb0115625d99d09
diff --git a/kde-apps/konqueror/konqueror-22.08.0.ebuild b/kde-apps/konqueror/konqueror-22.08.0.ebuild
new file mode 100644
index 000000000000..3f5617f5b9d9
--- /dev/null
+++ b/kde-apps/konqueror/konqueror-22.08.0.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+ECM_TEST="true"
+KFMIN=5.96.0
+QTMIN=5.15.5
+VIRTUALX_REQUIRED="test"
+inherit flag-o-matic ecm gear.kde.org optfeature
+
+DESCRIPTION="Web browser and file manager based on KDE Frameworks"
+HOMEPAGE="https://apps.kde.org/konqueror/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="activities speech X"
+
+# 4 of 4 tests fail. Last checked for 4.0.3
+RESTRICT="test"
+
+COMMON_DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtscript-${QTMIN}:5
+	>=dev-qt/qtwebengine-${QTMIN}:5[widgets]
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kbookmarks-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kdesu-${KFMIN}:5
+	>=kde-frameworks/kguiaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwallet-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	sys-libs/zlib
+	speech? ( >=dev-qt/qtspeech-${QTMIN}:5 )
+	X? ( >=dev-qt/qtx11extras-${QTMIN}:5 )
+"
+DEPEND="${COMMON_DEPEND}
+	activities? ( >=kde-frameworks/kactivities-${KFMIN}:5 )
+"
+RDEPEND="${COMMON_DEPEND}
+	kde-apps/kfind:5
+	kde-plasma/kde-cli-tools:5
+"
+
+PATCHES=( "${FILESDIR}/${PN}-22.04.3-without_x11.patch" )
+
+src_prepare() {
+	[[ ${CHOST} == *-solaris* ]] && append-ldflags -lmalloc
+
+	ecm_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_Hunspell=ON # requires fixing bug 634122
+		$(cmake_use_find_package activities KF5Activities)
+		$(cmake_use_find_package speech Qt5TextToSpeech)
+		-DWITHOUT_X11=$(usex !X)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "bookmarks support" kde-apps/keditbookmarks:${SLOT}
+		optfeature "filemanager component" kde-apps/dolphin:${SLOT}
+		optfeature "SVG support" kde-apps/svg:${SLOT}
+		optfeature "Java support on webpages" virtual/jre
+	fi
+	ecm_pkg_postinst
+}