summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorConrad Kostecki <conikost@gentoo.org>2020-05-25 13:17:11 +0200
committerConrad Kostecki <conikost@gentoo.org>2020-05-25 13:17:11 +0200
commit80bbda5bfac7dd4b6727f17b1bfbed04bbf773f1 (patch)
tree38fe8a8778691ab49016723aef26840ef639348a
parentsys-auth/AusweisApp2: New package (diff)
downloadgentoo-80bbda5bfac7dd4b6727f17b1bfbed04bbf773f1.tar.gz
gentoo-80bbda5bfac7dd4b6727f17b1bfbed04bbf773f1.tar.bz2
gentoo-80bbda5bfac7dd4b6727f17b1bfbed04bbf773f1.zip
net-misc/etherdfs: respect users LDFLAGS
Closes: https://bugs.gentoo.org/725236 Package-Manager: Portage-2.3.99, Repoman-2.3.22 Signed-off-by: Conrad Kostecki <conikost@gentoo.org>
-rw-r--r--net-misc/etherdfs/etherdfs-20180203-r1.ebuild60
1 files changed, 60 insertions, 0 deletions
diff --git a/net-misc/etherdfs/etherdfs-20180203-r1.ebuild b/net-misc/etherdfs/etherdfs-20180203-r1.ebuild
new file mode 100644
index 00000000000..d5a7bfb7698
--- /dev/null
+++ b/net-misc/etherdfs/etherdfs-20180203-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 2019-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PN="ethersrv-linux"
+MY_PV_TSR="0.8.2"
+MY_P="${MY_PN}-${PV}"
+
+inherit systemd toolchain-funcs
+
+DESCRIPTION="An ethernet-based file system for DOS"
+HOMEPAGE="http://etherdfs.sourceforge.net/"
+SRC_URI="
+ mirror://sourceforge/${PN}/${MY_P}.tar.xz
+ tsr? ( mirror://sourceforge/${PN}/v${MY_PV_TSR}/${PN}.zip -> ${P}.zip )
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="tsr"
+
+BDEPEND="tsr? ( app-arch/unzip )"
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=( "${FILESDIR}/${P}-makefile.patch" )
+
+DOCS=( "ethersrv-linux.txt" "history.txt" )
+
+src_prepare() {
+ default
+
+ # Respect users LDFLAGS
+ sed -e 's/$(CFLAGS)/& $(LDFLAGS)/' -i Makefile || die
+}
+
+src_compile() {
+ tc-export CC
+
+ default
+}
+
+src_install() {
+ dobin ethersrv-linux
+
+ if use tsr; then
+ insinto /usr/share/etherdfs
+ newins ../ETHERDFS.EXE etherdfs.exe
+
+ DOCS+=( "../ETHERDFS.TXT" "../HISTORY.TXT" )
+ fi
+
+ newinitd "${FILESDIR}"/etherdfs.initd etherdfs
+ newconfd "${FILESDIR}"/etherdfs.confd etherdfs
+ systemd_dounit "${FILESDIR}"/etherdfs.service
+
+ einstalldocs
+}