summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorBen Kohler <bkohler@gentoo.org>2019-02-23 11:40:20 -0600
committerBen Kohler <bkohler@gentoo.org>2019-02-23 11:40:43 -0600
commit899128a1dfe2c21fa99d28d542fb4a97a6fc81a1 (patch)
tree8dfd70f37914722e5c71dc01934ed7938f061081
parentgnome-extra/gnome-tweak-tool: drop unnecessary subslot operator dep (diff)
downloadgentoo-899128a1dfe2c21fa99d28d542fb4a97a6fc81a1.tar.gz
gentoo-899128a1dfe2c21fa99d28d542fb4a97a6fc81a1.tar.bz2
gentoo-899128a1dfe2c21fa99d28d542fb4a97a6fc81a1.zip
net-wireless/iwd: revbump to add -fsigned-char
Upstream recommends this compiler option and is default-enabling it when CFLAGS is unset. This commit will keep it enabled even when we set CFLAGS. This fixes a test on ppc (and maybe other arches). Package-Manager: Portage-2.3.62, Repoman-2.3.12 Signed-off-by: Ben Kohler <bkohler@gentoo.org>
-rw-r--r--net-wireless/iwd/iwd-0.14-r1.ebuild107
-rw-r--r--net-wireless/iwd/iwd-9999.ebuild3
2 files changed, 109 insertions, 1 deletions
diff --git a/net-wireless/iwd/iwd-0.14-r1.ebuild b/net-wireless/iwd/iwd-0.14-r1.ebuild
new file mode 100644
index 00000000000..bf525992339
--- /dev/null
+++ b/net-wireless/iwd/iwd-0.14-r1.ebuild
@@ -0,0 +1,107 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools flag-o-matic linux-info systemd
+
+if [[ ${PV} == 9999 ]]; then
+ EGIT_REPO_URI="https://git.kernel.org/pub/scm/network/wireless/iwd.git"
+ inherit git-r3
+else
+ SRC_URI="https://www.kernel.org/pub/linux/network/wireless/${P}.tar.xz"
+ KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~x86"
+fi
+
+DESCRIPTION="Wireless daemon for linux"
+HOMEPAGE="https://git.kernel.org/pub/scm/network/wireless/iwd.git/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="+client +monitor ofono wired cpu_flags_x86_aes cpu_flags_x86_ssse3"
+
+RDEPEND="sys-apps/dbus
+ client? ( sys-libs/readline:0= )"
+
+DEPEND="${RDEPEND}
+ virtual/pkgconfig"
+
+pkg_pretend() {
+ CONFIG_CHECK="
+ ~ASYMMETRIC_KEY_TYPE
+ ~ASYMMETRIC_PUBLIC_KEY_SUBTYPE
+ ~CRYPTO_AES
+ ~CRYPTO_ARC4
+ ~CRYPTO_CBC
+ ~CRYPTO_CMAC
+ ~CRYPTO_DES
+ ~CRYPTO_ECB
+ ~CRYPTO_HMAC
+ ~CRYPTO_MD4
+ ~CRYPTO_MD5
+ ~CRYPTO_RSA
+ ~CRYPTO_SHA1
+ ~CRYPTO_SHA256
+ ~CRYPTO_SHA512
+ ~CRYPTO_USER_API_HASH
+ ~CRYPTO_USER_API_SKCIPHER
+ ~KEY_DH_OPERATIONS
+ ~PKCS7_MESSAGE_PARSER
+ ~X509_CERTIFICATE_PARSER
+ "
+ if use amd64;then
+ CONFIG_CHECK="${CONFIG_CHECK} ~CRYPTO_AES_X86_64 ~CRYPTO_DES3_EDE_X86_64"
+ WARNING_CRYPTO_AES_X86_64="CRYPTO_AES_X86_64: enable for increased performance"
+ WARNING_CRYPTO_DES3_EDE_X86_64="CRYPTO_DES3_EDE_X86_64: enable for increased performance"
+ fi
+
+ if use cpu_flags_x86_aes;then
+ CONFIG_CHECK="${CONFIG_CHECK} ~CRYPTO_AES_NI_INTEL"
+ WARNING_CRYPTO_AES_NI_INTEL="CRYPTO_AES_NI_INTEL: enable for increased performance"
+ fi
+
+ if use cpu_flags_x86_ssse3; then
+ CONFIG_CHECK="${CONFIG_CHECK} ~CRYPTO_SHA1_SSSE3 ~CRYPTO_SHA256_SSSE3 ~CRYPTO_SHA512_SSSE3"
+ WARNING_CRYPTO_SHA1_SSSE3="CRYPTO_SHA1_SSSE3: enable for increased performance"
+ WARNING_CRYPTO_SHA256_SSSE3="CRYPTO_SHA256_SSSE3: enable for increased performance"
+ WARNING_CRYPTO_SHA512_SSSE3="CRYPTO_SHA512_SSSE3: enable for increased performance"
+ fi
+
+ check_extra_config
+}
+
+src_unpack() {
+ if [[ ${PV} == "9999" ]] ; then
+ git-r3_src_unpack
+ git clone git://git.kernel.org/pub/scm/libs/ell/ell.git "${WORKDIR}"/ell
+ else
+ default
+ fi
+}
+
+src_prepare() {
+ default
+ eautoreconf
+}
+
+src_configure() {
+ append-cflags "-fsigned-char"
+ econf --sysconfdir=/etc/iwd --localstatedir=/var \
+ $(use_enable client) \
+ $(use_enable monitor) \
+ $(use_enable ofono) \
+ $(use_enable wired) \
+ --enable-systemd-service \
+ --with-systemd-unitdir="$(systemd_get_systemunitdir)"
+}
+
+src_install() {
+ default
+ keepdir /var/lib/${PN}
+
+ newinitd "${FILESDIR}/iwd.initd" iwd
+
+ if [[ ${PV} == "9999" ]] ; then
+ exeinto /usr/share/iwd/scripts/
+ doexe test/*
+ fi
+}
diff --git a/net-wireless/iwd/iwd-9999.ebuild b/net-wireless/iwd/iwd-9999.ebuild
index 542d347128b..b037416528c 100644
--- a/net-wireless/iwd/iwd-9999.ebuild
+++ b/net-wireless/iwd/iwd-9999.ebuild
@@ -2,7 +2,7 @@
# Distributed under the terms of the GNU General Public License v2
EAPI=6
-inherit autotools linux-info systemd
+inherit autotools flag-o-matic linux-info systemd
if [[ ${PV} == 9999 ]]; then
EGIT_REPO_URI="https://git.kernel.org/pub/scm/network/wireless/iwd.git"
@@ -88,6 +88,7 @@ src_prepare() {
}
src_configure() {
+ append-cflags "-fsigned-char"
econf --sysconfdir=/etc/iwd --localstatedir=/var \
$(use_enable client) \
$(use_enable monitor) \