media-sound/qmmp: add 1.6.4

Closes: https://bugs.gentoo.org/905263
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 158 insertions, 0 deletions

diff --git a/media-sound/qmmp/Manifest b/media-sound/qmmp/Manifest
index c6a238a86166..7edc0915ba1b 100644
--- a/media-sound/qmmp/Manifest
+++ b/media-sound/qmmp/Manifest
@@ -1 +1,2 @@
 DIST qmmp-1.6.1.tar.bz2 1353769 BLAKE2B d12f91166cec051caf604ec27dc563d4cf2a52511eabfc0dee0b0679373e7c5fa0f0faac2b4d25420f33485caf90545c7f0098f1e3814f92d46d82b253410afd SHA512 efaf44002c21544514301b5ec1210507fe3cdeb4c6b8d14fb8a573d32db5bb73a9d6d36d00d9d61592261b69fa4260417e3c65183f13299234bd82dda43536c5
+DIST qmmp-1.6.4.tar.bz2 1379335 BLAKE2B e17ec8f84f94cfbc6a0a1d30d6d954f3e6b3448909c0e3344614340b41974d69aa5bd3dbb149fcc88c6ede289ec7900050eb0de81307dfeb8ebfc360255d1ea6 SHA512 da8eae4ca4e10cca8a177064a422fdc196e76bb5e3e06c3029040e1120da0d2e5666824a8effd51f82c94b999e1243ae3bc6c71c8c05e334276bf40a5767c17f
diff --git a/media-sound/qmmp/qmmp-1.6.4.ebuild b/media-sound/qmmp/qmmp-1.6.4.ebuild
new file mode 100644
index 000000000000..cad98f6a9903
--- /dev/null
+++ b/media-sound/qmmp/qmmp-1.6.4.ebuild
@@ -0,0 +1,157 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+DESCRIPTION="Qt5-based audio player with winamp/xmms skins support"
+HOMEPAGE="https://qmmp.ylsoftware.com"
+if [[ ${PV} != *9999* ]]; then
+	SRC_URI="https://qmmp.ylsoftware.com/files/${P}.tar.bz2
+		mirror://sourceforge/${PN}-dev/files/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~x86"
+else
+	inherit subversion
+	QMMP_DEV_BRANCH="1.3"
+	ESVN_REPO_URI="svn://svn.code.sf.net/p/${PN}-dev/code/branches/${PN}-${QMMP_DEV_BRANCH}"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+# KEYWORDS further up
+IUSE="aac +alsa analyzer archive bs2b cdda cover crossfade cue curl +dbus enca
+ffmpeg flac game gnome jack ladspa lyrics +mad midi mms mplayer musepack
+notifier opus oss pipewire projectm pulseaudio qsui qtmedia scrobbler shout sid
+sndfile soxr stereo tray udisks +vorbis wavpack xmp"
+
+REQUIRED_USE="
+	gnome? ( dbus )
+	shout? ( soxr vorbis )
+	udisks? ( dbus )
+"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtsql:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	media-libs/taglib
+	x11-libs/libX11
+	aac? ( media-libs/faad2 )
+	alsa? ( media-libs/alsa-lib )
+	archive? ( app-arch/libarchive )
+	bs2b? ( media-libs/libbs2b )
+	cdda? (
+		dev-libs/libcdio:=
+		dev-libs/libcdio-paranoia
+	)
+	curl? ( net-misc/curl )
+	dbus? ( dev-qt/qtdbus:5 )
+	enca? ( app-i18n/enca )
+	ffmpeg? ( media-video/ffmpeg:= )
+	flac? ( media-libs/flac:= )
+	game? ( media-libs/game-music-emu )
+	jack? (
+		media-libs/libsamplerate
+		virtual/jack
+	)
+	ladspa? ( media-plugins/cmt-plugins )
+	mad? (
+		media-libs/libmad:=
+		media-sound/mpg123:=
+	)
+	midi? ( media-sound/wildmidi )
+	mms? ( media-libs/libmms )
+	mplayer? ( media-video/mplayer )
+	musepack? ( >=media-sound/musepack-tools-444 )
+	opus? ( media-libs/opusfile )
+	pipewire? ( media-video/pipewire )
+	projectm? (
+		dev-qt/qtgui:5[-gles2-only]
+		dev-qt/qtopengl:5
+		media-libs/libprojectm:=
+	)
+	pulseaudio? ( media-libs/libpulse )
+	qtmedia? ( dev-qt/qtmultimedia:5 )
+	scrobbler? ( net-misc/curl )
+	shout? ( media-libs/libshout )
+	sid? ( >=media-libs/libsidplayfp-1.1.0 )
+	sndfile? ( media-libs/libsndfile )
+	soxr? ( media-libs/soxr )
+	udisks? ( sys-fs/udisks:2 )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+	wavpack? ( media-sound/wavpack )
+	xmp? ( media-libs/libxmp )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="dev-qt/linguist-tools:5"
+
+DOCS=( AUTHORS ChangeLog README )
+
+src_prepare() {
+	if has_version dev-libs/libcdio-paranoia ; then
+		sed -i \
+			-e 's:cdio/cdda.h:cdio/paranoia/cdda.h:' \
+			src/plugins/Input/cdaudio/decoder_cdaudio.cpp || die
+	fi
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DUSE_AAC="$(usex aac)"
+		-DUSE_ALSA="$(usex alsa)"
+		-DUSE_ANALYZER="$(usex analyzer)"
+		-DUSE_ARCHIVE="$(usex archive)"
+		-DUSE_BS2B="$(usex bs2b)"
+		-DUSE_CDA="$(usex cdda)"
+		-DUSE_COVER="$(usex cover)"
+		-DUSE_CROSSFADE="$(usex crossfade)"
+		-DUSE_CUE="$(usex cue)"
+		-DUSE_CURL="$(usex curl)"
+		-DUSE_KDENOTIFY="$(usex dbus)"
+		-DUSE_MPRIS="$(usex dbus)"
+		-DUSE_ENCA="$(usex enca)"
+		-DUSE_FFMPEG="$(usex ffmpeg)"
+		-DUSE_FILEWRITER="$(usex vorbis)"
+		-DUSE_FLAC="$(usex flac)"
+		-DUSE_GME="$(usex game)"
+		-DUSE_GNOMEHOTKEY="$(usex gnome)"
+		-DUSE_JACK="$(usex jack)"
+		-DUSE_LADSPA="$(usex ladspa)"
+		-DUSE_LYRICS="$(usex lyrics)"
+		-DUSE_MAD="$(usex mad)"
+		-DUSE_MIDI="$(usex midi)"
+		-DUSE_MMS="$(usex mms)"
+		-DUSE_MPLAYER="$(usex mplayer)"
+		-DUSE_MPC="$(usex musepack)"
+		-DUSE_NOTIFIER="$(usex notifier)"
+		-DUSE_OPUS="$(usex opus)"
+		-DUSE_OSS="$(usex oss)"
+		-DUSE_PIPEWIRE="$(usex pipewire)"
+		-DUSE_PROJECTM="$(usex projectm)"
+		-DUSE_PULSE="$(usex pulseaudio)"
+		-DUSE_QSUI="$(usex qsui)"
+		-DUSE_QTMULTIMEDIA="$(usex qtmedia)"
+		-DUSE_SCROBBLER="$(usex scrobbler)"
+		-DUSE_SHOUT="$(usex shout)"
+		-DUSE_SID="$(usex sid)"
+		-DUSE_SNDFILE="$(usex sndfile)"
+		-DUSE_SOXR="$(usex soxr)"
+		-DUSE_STEREO="$(usex stereo)"
+		-DUSE_STATICON="$(usex tray)"
+		-DUSE_UDISKS="$(usex udisks)"
+		-DUSE_VORBIS="$(usex vorbis)"
+		-DUSE_WAVPACK="$(usex wavpack)"
+		-DUSE_XMP="$(usex xmp)"
+	)
+
+	cmake_src_configure
+}