dev-libs/liborcus: Add USE=spreadsheet-model,tools (bugs 571964, 571966)

Further changes:
EAPI=6
0.7.1 and 0.9.2 - pin required mdds slot 0 and liborcus version
9999 - pin required mdds slot 1

Package-Manager: portage-2.2.27

5 files changed, 75 insertions, 13 deletions

diff --git a/dev-libs/liborcus/liborcus-0.7.1-r1.ebuild b/dev-libs/liborcus/liborcus-0.7.1-r1.ebuild
new file mode 100644
index 000000000000..3612205fec10
--- /dev/null
+++ b/dev-libs/liborcus/liborcus-0.7.1-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+EGIT_REPO_URI="git://gitlab.com/orcus/orcus.git"
+
+[[ ${PV} == 9999 ]] && GITECLASS="git-r3 autotools"
+inherit eutils ${GITECLASS}
+unset GITECLASS
+
+DESCRIPTION="Standalone file import filter library for spreadsheet documents"
+HOMEPAGE="https://gitlab.com/orcus/orcus"
+[[ ${PV} == 9999 ]] || SRC_URI="http://kohei.us/files/orcus/src/${P}.tar.xz"
+
+LICENSE="MIT"
+SLOT="0"
+[[ ${PV} == 9999 ]] || \
+KEYWORDS="~amd64 ~arm ~ppc ~x86"
+
+IUSE="+spreadsheet-model static-libs tools"
+
+RDEPEND="
+	>=dev-libs/boost-1.51.0:=
+	sys-libs/zlib:=
+	spreadsheet-model? ( =dev-libs/libixion-0.9*:= )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/mdds-0.8.1:0
+"
+
+src_prepare() {
+	eapply_user
+	[[ ${PV} == 9999 ]] && eautoreconf
+}
+
+src_configure() {
+	econf \
+		--disable-werror \
+		$(use_enable spreadsheet-model) \
+		$(use_enable static-libs static) \
+		$(use_with tools)
+}
+
+src_install() {
+	default
+
+	prune_libtool_files --all
+}
diff --git a/dev-libs/liborcus/liborcus-0.7.1.ebuild b/dev-libs/liborcus/liborcus-0.7.1.ebuild
index 7c68d4c97fbe..87cbf3624b7b 100644
--- a/dev-libs/liborcus/liborcus-0.7.1.ebuild
+++ b/dev-libs/liborcus/liborcus-0.7.1.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2015 Gentoo Foundation
+# Copyright 1999-2016 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 # $Id$
 
@@ -23,11 +23,11 @@ IUSE="static-libs"
 
 RDEPEND="
 	>=dev-libs/boost-1.51.0:=
-	>=dev-libs/libixion-0.9:=
+	=dev-libs/libixion-0.9*:=
 	sys-libs/zlib:=
 "
 DEPEND="${RDEPEND}
-	>=dev-util/mdds-0.8.1
+	>=dev-util/mdds-0.8.1:0
 "
 
 src_prepare() {
diff --git a/dev-libs/liborcus/liborcus-0.9.2.ebuild b/dev-libs/liborcus/liborcus-0.9.2-r1.ebuild
index 6668627e3640..8a6c9f20feb3 100644
--- a/dev-libs/liborcus/liborcus-0.9.2.ebuild
+++ b/dev-libs/liborcus/liborcus-0.9.2-r1.ebuild
@@ -1,8 +1,8 @@
-# Copyright 1999-2015 Gentoo Foundation
+# Copyright 1999-2016 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 # $Id$
 
-EAPI=5
+EAPI=6
 
 EGIT_REPO_URI="https://gitlab.com/orcus/orcus.git"
 
@@ -15,31 +15,34 @@ HOMEPAGE="https://gitlab.com/orcus/orcus/blob/master/README.md"
 [[ ${PV} == 9999 ]] || SRC_URI="http://kohei.us/files/orcus/src/${P}.tar.xz"
 
 LICENSE="MIT"
-SLOT="0/0.10"
+SLOT="0/0.10" # based on SONAME of liborcus.so
 
 #[[ ${PV} == 9999 ]] || \
 #KEYWORDS="~amd64 ~arm ~ppc ~x86"
 KEYWORDS=""
 
-IUSE="static-libs"
+IUSE="+spreadsheet-model static-libs tools"
 
 RDEPEND="
 	>=dev-libs/boost-1.51.0:=
-	=dev-libs/libixion-0.9*:=
 	sys-libs/zlib:=
+	spreadsheet-model? ( =dev-libs/libixion-0.9*:= )
 "
 DEPEND="${RDEPEND}
-	>=dev-util/mdds-0.11
+	>=dev-util/mdds-0.11:0
 "
 
 src_prepare() {
+	eapply_user
 	[[ ${PV} == 9999 ]] && eautoreconf
 }
 
 src_configure() {
 	econf \
 		--disable-werror \
-		$(use_enable static-libs static)
+		$(use_enable spreadsheet-model) \
+		$(use_enable static-libs static) \
+		$(use_with tools)
 }
 
 src_install() {
diff --git a/dev-libs/liborcus/liborcus-9999.ebuild b/dev-libs/liborcus/liborcus-9999.ebuild
index e87413f36da0..64a4c246dcdb 100644
--- a/dev-libs/liborcus/liborcus-9999.ebuild
+++ b/dev-libs/liborcus/liborcus-9999.ebuild
@@ -20,13 +20,13 @@ LICENSE="MIT"
 SLOT="0/0.11" # based on SONAME of liborcus.so
 [[ ${PV} == 9999 ]] || \
 KEYWORDS="~amd64 ~arm ~ppc ~x86"
-IUSE="python static-libs"
+IUSE="python +spreadsheet-model static-libs tools"
 
 RDEPEND="
 	>=dev-libs/boost-1.51.0:=
-	=dev-libs/libixion-9999:=
 	sys-libs/zlib:=
 	python? ( ${PYTHON_DEPS} )
+	spreadsheet-model? ( =dev-libs/libixion-9999:= )
 "
 DEPEND="${RDEPEND}
 	dev-util/mdds:1
@@ -47,7 +47,9 @@ src_configure() {
 	econf \
 		--disable-werror \
 		$(use_enable python) \
-		$(use_enable static-libs static)
+		$(use_enable spreadsheet-model) \
+		$(use_enable static-libs static) \
+		$(use_with tools)
 }
 
 src_install() {
diff --git a/dev-libs/liborcus/metadata.xml b/dev-libs/liborcus/metadata.xml
index 13ce236ee519..76fa89e1b408 100644
--- a/dev-libs/liborcus/metadata.xml
+++ b/dev-libs/liborcus/metadata.xml
@@ -5,4 +5,11 @@
 		<email>office@gentoo.org</email>
 		<name>Gentoo Office project</name>
 	</maintainer>
+	<use>
+		<flag name="spreadsheet-model">Enable the spreadsheet model implementation</flag>
+		<flag name="tools">Build miscellaneous tools</flag>
+	</use>
+	<upstream>
+		<remote-id type="gitlab">orcus/orcus</remote-id>
+	</upstream>
 </pkgmetadata>