summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorMatt Turner <mattst88@gentoo.org>2022-05-28 21:16:08 -0400
committerMatt Turner <mattst88@gentoo.org>2022-05-28 21:17:11 -0400
commit86cf7dde6f6cc1fdde18de42b2f66e7886c2e35e (patch)
treeef9c91843cf1fb0bae091d5de2dc56b82bce1e03
parentx11-terms/gnome-terminal: Version bump to 3.44.1 (diff)
downloadgentoo-86cf7dde6f6cc1fdde18de42b2f66e7886c2e35e.tar.gz
gentoo-86cf7dde6f6cc1fdde18de42b2f66e7886c2e35e.tar.bz2
gentoo-86cf7dde6f6cc1fdde18de42b2f66e7886c2e35e.zip
net-libs/webkit-gtk: Version bump to 2.36.3
Bug: https://bugs.gentoo.org/845252 Signed-off-by: Matt Turner <mattst88@gentoo.org>
-rw-r--r--net-libs/webkit-gtk/Manifest1
-rw-r--r--net-libs/webkit-gtk/webkit-gtk-2.36.3.ebuild250
2 files changed, 251 insertions, 0 deletions
diff --git a/net-libs/webkit-gtk/Manifest b/net-libs/webkit-gtk/Manifest
index e63783a4835..851d58b2a81 100644
--- a/net-libs/webkit-gtk/Manifest
+++ b/net-libs/webkit-gtk/Manifest
@@ -1,2 +1,3 @@
DIST webkitgtk-2.36.1.tar.xz 27149816 BLAKE2B 8136caed8779c23f872d2d540f3ca934e0e718699c575c893f44c63dac0f5fd59a93ad6cd299531a544719d6b5715c8d33fac3c3288983bcef51a47a2d75db59 SHA512 c0574bd8924df89c1a82905a8c0c09b4be49f75639db659b38fc3123922128a22fa6f4cf099f08ef7742ecefbbde765177a77e00fd641db3a5eb509586e96ae4
DIST webkitgtk-2.36.2.tar.xz 26444132 BLAKE2B 5ad4f3aad0e5c984a2c18b32faf13b5357828a010b64f35d743f5fc3b45c6912339b2d1996735ca690547c8cdc3aceaeac2c89e104d4addd29ab47aa4a139ab3 SHA512 00849ab0a4f6deca4287d3556ee10d9779197fcb618045174c3d39ff1847937bd3fe4208a39a13c53ebf7e2fe35a915494ddf6bec1120100dfba8695c883154a
+DIST webkitgtk-2.36.3.tar.xz 26600236 BLAKE2B 80c1127e75a12603e3646b840d6fd8cc4146b5a964d9a44966ff7d40e67f8743420c87f3c001f9299b2449f492401d86c02e55395e2db8938ff0e3bbb08790cb SHA512 dfd02e22a58d0080d9bf6c7dd2a710bb9d8698ff8a4226653629294b74cc981a3e35d4d93eed5ebad35c81b339ec8b96755ad0b36c0238da151b359e07bcb692
diff --git a/net-libs/webkit-gtk/webkit-gtk-2.36.3.ebuild b/net-libs/webkit-gtk/webkit-gtk-2.36.3.ebuild
new file mode 100644
index 00000000000..4743940081e
--- /dev/null
+++ b/net-libs/webkit-gtk/webkit-gtk-2.36.3.ebuild
@@ -0,0 +1,250 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_REQ_USE="xml(+)"
+PYTHON_COMPAT=( python3_{8..11} )
+USE_RUBY="ruby27 ruby30 ruby31"
+
+inherit check-reqs flag-o-matic gnome2 python-any-r1 ruby-single toolchain-funcs cmake
+
+MY_P="webkitgtk-${PV}"
+DESCRIPTION="Open source web browser engine"
+HOMEPAGE="https://www.webkitgtk.org"
+SRC_URI="https://www.webkitgtk.org/releases/${MY_P}.tar.xz"
+
+LICENSE="LGPL-2+ BSD"
+SLOT="4/37" # soname version of libwebkit2gtk-4.0
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+IUSE="aqua avif +egl examples gamepad +geolocation gles2-only gnome-keyring +gstreamer gtk-doc +introspection +jpeg2k +jumbo-build lcms libnotify seccomp spell systemd test wayland X"
+
+# gstreamer with opengl/gles2 needs egl
+REQUIRED_USE="
+ gles2-only? ( egl )
+ gstreamer? ( egl )
+ wayland? ( egl )
+ || ( aqua wayland X )
+"
+
+# Tests fail to link for inexplicable reasons
+# https://bugs.webkit.org/show_bug.cgi?id=148210
+RESTRICT="test"
+
+# Dependencies found at Source/cmake/OptionsGTK.cmake
+# Missing WebRTC support, but ENABLE_MEDIA_STREAM/ENABLE_WEB_RTC is experimental upstream (PRIVATE OFF) and shouldn't be used yet in 2.30
+# >=gst-plugins-opus-1.14.4-r1 for opusparse (required by MSE)
+# TODO: gst-plugins-base[X] is only needed when build configuration ends up with GLX set, but that's a bit automagic too to fix
+RDEPEND="
+ >=x11-libs/cairo-1.16.0:=[X?]
+ >=media-libs/fontconfig-2.13.0:1.0
+ >=media-libs/freetype-2.9.0:2
+ >=dev-libs/libgcrypt-1.7.0:0=
+ >=x11-libs/gtk+-3.22.0:3[aqua?,introspection?,wayland?,X?]
+ >=media-libs/harfbuzz-1.4.2:=[icu(+)]
+ >=dev-libs/icu-61.2:=
+ media-libs/libjpeg-turbo:0=
+ >=net-libs/libsoup-2.54:2.4[introspection?]
+ >=dev-libs/libxml2-2.8.0:2
+ >=media-libs/libpng-1.4:0=
+ dev-db/sqlite:3=
+ sys-libs/zlib:0
+ >=dev-libs/atk-2.16.0
+ media-libs/libwebp:=
+
+ >=dev-libs/glib-2.67.1:2
+ >=dev-libs/libxslt-1.1.7
+ media-libs/woff2
+ gnome-keyring? ( app-crypt/libsecret )
+ introspection? ( >=dev-libs/gobject-introspection-1.59.1:= )
+ dev-libs/libtasn1:=
+ spell? ( >=app-text/enchant-0.22:2 )
+ gstreamer? (
+ >=media-libs/gstreamer-1.20:1.0
+ >=media-libs/gst-plugins-base-1.20:1.0[egl?,X?]
+ gles2-only? ( media-libs/gst-plugins-base:1.0[gles2] )
+ !gles2-only? ( media-libs/gst-plugins-base:1.0[opengl] )
+ >=media-plugins/gst-plugins-opus-1.20:1.0
+ >=media-libs/gst-plugins-bad-1.20:1.0
+ )
+
+ X? (
+ x11-libs/libX11
+ x11-libs/libXcomposite
+ x11-libs/libXdamage
+ x11-libs/libXrender
+ x11-libs/libXt
+ )
+
+ libnotify? ( x11-libs/libnotify )
+ dev-libs/hyphen
+ jpeg2k? ( >=media-libs/openjpeg-2.2.0:2= )
+ avif? ( >=media-libs/libavif-0.9.0:= )
+ lcms? ( media-libs/lcms:2 )
+
+ egl? ( media-libs/mesa[egl(+)] )
+ gles2-only? ( media-libs/mesa[gles2] )
+ !gles2-only? ( virtual/opengl )
+ wayland? (
+ dev-libs/wayland
+ >=dev-libs/wayland-protocols-1.12
+ >=gui-libs/libwpe-1.5.0:1.0
+ >=gui-libs/wpebackend-fdo-1.7.0:1.0
+ )
+
+ seccomp? (
+ >=sys-apps/bubblewrap-0.3.1
+ sys-libs/libseccomp
+ sys-apps/xdg-dbus-proxy
+ )
+
+ systemd? ( sys-apps/systemd:= )
+ gamepad? ( >=dev-libs/libmanette-0.2.4 )
+"
+DEPEND="${RDEPEND}"
+# Need real bison, not yacc
+BDEPEND="
+ ${PYTHON_DEPS}
+ ${RUBY_DEPS}
+ >=app-accessibility/at-spi2-core-2.5.3
+ dev-util/glib-utils
+ >=dev-util/gperf-3.0.1
+ >=sys-devel/bison-2.4.3
+ || ( >=sys-devel/gcc-7.3 >=sys-devel/clang-5 )
+ sys-devel/gettext
+ virtual/pkgconfig
+
+ >=dev-lang/perl-5.10
+ virtual/perl-Data-Dumper
+ virtual/perl-Carp
+ virtual/perl-JSON-PP
+
+ gtk-doc? ( >=dev-util/gtk-doc-1.32 )
+ geolocation? ( dev-util/gdbus-codegen )
+ >=dev-util/cmake-3.10
+"
+# test? (
+# dev-python/pygobject:3[python_targets_python2_7]
+# x11-themes/hicolor-icon-theme
+# )
+RDEPEND="${RDEPEND}
+ geolocation? ( >=app-misc/geoclue-2.1.5:2.0 )
+"
+
+S="${WORKDIR}/${MY_P}"
+
+CHECKREQS_DISK_BUILD="18G" # and even this might not be enough, bug #417307
+
+pkg_pretend() {
+ if [[ ${MERGE_TYPE} != "binary" ]] ; then
+ if is-flagq "-g*" && ! is-flagq "-g*0" ; then
+ einfo "Checking for sufficient disk space to build ${PN} with debugging CFLAGS"
+ check-reqs_pkg_pretend
+ fi
+
+ if ! test-flag-CXX -std=c++17 ; then
+ die "You need at least GCC 7.3.x or Clang >= 5 for C++17-specific compiler flags"
+ fi
+ fi
+}
+
+pkg_setup() {
+ if [[ ${MERGE_TYPE} != "binary" ]] && is-flagq "-g*" && ! is-flagq "-g*0" ; then
+ check-reqs_pkg_setup
+ fi
+
+ python-any-r1_pkg_setup
+}
+
+src_prepare() {
+ cmake_src_prepare
+ gnome2_src_prepare
+}
+
+src_configure() {
+ # Respect CC, otherwise fails on prefix #395875
+ tc-export CC
+
+ # It does not compile on alpha without this in LDFLAGS
+ # https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=648761
+ use alpha && append-ldflags "-Wl,--no-relax"
+
+ # ld segfaults on ia64 with LDFLAGS --as-needed, bug #555504
+ use ia64 && append-ldflags "-Wl,--no-as-needed"
+
+ # Sigbuses on SPARC with mcpu and co., bug #???
+ use sparc && filter-flags "-mvis"
+
+ # https://bugs.webkit.org/show_bug.cgi?id=42070 , #301634
+ use ppc64 && append-flags "-mminimal-toc"
+
+ # Try to use less memory, bug #469942 (see Fedora .spec for reference)
+ # --no-keep-memory doesn't work on ia64, bug #502492
+ if ! use ia64; then
+ append-ldflags $(test-flags-CCLD "-Wl,--no-keep-memory")
+ fi
+
+ # Ruby situation is a bit complicated. See bug 513888
+ local rubyimpl
+ local ruby_interpreter=""
+ for rubyimpl in ${USE_RUBY}; do
+ if has_version -b "virtual/rubygems[ruby_targets_${rubyimpl}]"; then
+ ruby_interpreter="-DRUBY_EXECUTABLE=$(type -P ${rubyimpl})"
+ fi
+ done
+ # This will rarely occur. Only a couple of corner cases could lead us to
+ # that failure. See bug 513888
+ [[ -z $ruby_interpreter ]] && die "No suitable ruby interpreter found"
+
+ # TODO: Check Web Audio support
+ # should somehow let user select between them?
+
+ local mycmakeargs=(
+ ${ruby_interpreter}
+ $(cmake_use_find_package gles2-only OpenGLES2)
+ $(cmake_use_find_package egl EGL)
+ $(cmake_use_find_package !gles2-only OpenGL)
+ -DBWRAP_EXECUTABLE:FILEPATH="${EPREFIX}"/usr/bin/bwrap # If bubblewrap[suid] then portage makes it go-r and cmake find_program fails with that
+ -DDBUS_PROXY_EXECUTABLE:FILEPATH="${EPREFIX}"/usr/bin/xdg-dbus-proxy
+ -DPORT=GTK
+ # Source/cmake/WebKitFeatures.cmake
+ -DENABLE_API_TESTS=$(usex test)
+ -DENABLE_BUBBLEWRAP_SANDBOX=$(usex seccomp)
+ -DENABLE_GAMEPAD=$(usex gamepad)
+ -DENABLE_GEOLOCATION=$(usex geolocation) # Runtime optional (talks over dbus service)
+ -DENABLE_MINIBROWSER=$(usex examples)
+ -DENABLE_SPELLCHECK=$(usex spell)
+ -DENABLE_UNIFIED_BUILDS=$(usex jumbo-build)
+ -DENABLE_VIDEO=$(usex gstreamer)
+ -DENABLE_WEBGL=ON
+ # Supported only under ANGLE
+ -DENABLE_WEBGL2=OFF
+ -DENABLE_WEB_AUDIO=$(usex gstreamer)
+ # Source/cmake/OptionsGTK.cmake
+ -DENABLE_GLES2=$(usex gles2-only)
+ -DENABLE_GTKDOC=$(usex gtk-doc)
+ -DENABLE_INTROSPECTION=$(usex introspection)
+ -DENABLE_JOURNALD_LOG=$(usex systemd)
+ -DENABLE_QUARTZ_TARGET=$(usex aqua)
+ -DENABLE_WAYLAND_TARGET=$(usex wayland)
+ -DENABLE_X11_TARGET=$(usex X)
+ -DUSE_ANGLE_WEBGL=OFF
+ -DUSE_AVIF=$(usex avif)
+ -DUSE_GTK4=OFF
+ -DUSE_JPEGXL=OFF
+ -DUSE_LCMS=$(usex lcms)
+ -DUSE_LIBHYPHEN=ON
+ -DUSE_LIBNOTIFY=$(usex libnotify)
+ -DUSE_LIBSECRET=$(usex gnome-keyring)
+ -DUSE_OPENGL_OR_ES=ON
+ -DUSE_OPENJPEG=$(usex jpeg2k)
+ -DUSE_SOUP2=ON
+ -DUSE_WOFF2=ON
+ -DUSE_WPE_RENDERER=$(usex wayland) # WPE renderer is used to implement accelerated compositing under wayland
+ )
+
+ # https://bugs.gentoo.org/761238
+ append-cppflags -DNDEBUG
+
+ WK_USE_CCACHE=NO cmake_src_configure
+}