summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorBrian Dolbec <dolsen@gentoo.org>2017-06-19 10:33:09 -0700
committerBrian Dolbec <dolsen@gentoo.org>2017-06-19 11:29:37 -0700
commit96536bbcdba3c1c205a4df2128dc5183c5275fa6 (patch)
tree02b5b88f46ca5fb8238c31ab8d6c7adff2c9edc8
parentdev-ruby/net-http-pipeline: add ruby24 (diff)
downloadgentoo-96536bbcdba3c1c205a4df2128dc5183c5275fa6.zip
gentoo-96536bbcdba3c1c205a4df2128dc5183c5275fa6.tar.gz
gentoo-96536bbcdba3c1c205a4df2128dc5183c5275fa6.tar.bz2
dev-util/buildbot: Version bump, update 9999
Package-Manager: Portage-2.3.6_p2, Repoman-2.3.2_p70
-rw-r--r--dev-util/buildbot/Manifest1
-rw-r--r--dev-util/buildbot/buildbot-0.9.8.ebuild194
-rw-r--r--dev-util/buildbot/buildbot-9999.ebuild11
3 files changed, 203 insertions, 3 deletions
diff --git a/dev-util/buildbot/Manifest b/dev-util/buildbot/Manifest
index 6dc7554..a0e595b 100644
--- a/dev-util/buildbot/Manifest
+++ b/dev-util/buildbot/Manifest
@@ -3,3 +3,4 @@ DIST buildbot-0.8.12.tar.gz 4834352 SHA256 c6b66976dff712268566574d57131ec15e568
DIST buildbot-0.9.4.docs.tar.xz 69224 SHA256 69fc33762a885568b02c42954a64d62d28bcb750b3aed011c3da8a9f84c13371 SHA512 906e551e0db32c8a0b4010b3b8b00c4776e3d1b7d7381e4dc0ccf01d361184e4605c3ab0ecaf4e42207bd73c3e72f8a570a4d4c29db72f4d68241abf48741d7e WHIRLPOOL 95f263e0b9ab22a649118f362d866b08cbdf62511f2a1f9bd6a7265103f174e35d0c8d86ad6a3b7dd5fd0b4277d60dbd25801c5e6f7e414e7fa634c241dae987
DIST buildbot-0.9.4.tar.gz 3020851 SHA256 068161cd9ada10b87f40117c768a37ce796ebf5e7bf08f224f4c7ded88cd7472 SHA512 938a94192560b989a277d9650c50781d7e7c116bc5e2010ccb2e655df757de0ee254369531b2f432c835c0285c724e52d999a393d0ce1b104d4b9dcc5c6687da WHIRLPOOL 0ffe61b82ee93b78cdb3cb74ef96d5a3547e0fcab9ec8093b59a7212c5e2a1ad16eff046306bffcc0ea63b2e0bf2df1e54b5a0874dc78e27744db2088ccac804
DIST buildbot-0.9.7.tar.gz 3092434 SHA256 8fcbf0e6536e5d60407f59d14f96d5f8386cd91846a4fa47b4336d71551a9e33 SHA512 3fd2b488cabac37e297bb1a475cdb115f261324a22ec4d6fbcf8dc5bfb6ee135fab3763998433be8795581d476f69e2adb6f42d248bf2131a42eecfc1667202a WHIRLPOOL 427d4c1c452f767550a3d2731b2e34480c399dcf50e57d4fb69f0a350f381e3e7ecc47d712fc8fbb99afcf8b230c7bd3afe8437ec3b24bf9ddbf7d35b4d1caad
+DIST buildbot-0.9.8.tar.gz 3101418 SHA256 39a2f7df458ec9be1009cf90a02d732d142a2ec3fbc0404e4f3fce4b8a4c3af7 SHA512 88800bad542d26aee6df348021faf5f76f36c250e9fb85c9abe3af7f13ec87fcae5727c8633772205f5c024709fd39b05d1d9c3aa1374b4ca72a528b5ec3ba83 WHIRLPOOL fafb46f6d6bc10f6073567cd6a6894cd67d61c4ff537b342060319874eb22ea45d816f6b764f0b9f841f9b7a5e127481a85dbb4abbacd228a8168a5e3e948b2b
diff --git a/dev-util/buildbot/buildbot-0.9.8.ebuild b/dev-util/buildbot/buildbot-0.9.8.ebuild
new file mode 100644
index 00000000..a32f4fa
--- /dev/null
+++ b/dev-util/buildbot/buildbot-0.9.8.ebuild
@@ -0,0 +1,194 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="5"
+PYTHON_REQ_USE="sqlite"
+PYTHON_COMPAT=( python2_7 python3_5 )
+
+EGIT_REPO_URI="https://github.com/buildbot/${PN}.git"
+
+[[ ${PV} == *9999 ]] && inherit git-r3
+inherit readme.gentoo-r1 user systemd distutils-r1
+
+MY_PV="${PV/_p/p}"
+MY_P="${PN}-${MY_PV}"
+
+DESCRIPTION="BuildBot build automation system"
+HOMEPAGE="https://buildbot.net/ https://github.com/buildbot/buildbot https://pypi.python.org/pypi/buildbot"
+[[ ${PV} == *9999 ]] || SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+if [[ ${PV} == *9999 ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~amd64"
+fi
+
+IUSE="crypt doc examples irc test"
+
+RDEPEND="
+ >=dev-python/jinja-2.1[${PYTHON_USEDEP}]
+ >=dev-python/twisted-17.5.0[${PYTHON_USEDEP}]
+ >=dev-python/autobahn-0.16.0[${PYTHON_USEDEP}]
+ >=dev-python/sqlalchemy-0.8[${PYTHON_USEDEP}]
+ >=dev-python/sqlalchemy-migrate-0.9[${PYTHON_USEDEP}]
+ crypt? (
+ >=dev-python/twisted-17.5.0[${PYTHON_USEDEP},crypt]
+ >=dev-python/pyopenssl-16.0.0[${PYTHON_USEDEP}]
+ dev-python/idna[${PYTHON_USEDEP}]
+ dev-python/service_identity[${PYTHON_USEDEP}]
+ )
+ irc? (
+ dev-python/txrequests[${PYTHON_USEDEP}]
+ )
+ dev-python/future[${PYTHON_USEDEP}]
+ >=dev-python/python-dateutil-1.5[${PYTHON_USEDEP}]
+ >=dev-python/txaio-2.2.2[${PYTHON_USEDEP}]
+ dev-python/pyjwt[${PYTHON_USEDEP}]
+ dev-python/distro[${PYTHON_USEDEP}]
+ >=dev-python/zope-interface-4.1.1[${PYTHON_USEDEP}]
+ ~dev-util/buildbot-worker-${PV}[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}
+ >=dev-python/setuptools-21.2.1[${PYTHON_USEDEP}]
+ doc? (
+ >=dev-python/sphinx-1.4.3[${PYTHON_USEDEP}]
+ dev-python/sphinxcontrib-blockdiag[${PYTHON_USEDEP}]
+ dev-python/sphinxcontrib-spelling[${PYTHON_USEDEP}]
+ dev-python/pyenchant[${PYTHON_USEDEP}]
+ >=dev-python/docutils-0.8[${PYTHON_USEDEP}]
+ <dev-python/docutils-0.13.0[${PYTHON_USEDEP}]
+ dev-python/sphinx-jinja[${PYTHON_USEDEP}]
+ dev-python/ramlfications[${PYTHON_USEDEP}]
+ )
+ test? (
+ >=dev-python/python-dateutil-1.5[${PYTHON_USEDEP}]
+ >=dev-python/mock-2.0.0[${PYTHON_USEDEP}]
+ dev-python/moto[${PYTHON_USEDEP}]
+ dev-python/boto3[${PYTHON_USEDEP}]
+ dev-python/ramlfications[${PYTHON_USEDEP}]
+ dev-python/pyjade[${PYTHON_USEDEP}]
+ dev-python/txgithub[${PYTHON_USEDEP}]
+ dev-python/txrequests[${PYTHON_USEDEP}]
+ dev-python/lz4[${PYTHON_USEDEP}]
+ dev-python/treq[${PYTHON_USEDEP}]
+ dev-python/setuptools_trial[${PYTHON_USEDEP}]
+ ~dev-util/buildbot-worker-${PV}[${PYTHON_USEDEP}]
+ )"
+
+S=${WORKDIR}/${MY_P}
+[[ ${PV} == *9999 ]] && S=${S}/master
+
+pkg_setup() {
+ enewuser buildbot
+
+ DOC_CONTENTS="The \"buildbot\" user and the \"buildmaster\" init script has been added
+ to support starting buildbot through Gentoo's init system. To use this,
+ execute \"emerge --config =${CATEGORY}/${PF}\" to create a new instance.
+ The scripts can run as a different user if desired."
+}
+
+src_compile() {
+ distutils-r1_src_compile
+
+ if use doc; then
+ einfo "Generation of documentation"
+ pushd docs > /dev/null
+ #'man' target is currently broken
+ emake html
+ popd > /dev/null
+ fi
+}
+
+src_install() {
+ distutils-r1_src_install
+
+ doman docs/buildbot.1
+
+ if use doc; then
+ dohtml -r docs/_build/html/
+ # TODO: install man pages
+ fi
+
+ if use examples; then
+ insinto /usr/share/doc/${PF}
+ doins -r contrib docs/examples
+ fi
+
+ newconfd "${FILESDIR}/buildmaster.confd" buildmaster
+ newinitd "${FILESDIR}/buildmaster.initd" buildmaster
+ systemd_dounit "${FILESDIR}/buildmaster.target"
+ systemd_newunit "${FILESDIR}/buildmaster_at.service" "buildmaster@.service"
+ systemd_install_serviced "${FILESDIR}/buildmaster_at.service.conf" "buildmaster@.service"
+
+ readme.gentoo_create_doc
+}
+
+python_test() {
+ distutils_install_for_testing
+ export TEST_HYPER=1
+
+ esetup.py test || die "Tests failed under ${EPYTHON}"
+}
+
+pkg_postinst() {
+ readme.gentoo_print_elog
+
+ if [[ -n ${REPLACING_VERSIONS} ]]; then
+ ewarn
+ ewarn "Starting with buildbot-0.8.12-r2, more than one instance of buildmaster"
+ ewarn "can be run simultaneously. Note that \"BASEDIR\" in the buildbot configuration file"
+ ewarn "is now the common base directory for all instances. If you are migrating from an older"
+ ewarn "version, make sure that you copy the current contents of \"BASEDIR\" to a subdirectory."
+ ewarn "The name of the subdirectory corresponds to the name of the buildmaster instance."
+ ewarn "In order to start the service running OpenRC-based systems need to link to the init file:"
+ ewarn " ln --symbolic --relative /etc/init.d/buildmaster /etc/init.d/buildmaster.myinstance"
+ ewarn " rc-update add buildmaster.myinstance default"
+ ewarn " /etc/init.d/buildmaster.myinstance start"
+ ewarn "Systems using systemd can do the following:"
+ ewarn " systemctl enable buildmaster@myinstance.service"
+ ewarn " systemctl enable buildmaster.target"
+ ewarn " systemctl start buildmaster.target"
+ elog
+ elog "Upstream recommends the following when upgrading:"
+ elog "Each time you install a new version of Buildbot, you should run the"
+ elog "\"buildbot upgrade-master\" command on each of your pre-existing build masters."
+ elog "This will add files and fix (or at least detect) incompatibilities between"
+ elog "your old config and the new code."
+ fi
+ elog
+ elog "In order to create a new instance of buildmaster, execute:"
+ elog " emerge --config =${CATEGORY}/${PF}"
+}
+
+pkg_config() {
+ local buildmaster_path="/var/lib/buildmaster"
+ einfo "This will prepare a new buildmaster instance in ${buildmaster_path}."
+ einfo "Press Control-C to abort."
+
+ einfo "Enter the name for the new instance: "
+ read instance_name
+ [[ -z "${instance_name}" ]] && die "Invalid instance name"
+
+ local instance_path="${buildmaster_path}/${instance_name}"
+ if [[ -e "${instance_path}" ]]; then
+ eerror "The instance with the specified name already exists:"
+ eerror "${instance_path}"
+ die "Instance already exists"
+ fi
+
+ local buildbot="/usr/bin/buildbot"
+ if [[ ! -d "${buildmaster_path}" ]]; then
+ mkdir --parents "${buildmaster_path}" || die "Unable to create directory ${buildmaster_path}"
+ fi
+ "${buildbot}" create-master "${instance_path}" &>/dev/null || die "Creating instance failed"
+ chown --recursive buildbot "${instance_path}" || die "Setting permissions for instance failed"
+ mv "${instance_path}/master.cfg.sample" "${instance_path}/master.cfg" \
+ || die "Moving sample configuration failed"
+ ln --symbolic --relative "/etc/init.d/buildmaster" "/etc/init.d/buildmaster.${instance_name}" \
+ || die "Unable to create link to init file"
+
+ einfo "Successfully created a buildmaster instance at ${instance_path}."
+ einfo "To change the default settings edit the master.cfg file in this directory."
+}
diff --git a/dev-util/buildbot/buildbot-9999.ebuild b/dev-util/buildbot/buildbot-9999.ebuild
index 834f434..ed83f83 100644
--- a/dev-util/buildbot/buildbot-9999.ebuild
+++ b/dev-util/buildbot/buildbot-9999.ebuild
@@ -3,7 +3,7 @@
EAPI="5"
PYTHON_REQ_USE="sqlite"
-PYTHON_COMPAT=( python2_7 python3_{4,5} )
+PYTHON_COMPAT=( python2_7 python3_5 )
EGIT_REPO_URI="https://github.com/buildbot/${PN}.git"
@@ -29,12 +29,12 @@ IUSE="crypt doc examples irc test"
RDEPEND="
>=dev-python/jinja-2.1[${PYTHON_USEDEP}]
- $(python_gen_cond_dep '>=dev-python/twisted-16.0.0[${PYTHON_USEDEP},crypt?]' python2_7 )
- $(python_gen_cond_dep '>=dev-python/twisted-17.1.0[${PYTHON_USEDEP},crypt?]' python3_5 python3_6 )
+ >=dev-python/twisted-17.5.0[${PYTHON_USEDEP}]
>=dev-python/autobahn-0.16.0[${PYTHON_USEDEP}]
>=dev-python/sqlalchemy-0.8[${PYTHON_USEDEP}]
>=dev-python/sqlalchemy-migrate-0.9[${PYTHON_USEDEP}]
crypt? (
+ >=dev-python/twisted-17.5.0[${PYTHON_USEDEP},crypt]
>=dev-python/pyopenssl-16.0.0[${PYTHON_USEDEP}]
dev-python/idna[${PYTHON_USEDEP}]
dev-python/service_identity[${PYTHON_USEDEP}]
@@ -48,6 +48,7 @@ RDEPEND="
dev-python/pyjwt[${PYTHON_USEDEP}]
dev-python/distro[${PYTHON_USEDEP}]
>=dev-python/zope-interface-4.1.1[${PYTHON_USEDEP}]
+ ~dev-util/buildbot-worker-${PV}[${PYTHON_USEDEP}]
"
DEPEND="${RDEPEND}
>=dev-python/setuptools-21.2.1[${PYTHON_USEDEP}]
@@ -70,6 +71,10 @@ DEPEND="${RDEPEND}
dev-python/pyjade[${PYTHON_USEDEP}]
dev-python/txgithub[${PYTHON_USEDEP}]
dev-python/txrequests[${PYTHON_USEDEP}]
+ dev-python/lz4[${PYTHON_USEDEP}]
+ dev-python/treq[${PYTHON_USEDEP}]
+ dev-python/setuptools_trial[${PYTHON_USEDEP}]
+ ~dev-util/buildbot-worker-${PV}[${PYTHON_USEDEP}]
)"
S=${WORKDIR}/${MY_P}