summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorJoonas Niilola <juippis@gmail.com>2019-03-14 19:01:07 +0200
committerLars Wendler <polynomial-c@gentoo.org>2019-03-18 17:47:19 +0100
commit8104c9cc0fb26313e50a74d038b1589f5d84e572 (patch)
treeb1ce28759e56631cf45567ab3a5d2436e7872716
parentnet-libs/libsoup: bump to 2.64.2 (diff)
downloadgentoo-8104c9cc0fb26313e50a74d038b1589f5d84e572.tar.gz
gentoo-8104c9cc0fb26313e50a74d038b1589f5d84e572.tar.bz2
gentoo-8104c9cc0fb26313e50a74d038b1589f5d84e572.zip
games-util/lutris: add dev-python/requests to RDEPEND
Closes: https://bugs.gentoo.org/679828 Package-Manager: Portage-2.3.62, Repoman-2.3.12 Signed-off-by: Joonas Niilola <juippis@gmail.com> Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>
-rw-r--r--games-util/lutris/lutris-0.5.0.1-r1.ebuild75
1 files changed, 75 insertions, 0 deletions
diff --git a/games-util/lutris/lutris-0.5.0.1-r1.ebuild b/games-util/lutris/lutris-0.5.0.1-r1.ebuild
new file mode 100644
index 00000000000..d6cbb9e6644
--- /dev/null
+++ b/games-util/lutris/lutris-0.5.0.1-r1.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{4,5,6,7} )
+PYTHON_REQ_USE="sqlite,threads(+)"
+
+inherit distutils-r1 virtualx xdg
+
+DESCRIPTION="An open source gaming platform for GNU/Linux"
+HOMEPAGE="https://lutris.net/"
+
+if [[ ${PV} == *9999* ]] ; then
+ EGIT_REPO_URI="https://github.com/lutris/lutris.git"
+ inherit git-r3
+else
+ SRC_URI="https://lutris.net/releases/${P/-/_}.tar.xz"
+ KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+
+BDEPEND="
+ test? ( dev-python/nose[${PYTHON_USEDEP}] )
+"
+RDEPEND="
+ app-arch/cabextract
+ app-arch/p7zip
+ app-arch/unrar
+ app-arch/unzip
+ dev-python/pillow[${PYTHON_USEDEP}]
+ dev-python/pygobject:3[${PYTHON_USEDEP}]
+ dev-python/python-evdev[${PYTHON_USEDEP}]
+ dev-python/pyyaml[${PYTHON_USEDEP}]
+ dev-python/requests[${PYTHON_USEDEP}]
+ gnome-base/gnome-desktop[introspection]
+ media-sound/fluid-soundfont
+ net-libs/libsoup
+ net-libs/webkit-gtk:4[introspection]
+ x11-apps/xgamma
+ x11-apps/xrandr
+ x11-libs/gtk+:3[introspection]
+ x11-libs/libnotify
+"
+
+S="${WORKDIR}/${PN}"
+
+python_install_all() {
+ local DOCS=( AUTHORS README.rst docs/installers.rst )
+ distutils-r1_python_install_all
+}
+
+python_test() {
+ virtx nosetests -v || die
+}
+
+pkg_preinst() {
+ xdg_pkg_preinst
+}
+
+pkg_postinst() {
+ xdg_pkg_postinst
+
+ # Quote README.rst
+ elog "Lutris installations are fully automated through scripts, which can"
+ elog "be written in either JSON or YAML. The scripting syntax is described"
+ elog "in ${EROOT}/usr/share/doc/${PF}/installers.rst.bz2, and is also"
+ elog "available online at lutris.net."
+}
+
+pkg_postrm() {
+ xdg_pkg_postrm
+}