summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorBrian Dolbec <dolsen@gentoo.org>2016-09-01 10:07:22 -0700
committerBrian Dolbec <dolsen@gentoo.org>2016-09-01 10:13:48 -0700
commit960eb3f46e921f86cc82d73102637d61a092e8f7 (patch)
tree881213a013063f00de3c9ac18a3076350762f42f
parentwww-client/chromium: remove old (diff)
downloadgentoo-960eb3f46e921f86cc82d73102637d61a092e8f7.tar.gz
gentoo-960eb3f46e921f86cc82d73102637d61a092e8f7.tar.bz2
gentoo-960eb3f46e921f86cc82d73102637d61a092e8f7.zip
dev-util/buildbot: Version bump, syncronize deps in 9999
Package-Manager: portage-2.3.0
-rw-r--r--dev-util/buildbot/Manifest1
-rw-r--r--dev-util/buildbot/buildbot-0.9.0_rc2.ebuild209
-rw-r--r--dev-util/buildbot/buildbot-9999.ebuild21
3 files changed, 225 insertions, 6 deletions
diff --git a/dev-util/buildbot/Manifest b/dev-util/buildbot/Manifest
index 3f4671f2eef4..98ea485a4e15 100644
--- a/dev-util/buildbot/Manifest
+++ b/dev-util/buildbot/Manifest
@@ -1,3 +1,4 @@
DIST buildbot-0.8.10.tar.gz 4822307 SHA256 c4964d2ebd81cb80a14cb058fb2aab0572a1d8d86672d514e775b42deb08a5f4 SHA512 e148a1670a56837587d858d1697fe117661cbbfedab42bf7be905f9e8e4266e4ff0170b0cd81aed61234d30497a05427061c3084033f09811d0bc306b200661b WHIRLPOOL 26397b6f914266201aba4feb4df7353facad4fd0f51bdf7e35cf25205c45eadcf83f24c265e540b13d327750ce9561362be6a5aa237152cf1298d970c504f76c
DIST buildbot-0.8.12.tar.gz 4834352 SHA256 c6b66976dff712268566574d57131ec15e5682f6d4390cd5c8559bab0980c4d6 SHA512 18c5144132fb033f3581d3c494d5e8ff35d3e8b1548764452ce9ae543d710e58a2c6e3e8e46a0ef237804f9a6a45485890ae4616ab655fb00d4ccf328d6f6645 WHIRLPOOL 5754b7c0278fb5e7da8a7dd66253f6f4d12f54c125f6a78aa9018a2b6b22fd88a27e79e6821ab05e4cd9e87bf0dd08c3c73c7914d4c499ac13c48ca232ed21c8
DIST buildbot-0.9.0rc1.tar.gz 3004783 SHA256 f089c4c6494c82ad8d42bf80a356eef62580054d864a9c8b2217adeeec53ba27 SHA512 4ec664f24f001c172d378d378ced95ad4507893a0f989178b078f4364fc9e52b2fb79196fc6f440f94f36cb14fd7b9e53530b4f5ee21fb81a0698789676be778 WHIRLPOOL 049f9c4efa37658bb2d5c9b04017f260c3d04e5b2df4a66eb3b3d99d6119343dcb5f78f50c8b00959932c323acf512729dbc5acd76d46eb418c6f120a8cba4b6
+DIST buildbot-0.9.0rc2.tar.gz 3007080 SHA256 b3b2fa1a004f6c3a83a0d1222da8d3d5279498030565de28247e8d28bf5cbf1b SHA512 122a0016bf35c409c30a9407164bb1058a0e3701f339d8fb01fc619b12f5ccfaf0de90070051f2d68e4fbfcd28174df031a8c5e8d339911490d3ee14f6ac5d32 WHIRLPOOL bc09cfc862f8f5756a2cdd5cc297e691537f52ecfcbd84532d4173b468727e3db32e983a19c18b788f0f3f98afb8ddc698efebb0994be57f315097d6b1c1b685
diff --git a/dev-util/buildbot/buildbot-0.9.0_rc2.ebuild b/dev-util/buildbot/buildbot-0.9.0_rc2.ebuild
new file mode 100644
index 000000000000..239248c6c62b
--- /dev/null
+++ b/dev-util/buildbot/buildbot-0.9.0_rc2.ebuild
@@ -0,0 +1,209 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+PYTHON_REQ_USE="sqlite"
+PYTHON_COMPAT=( python2_7 )
+
+EGIT_REPO_URI="https://github.com/buildbot/${PN}.git"
+
+[[ ${PV} == *9999 ]] && inherit git-r3
+inherit readme.gentoo-r1 user systemd distutils-r1
+
+MY_V="0.9.0rc2"
+MY_P="${PN}-${MY_V}"
+
+DESCRIPTION="BuildBot build automation system"
+HOMEPAGE="http://trac.buildbot.net/ https://github.com/buildbot/buildbot http://pypi.python.org/pypi/buildbot"
+[[ ${PV} == *9999 ]] || SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+if [[ ${PV} == *9999 ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64"
+fi
+
+IUSE="crypt doc examples irc mail manhole test"
+
+RDEPEND=">=dev-python/jinja-2.1[${PYTHON_USEDEP}]
+ || (
+ >=dev-python/twisted-web-14.0.1[${PYTHON_USEDEP}]
+ >=dev-python/twisted-16.0.0[${PYTHON_USEDEP}]
+ )
+ >=dev-python/sqlalchemy-0.8[${PYTHON_USEDEP}]
+ >=dev-python/sqlalchemy-migrate-0.9[${PYTHON_USEDEP}]
+ crypt? (
+ >=dev-python/pyopenssl-0.13[${PYTHON_USEDEP}]
+ dev-python/idna[${PYTHON_USEDEP}]
+ dev-python/service_identity[${PYTHON_USEDEP}]
+ )
+ irc? (
+ dev-python/txrequests[${PYTHON_USEDEP}]
+ || ( >=dev-python/twisted-words-14.0.1[${PYTHON_USEDEP}]
+ >=dev-python/twisted-16.0.0[${PYTHON_USEDEP}]
+ )
+ )
+ mail? (
+ || ( >=dev-python/twisted-mail-14.0.1[${PYTHON_USEDEP}]
+ >=dev-python/twisted-16.0.0[${PYTHON_USEDEP}]
+ )
+ )
+ manhole? (
+ || ( >=dev-python/twisted-conch-14.0.1[${PYTHON_USEDEP}]
+ >=dev-python/twisted-16.0.0[${PYTHON_USEDEP}]
+ )
+ )
+ dev-python/future[${PYTHON_USEDEP}]
+ >=dev-python/python-dateutil-1.5[${PYTHON_USEDEP}]
+ || (
+ ( !<dev-python/twisted-16.3.0[${PYTHON_USEDEP}]
+ >=dev-python/autobahn-0.16.0[${PYTHON_USEDEP}]
+ )
+ ( || ( <dev-python/twisted-16.3.0[${PYTHON_USEDEP}]
+ dev-python/twisted-core[${PYTHON_USEDEP}]
+ )
+ dev-python/autobahn[${PYTHON_USEDEP}]
+ )
+ )
+ >=dev-python/txaio-2.2.2[${PYTHON_USEDEP}]
+ "
+DEPEND="${RDEPEND}
+ >=dev-python/setuptools-21.2.1[${PYTHON_USEDEP}]
+ doc? ( >=dev-python/sphinx-1.4.3[${PYTHON_USEDEP}] )
+ test? (
+ >=dev-python/python-dateutil-1.5[${PYTHON_USEDEP}]
+ dev-python/mock[${PYTHON_USEDEP}]
+ || (
+ (
+ >=dev-python/twisted-mail-14.0.1[${PYTHON_USEDEP}]
+ >=dev-python/twisted-web-14.0.1[${PYTHON_USEDEP}]
+ >=dev-python/twisted-words-14.0.1[${PYTHON_USEDEP}]
+ )
+ >=dev-python/twisted-16.0.0[${PYTHON_USEDEP}]
+ )
+ dev-python/moto[${PYTHON_USEDEP}]
+ dev-python/boto3[${PYTHON_USEDEP}]
+ dev-python/ramlfications[${PYTHON_USEDEP}]
+ dev-python/pyjade[${PYTHON_USEDEP}]
+ dev-python/txgithub[${PYTHON_USEDEP}]
+ dev-python/txrequests[${PYTHON_USEDEP}]
+ )"
+
+# still yet to be added deps
+# doc? ( 'sphinxcontrib-blockdiag',
+# 'sphinxcontrib-spelling',
+# 'pyenchant',
+# 'docutils>=0.8',
+# 'sphinx-jinja',)
+
+S=${WORKDIR}/${MY_P}
+[[ ${PV} == *9999 ]] && S=${S}/master
+
+pkg_setup() {
+ enewuser buildbot
+
+ DOC_CONTENTS="The \"buildbot\" user and the \"buildmaster\" init script has been added
+ to support starting buildbot through Gentoo's init system. To use this,
+ execute \"emerge --config =${CATEGORY}/${PF}\" to create a new instance.
+ The scripts can run as a different user if desired."
+}
+
+src_compile() {
+ distutils-r1_src_compile
+
+ if use doc; then
+ einfo "Generation of documentation"
+ pushd docs > /dev/null
+ #'man' target is currently broken
+ emake html
+ popd > /dev/null
+ fi
+}
+
+src_install() {
+ distutils-r1_src_install
+
+ doman docs/buildbot.1
+
+ if use doc; then
+ dohtml -r docs/_build/html/
+ # TODO: install man pages
+ fi
+
+ if use examples; then
+ insinto /usr/share/doc/${PF}
+ doins -r contrib docs/examples
+ fi
+
+ newconfd "${FILESDIR}/buildmaster.confd" buildmaster
+ newinitd "${FILESDIR}/buildmaster.initd" buildmaster
+ systemd_dounit "${FILESDIR}/buildmaster.target"
+ systemd_newunit "${FILESDIR}/buildmaster_at.service" "buildmaster@.service"
+ systemd_install_serviced "${FILESDIR}/buildmaster_at.service.conf" "buildmaster@.service"
+
+ readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+ readme.gentoo_print_elog
+
+ if [[ -n ${REPLACING_VERSIONS} ]]; then
+ ewarn
+ ewarn "Starting with buildbot-0.8.12-r2, more than one instance of buildmaster"
+ ewarn "can be run simultaneously. Note that \"BASEDIR\" in the buildbot configuration file"
+ ewarn "is now the common base directory for all instances. If you are migrating from an older"
+ ewarn "version, make sure that you copy the current contents of \"BASEDIR\" to a subdirectory."
+ ewarn "The name of the subdirectory corresponds to the name of the buildmaster instance."
+ ewarn "In order to start the service running OpenRC-based systems need to link to the init file:"
+ ewarn " ln --symbolic --relative /etc/init.d/buildmaster /etc/init.d/buildmaster.myinstance"
+ ewarn " rc-update add buildmaster.myinstance default"
+ ewarn " /etc/init.d/buildmaster.myinstance start"
+ ewarn "Systems using systemd can do the following:"
+ ewarn " systemctl enable buildmaster@myinstance.service"
+ ewarn " systemctl enable buildmaster.target"
+ ewarn " systemctl start buildmaster.target"
+ elog
+ elog "Upstream recommends the following when upgrading:"
+ elog "Each time you install a new version of Buildbot, you should run the"
+ elog "\"buildbot upgrade-master\" command on each of your pre-existing build masters."
+ elog "This will add files and fix (or at least detect) incompatibilities between"
+ elog "your old config and the new code."
+ fi
+ elog
+ elog "In order to create a new instance of buildmaster, execute:"
+ elog " emerge --config =${CATEGORY}/${PF}"
+}
+
+pkg_config() {
+ local buildmaster_path="/var/lib/buildmaster"
+ einfo "This will prepare a new buildmaster instance in ${buildmaster_path}."
+ einfo "Press Control-C to abort."
+
+ einfo "Enter the name for the new instance: "
+ read instance_name
+ [[ -z "${instance_name}" ]] && die "Invalid instance name"
+
+ local instance_path="${buildmaster_path}/${instance_name}"
+ if [[ -e "${instance_path}" ]]; then
+ eerror "The instance with the specified name already exists:"
+ eerror "${instance_path}"
+ die "Instance already exists"
+ fi
+
+ local buildbot="/usr/bin/buildbot"
+ if [[ ! -d "${buildmaster_path}" ]]; then
+ mkdir --parents "${buildmaster_path}" || die "Unable to create directory ${buildmaster_path}"
+ fi
+ "${buildbot}" create-master "${instance_path}" &>/dev/null || die "Creating instance failed"
+ chown --recursive buildbot "${instance_path}" || die "Setting permissions for instance failed"
+ mv "${instance_path}/master.cfg.sample" "${instance_path}/master.cfg" \
+ || die "Moving sample configuration failed"
+ ln --symbolic --relative "/etc/init.d/buildmaster" "/etc/init.d/buildmaster.${instance_name}" \
+ || die "Unable to create link to init file"
+
+ einfo "Successfully created a buildmaster instance at ${instance_path}."
+ einfo "To change the default settings edit the master.cfg file in this directory."
+}
diff --git a/dev-util/buildbot/buildbot-9999.ebuild b/dev-util/buildbot/buildbot-9999.ebuild
index 05d44461c011..1d53a34a8a5f 100644
--- a/dev-util/buildbot/buildbot-9999.ebuild
+++ b/dev-util/buildbot/buildbot-9999.ebuild
@@ -41,24 +41,33 @@ RDEPEND=">=dev-python/jinja-2.1[${PYTHON_USEDEP}]
dev-python/service_identity[${PYTHON_USEDEP}]
)
irc? (
+ dev-python/txrequests[${PYTHON_USEDEP}]
|| ( >=dev-python/twisted-words-14.0.1[${PYTHON_USEDEP}]
- <dev-python/twisted-16.3.0[${PYTHON_USEDEP}]
+ >=dev-python/twisted-16.0.0[${PYTHON_USEDEP}]
)
)
mail? (
|| ( >=dev-python/twisted-mail-14.0.1[${PYTHON_USEDEP}]
- <dev-python/twisted-16.3.0[${PYTHON_USEDEP}]
+ >=dev-python/twisted-16.0.0[${PYTHON_USEDEP}]
)
)
manhole? (
|| ( >=dev-python/twisted-conch-14.0.1[${PYTHON_USEDEP}]
- <dev-python/twisted-16.3.0[${PYTHON_USEDEP}]
+ >=dev-python/twisted-16.0.0[${PYTHON_USEDEP}]
)
)
dev-python/future[${PYTHON_USEDEP}]
>=dev-python/python-dateutil-1.5[${PYTHON_USEDEP}]
- >=dev-python/autobahn-0.10.2[${PYTHON_USEDEP}]
- <dev-python/autobahn-0.13.0[${PYTHON_USEDEP}]
+ || (
+ ( !<dev-python/twisted-16.3.0[${PYTHON_USEDEP}]
+ >=dev-python/autobahn-0.16.0[${PYTHON_USEDEP}]
+ )
+ ( || ( <dev-python/twisted-16.3.0[${PYTHON_USEDEP}]
+ dev-python/twisted-core[${PYTHON_USEDEP}]
+ )
+ dev-python/autobahn[${PYTHON_USEDEP}]
+ )
+ )
>=dev-python/txaio-2.2.2[${PYTHON_USEDEP}]
"
DEPEND="${RDEPEND}
@@ -73,7 +82,7 @@ DEPEND="${RDEPEND}
>=dev-python/twisted-web-14.0.1[${PYTHON_USEDEP}]
>=dev-python/twisted-words-14.0.1[${PYTHON_USEDEP}]
)
- <dev-python/twisted-16.3.0[${PYTHON_USEDEP}]
+ >=dev-python/twisted-16.0.0[${PYTHON_USEDEP}]
)
dev-python/moto[${PYTHON_USEDEP}]
dev-python/boto3[${PYTHON_USEDEP}]