summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAndreas Sturmlechner <asturm@gentoo.org>2019-02-14 23:56:46 +0100
committerAndreas Sturmlechner <asturm@gentoo.org>2019-02-15 00:06:33 +0100
commit833af269e0d7307b5463579af285dbbf43f810e6 (patch)
tree3a38df1c924ddee4a5d4bf1f1ee1aab9a0d19056
parentapp-text/apvlv: Switch from gnome2-utils to xdg, EAPI-7 bump (diff)
downloadgentoo-833af269e0d7307b5463579af285dbbf43f810e6.tar.gz
gentoo-833af269e0d7307b5463579af285dbbf43f810e6.tar.bz2
gentoo-833af269e0d7307b5463579af285dbbf43f810e6.zip
media-plugins/audacious-plugins: 3.10.1 version bump, EAPI-7 bump
Package-Manager: Portage-2.3.60, Repoman-2.3.12 Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
-rw-r--r--media-plugins/audacious-plugins/Manifest1
-rw-r--r--media-plugins/audacious-plugins/audacious-plugins-3.10.1.ebuild169
-rw-r--r--media-plugins/audacious-plugins/audacious-plugins-9999.ebuild15
3 files changed, 178 insertions, 7 deletions
diff --git a/media-plugins/audacious-plugins/Manifest b/media-plugins/audacious-plugins/Manifest
index d6fc74039d6..d8188f36726 100644
--- a/media-plugins/audacious-plugins/Manifest
+++ b/media-plugins/audacious-plugins/Manifest
@@ -1,2 +1,3 @@
+DIST audacious-plugins-3.10.1.tar.bz2 1715477 BLAKE2B fda3940e6c06aadd93a3e1538be747083fcc969cf3118cf3e942787906b9ee0a13bd3c30d15ba19cb713559cdf8f7b71d7b961173b1619f0aafbdea5deb75ac3 SHA512 454e9ce4061e92a0ecda40f562d4cc7453fc0019fd76b25dbe9e319319fa37c22f9785cb29563e8074de8a88e6130106aca1e431790297e1b4636dc974fde565
DIST audacious-plugins-3.10.tar.bz2 1701877 BLAKE2B 4db7351af494ff5b7d2a7968524e2480f321505759f4a6532dd86f8fd87f43ab0a66e9f1fc75cfcbc8c59d35c1071048b61a8452fa6e041cd1667872f5b5699e SHA512 88dd93b5a7f6582ec42cf539d1000de0900cce683f4de85d8a17f57c7ba34545c6277882cad1505cb6682ee7b885ffcd1fe5675f7e24dc3e2a650615789d9d52
DIST audacious-plugins-3.9-gtk3.tar.bz2 1842950 BLAKE2B 55f373be204a9b4c9cff41d41d43c4776f680ab203643e90e5d338bec2e7f8a4c60cda9caa08e461089a475f3ec1bc237538f781718eb0d26a4365743337e977 SHA512 e2529af761bc97e589cac08689b16db657096b1bbfcc802789726ae1b472746025bec1b492de52eef755d7b50574d09b9250761bf701b1ca37f8a0e8db0f207b
diff --git a/media-plugins/audacious-plugins/audacious-plugins-3.10.1.ebuild b/media-plugins/audacious-plugins/audacious-plugins-3.10.1.ebuild
new file mode 100644
index 00000000000..2cd7781d94f
--- /dev/null
+++ b/media-plugins/audacious-plugins/audacious-plugins-3.10.1.ebuild
@@ -0,0 +1,169 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_P="${P/_/-}"
+
+if [[ ${PV} == *9999 ]]; then
+ inherit autotools git-r3
+ EGIT_REPO_URI="https://github.com/audacious-media-player/audacious-plugins.git"
+else
+ SRC_URI="https://distfiles.audacious-media-player.org/${MY_P}.tar.bz2"
+ KEYWORDS="~amd64 ~x86"
+fi
+DESCRIPTION="Lightweight and versatile audio player"
+HOMEPAGE="https://audacious-media-player.org/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="aac adplug +alsa ampache bs2b cdda cue ffmpeg flac fluidsynth http gme jack lame libav libnotify libsamplerate
+ lirc mms modplug mp3 nls opengl pulseaudio qt5 qtmedia scrobbler sdl sid sndfile soxr speedpitch vorbis wavpack"
+REQUIRED_USE="
+ || ( alsa jack pulseaudio qtmedia sdl )
+ ampache? ( qt5 http ) qtmedia? ( qt5 )"
+
+# The following plugins REQUIRE a GUI build of audacious, because non-GUI
+# builds do NOT install the libaudgui library & headers.
+# Plugins without a configure option:
+# alarm
+# albumart
+# delete-files
+# ladspa
+# playlist-manager
+# search-tool
+# skins
+# vtx
+# Plugins with a configure option:
+# glspectrum
+# gtkui
+# hotkey
+# notify
+# statusicon
+BDEPEND="
+ dev-util/gdbus-codegen
+ virtual/pkgconfig
+ nls? ( dev-util/intltool )
+"
+RDEPEND="
+ app-arch/unzip
+ dev-libs/dbus-glib
+ dev-libs/glib
+ dev-libs/libxml2:2
+ ~media-sound/audacious-${PV}[qt5=]
+ aac? ( >=media-libs/faad2-2.7 )
+ adplug? ( media-libs/adplug )
+ alsa? ( >=media-libs/alsa-lib-1.0.16 )
+ ampache? ( =media-libs/ampache_browser-1* )
+ bs2b? ( media-libs/libbs2b )
+ cdda? (
+ dev-libs/libcdio:=
+ dev-libs/libcdio-paranoia
+ >=media-libs/libcddb-1.2.1
+ )
+ cue? ( media-libs/libcue )
+ ffmpeg? ( >=virtual/ffmpeg-0.7.3 )
+ flac? (
+ >=media-libs/flac-1.2.1-r1
+ >=media-libs/libvorbis-1.0
+ )
+ fluidsynth? ( media-sound/fluidsynth )
+ http? ( >=net-libs/neon-0.26.4 )
+ jack? (
+ >=media-libs/bio2jack-0.4
+ virtual/jack
+ )
+ lame? ( media-sound/lame )
+ libnotify? ( x11-libs/libnotify )
+ libsamplerate? ( media-libs/libsamplerate:= )
+ lirc? ( app-misc/lirc )
+ mms? ( >=media-libs/libmms-0.3 )
+ modplug? ( media-libs/libmodplug )
+ mp3? ( >=media-sound/mpg123-1.12.1 )
+ pulseaudio? ( >=media-sound/pulseaudio-0.9.3 )
+ !qt5? (
+ x11-libs/gtk+:2
+ x11-libs/libXcomposite
+ x11-libs/libXrender
+ )
+ qt5? (
+ dev-qt/qtcore:5
+ dev-qt/qtgui:5
+ dev-qt/qtwidgets:5
+ opengl? ( dev-qt/qtopengl:5 )
+ )
+ qtmedia? ( dev-qt/qtmultimedia:5 )
+ scrobbler? ( net-misc/curl )
+ sdl? ( media-libs/libsdl2[sound] )
+ sid? ( >=media-libs/libsidplayfp-1.0.0 )
+ sndfile? ( >=media-libs/libsndfile-1.0.17-r1 )
+ soxr? ( media-libs/soxr )
+ speedpitch? ( media-libs/libsamplerate:= )
+ vorbis? (
+ >=media-libs/libogg-1.1.3
+ >=media-libs/libvorbis-1.2.0
+ )
+ wavpack? ( >=media-sound/wavpack-4.50.1-r1 )
+"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+ default
+ if ! use nls; then
+ sed -e "/SUBDIRS/s/ po//" -i Makefile || die # bug #512698
+ fi
+ [[ ${PV} == *9999 ]] && eautoreconf
+}
+
+src_configure() {
+ use mp3 || ewarn "MP3 support is optional, you may want to enable the mp3 USE-flag"
+
+ local myeconfargs=(
+ --enable-mpris2
+ --enable-songchange
+ --disable-oss4
+ --disable-coreaudio
+ --disable-sndio
+ $(use_enable aac)
+ $(use_enable adplug)
+ $(use_enable alsa)
+ $(use_enable ampache)
+ $(use_enable bs2b)
+ $(use_enable cdda cdaudio)
+ $(use_enable cue)
+ $(use_enable flac)
+ $(use_enable flac filewriter)
+ $(use_enable fluidsynth amidiplug)
+ $(use_enable gme console)
+ $(use_enable http neon)
+ $(use_enable jack)
+ $(use_enable lame filewriter_mp3)
+ $(use_enable libnotify notify)
+ $(use_enable libsamplerate resample)
+ $(use_enable lirc)
+ $(use_enable mms)
+ $(use_enable modplug)
+ $(use_enable mp3 mpg123)
+ $(use_enable nls)
+ $(use_enable pulseaudio pulse)
+ $(use_enable !qt5 aosd)
+ $(use_enable !qt5 gtk)
+ $(use_enable !qt5 hotkey)
+ $(use_enable qt5 qt)
+ $(use_enable qtmedia qtaudio)
+ $(use_enable scrobbler scrobbler2)
+ $(use_enable sdl sdlout)
+ $(use_enable sid)
+ $(use_enable sndfile)
+ $(use_enable soxr)
+ $(use_enable speedpitch)
+ $(use_enable vorbis)
+ $(use_enable wavpack)
+ $(use_with ffmpeg ffmpeg $(usex libav libav ffmpeg))
+ )
+ use qt5 && myeconfargs+=( $(usex opengl --enable-qtglspectrum --disable-qtglspectrum) )
+
+ econf "${myeconfargs[@]}"
+}
diff --git a/media-plugins/audacious-plugins/audacious-plugins-9999.ebuild b/media-plugins/audacious-plugins/audacious-plugins-9999.ebuild
index d3d11e6d779..2cd7781d94f 100644
--- a/media-plugins/audacious-plugins/audacious-plugins-9999.ebuild
+++ b/media-plugins/audacious-plugins/audacious-plugins-9999.ebuild
@@ -1,7 +1,7 @@
-# Copyright 1999-2018 Gentoo Authors
+# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
-EAPI=6
+EAPI=7
MY_P="${P/_/-}"
@@ -40,6 +40,11 @@ REQUIRED_USE="
# hotkey
# notify
# statusicon
+BDEPEND="
+ dev-util/gdbus-codegen
+ virtual/pkgconfig
+ nls? ( dev-util/intltool )
+"
RDEPEND="
app-arch/unzip
dev-libs/dbus-glib
@@ -100,11 +105,7 @@ RDEPEND="
)
wavpack? ( >=media-sound/wavpack-4.50.1-r1 )
"
-DEPEND="${RDEPEND}
- dev-util/gdbus-codegen
- virtual/pkgconfig
- nls? ( dev-util/intltool )
-"
+RDEPEND="${DEPEND}"
S="${WORKDIR}/${MY_P}"