app-admin/consul-template: Version bump to 1.19.5

Package-Manager: Portage-2.3.42, Repoman-2.3.9

2 files changed, 64 insertions, 0 deletions

diff --git a/app-admin/consul-template/Manifest b/app-admin/consul-template/Manifest
index f693d052bd2c..3b5747bc247c 100644
--- a/app-admin/consul-template/Manifest
+++ b/app-admin/consul-template/Manifest
@@ -1 +1,2 @@
 DIST consul-template-0.18.5.tar.gz 5285939 BLAKE2B 822df39f77d9aebc55e03d74b43ace9d453135c6270aedd3d41a674b5ae325a588af2a76c9236072d6f6dd274ab75c050df6607aa5bfc98b0caf2cd3065b1b04 SHA512 1709c889cd414d2b3510400e8077aec49006c31958618a38f6bce78dad2ba4aac5405410b030bf968b5cf148f4cfbe963ccf95a015cd1e58f2f6d1f09edc13de
+DIST consul-template-0.19.5.tar.gz 6054881 BLAKE2B 48d691f9d09531248310ec50c6c59d3c74db4c8ca5f0236ac8336df92c75da89677e64cb593518032f48f53b9f5aa914a7b6ac0a2dc6bf6d32ae7c1f6d1dc60d SHA512 bdba4e821e353a71f9f6287b8ff352e85a916201314229b998bfbebb066fec17c5d7f12e224bf2920b018a4f5fec9000f122f6c04cb2e455a195b945e35235a5
diff --git a/app-admin/consul-template/consul-template-0.19.5.ebuild b/app-admin/consul-template/consul-template-0.19.5.ebuild
new file mode 100644
index 000000000000..dfa6bf036b0b
--- /dev/null
+++ b/app-admin/consul-template/consul-template-0.19.5.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit golang-vcs-snapshot systemd user
+
+KEYWORDS="~amd64"
+DESCRIPTION="Generic template rendering and notifications with Consul"
+GIT_COMMIT="f8c8205"
+EGO_PN="github.com/hashicorp/${PN}"
+HOMEPAGE="https://github.com/hashicorp/consul-template"
+LICENSE="MPL-2.0"
+SLOT="0"
+IUSE="test"
+
+DEPEND="dev-lang/go
+	test? ( app-admin/consul )"
+RDEPEND=""
+
+SRC_URI="https://${EGO_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+pkg_setup() {
+	enewgroup ${PN}
+	enewuser ${PN} -1 -1 -1 ${PN}
+}
+
+src_prepare() {
+	default
+	# Avoid the need to have a git checkout
+	sed -e "s:git rev-parse --short HEAD:echo ${GIT_COMMIT}:" \
+		-e '/-s \\/d' \
+		-i src/${EGO_PN}/Makefile || die
+}
+
+src_compile() {
+	export GOPATH=${S}
+	cd src/${EGO_PN} || die
+	#XC_ARCH=$(go env GOARCH) \
+	#XC_OS=$(go env GOOS) \
+	emake dev
+}
+
+src_test() {
+	cd src/${EGO_PN} || die
+	emake test
+}
+
+src_install() {
+	dobin bin/${PN}
+	dodoc src/${EGO_PN}/{CHANGELOG.md,README.md}
+
+	keepdir /var/log/${PN}
+	fowners ${PN}:${PN} /var/log/${PN}
+
+	newinitd "${FILESDIR}/${PN}.initd" "${PN}"
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}/${PN}.logrotated" "${PN}"
+	newconfd "${FILESDIR}/${PN}.confd" "${PN}"
+	systemd_dounit "${FILESDIR}/${PN}.service"
+
+	keepdir /etc/${PN}.d
+}