summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorLars Wendler <polynomial-c@gentoo.org>2019-07-09 17:50:12 +0200
committerLars Wendler <polynomial-c@gentoo.org>2019-07-09 17:50:27 +0200
commitab87aa508412aab3131c785babb4b6919db963fa (patch)
tree43bb8689de257e2c59eddeea042b5ee2f149cf17
parentnet-fs/samba: Bump to version 4.10.6 (diff)
downloadgentoo-ab87aa508412aab3131c785babb4b6919db963fa.tar.gz
gentoo-ab87aa508412aab3131c785babb4b6919db963fa.tar.bz2
gentoo-ab87aa508412aab3131c785babb4b6919db963fa.zip
net-fs/samba: Removed old.
Package-Manager: Portage-2.3.68, Repoman-2.3.16 Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>
-rw-r--r--net-fs/samba/Manifest1
-rw-r--r--net-fs/samba/samba-4.10.4.ebuild309
2 files changed, 0 insertions, 310 deletions
diff --git a/net-fs/samba/Manifest b/net-fs/samba/Manifest
index 47d6d81503e..d2cd90f4f36 100644
--- a/net-fs/samba/Manifest
+++ b/net-fs/samba/Manifest
@@ -1,5 +1,4 @@
DIST samba-4.10.2.tar.gz 18280710 BLAKE2B f15b117d1159dfa6cd279c5011629d688fcfba94a2ca8184a827d0787a31f76a38f46b355454b916f2e62c0a88109b86664f6bb16fc0e23d0f61d09908e587cd SHA512 3d146ea12567ebb02a7babcad779b82339ffbfb19f6f2be5cac33eb18af2c9b546dc1cd910072a5c9e152ba9c4a632ed6870c48a8f6ad9d04304b130f240a4bf
-DIST samba-4.10.4.tar.gz 18289224 BLAKE2B e5e416ed9ab51ed8294023619c6a4b8a6d41b0962cab7b9788d8d8b21706bd93a1d6a3833712377839d6112b67ce6fbd0d9be93f64c0bd603800624b130b780a SHA512 10799f866b896903baaea5141af89cf442f3892d9c6f74b7acf217dd95abfe77b09f2bb001273cccf2e433bd2e845fad90651970952b4e18e8cd37bde956cf4e
DIST samba-4.10.5.tar.gz 18290612 BLAKE2B 731ea29b02db5158c5cc564d5663e3f9552d7e1164ed8a41738dba8656692b685cc9a7ba57e8cd32fe9a1cb24eed5373929d2b805bf3da3982c0f4b1246883d0 SHA512 82961791a43511aa42f0d648edd13f0533cb20e1d673903e6a1f6235b0df19dfc0755ab0c8e6d4518ca19c188968a38a6c8e8c80d05a20141c097fb0b3e2b795
DIST samba-4.10.6.tar.gz 18306135 BLAKE2B 236598c26294e1b7b23e48eba7d6429eec01e65a4a73a45fea16ef0e0b7cf1c7b861d824e860bc178d358c298400e829577525b0438e0384fca7bf4409bd69f0 SHA512 6c06a55ac686210965cf52f79190700a3d3a5cba8ea54b32e5bdb4d6b6167f1fa9aef308c3d5fdc7078496aa78b46d5cea3c623438d3a049b11fc58d334f8d0f
DIST samba-4.5.11-disable-python-patches.tar.xz 6292 BLAKE2B c2a32a1059a02bc1c87ce5f604cbc5878c654b8f693c8486b5ba63b37513444915a7b6389fe82b7e31ab2f9577dd8462eddba60b4f4f756b4ed1145ce7bd90ae SHA512 f0e3076e3e1ecaae3f06b3ef30efc81719fb3f63a1041dcbdae4b62ca4cf693732f9eb16f047d046d4930136fed82194e82b455ea888e12cf845b3e6a122d57d
diff --git a/net-fs/samba/samba-4.10.4.ebuild b/net-fs/samba/samba-4.10.4.ebuild
deleted file mode 100644
index 9abce7be82c..00000000000
--- a/net-fs/samba/samba-4.10.4.ebuild
+++ /dev/null
@@ -1,309 +0,0 @@
-# Copyright 1999-2019 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-PYTHON_COMPAT=( python3_{5,6,7} )
-PYTHON_REQ_USE='threads(+),xml(+)'
-
-inherit python-single-r1 waf-utils multilib-minimal linux-info systemd pam
-
-MY_PV="${PV/_rc/rc}"
-MY_P="${PN}-${MY_PV}"
-
-SRC_PATH="stable"
-[[ ${PV} = *_rc* ]] && SRC_PATH="rc"
-
-SRC_URI="mirror://samba/${SRC_PATH}/${MY_P}.tar.gz"
-[[ ${PV} = *_rc* ]] || \
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
-
-DESCRIPTION="Samba Suite Version 4"
-HOMEPAGE="https://www.samba.org/"
-LICENSE="GPL-3"
-
-SLOT="0"
-
-IUSE="acl addc addns ads ceph client cluster cups debug dmapi fam gnutls gpg
-iprint json ldap pam profiling-data python quota selinux syslog system-heimdal
-+system-mitkrb5 systemd test winbind zeroconf"
-
-MULTILIB_WRAPPED_HEADERS=(
- /usr/include/samba-4.0/policy.h
- /usr/include/samba-4.0/dcerpc_server.h
- /usr/include/samba-4.0/ctdb.h
- /usr/include/samba-4.0/ctdb_client.h
- /usr/include/samba-4.0/ctdb_protocol.h
- /usr/include/samba-4.0/ctdb_private.h
- /usr/include/samba-4.0/ctdb_typesafe_cb.h
- /usr/include/samba-4.0/ctdb_version.h
-)
-
-# sys-apps/attr is an automagic dependency (see bug #489748)
-CDEPEND="
- >=app-arch/libarchive-3.1.2[${MULTILIB_USEDEP}]
- dev-lang/perl:=
- dev-libs/libaio[${MULTILIB_USEDEP}]
- dev-libs/libbsd[${MULTILIB_USEDEP}]
- dev-libs/iniparser:0
- dev-libs/popt[${MULTILIB_USEDEP}]
- dev-python/subunit[${PYTHON_USEDEP},${MULTILIB_USEDEP}]
- >=dev-util/cmocka-1.1.1[${MULTILIB_USEDEP}]
- net-libs/libnsl:=[${MULTILIB_USEDEP}]
- sys-apps/attr[${MULTILIB_USEDEP}]
- >=sys-libs/ldb-1.5.4[ldap(+)?,python?,${PYTHON_USEDEP},${MULTILIB_USEDEP}]
- <sys-libs/ldb-1.6.0[ldap(+)?,python?,${PYTHON_USEDEP},${MULTILIB_USEDEP}]
- sys-libs/libcap
- sys-libs/ncurses:0=[${MULTILIB_USEDEP}]
- sys-libs/readline:0=
- >=sys-libs/talloc-2.1.16[python?,${PYTHON_USEDEP},${MULTILIB_USEDEP}]
- >=sys-libs/tdb-1.3.18[python?,${PYTHON_USEDEP},${MULTILIB_USEDEP}]
- >=sys-libs/tevent-0.9.39[python?,${PYTHON_USEDEP},${MULTILIB_USEDEP}]
- sys-libs/zlib[${MULTILIB_USEDEP}]
- virtual/libiconv
- pam? ( virtual/pam )
- acl? ( virtual/acl )
- addns? (
- net-dns/bind-tools[gssapi]
- dev-python/dnspython:=[${PYTHON_USEDEP}]
- )
- ceph? ( sys-cluster/ceph )
- cluster? (
- net-libs/rpcsvc-proto
- !dev-db/ctdb
- )
- cups? ( net-print/cups )
- debug? ( dev-util/lttng-ust )
- dmapi? ( sys-apps/dmapi )
- fam? ( virtual/fam )
- gnutls? (
- dev-libs/libgcrypt:0
- >=net-libs/gnutls-1.4.0
- )
- gpg? ( app-crypt/gpgme )
- json? ( dev-libs/jansson )
- ldap? ( net-nds/openldap[${MULTILIB_USEDEP}] )
- system-heimdal? ( >=app-crypt/heimdal-1.5[-ssl,${MULTILIB_USEDEP}] )
- system-mitkrb5? ( >=app-crypt/mit-krb5-1.15.1[${MULTILIB_USEDEP}] )
- systemd? ( sys-apps/systemd:0= )
-"
-DEPEND="${CDEPEND}
- ${PYTHON_DEPS}
- app-text/docbook-xsl-stylesheets
- dev-libs/libxslt
- net-libs/libtirpc[${MULTILIB_USEDEP}]
- virtual/pkgconfig
- || (
- net-libs/rpcsvc-proto
- <sys-libs/glibc-2.26[rpc(+)]
- )
- test? (
- !system-mitkrb5? (
- >=sys-libs/nss_wrapper-1.1.3
- >=net-dns/resolv_wrapper-1.1.4
- >=net-libs/socket_wrapper-1.1.9
- >=sys-libs/uid_wrapper-1.2.1
- )
- )"
-RDEPEND="${CDEPEND}
- python? ( ${PYTHON_DEPS} )
- client? ( net-fs/cifs-utils[ads?] )
- selinux? ( sec-policy/selinux-samba )
- !dev-perl/Parse-Yapp
-"
-
-REQUIRED_USE="
- addc? ( python gnutls json winbind )
- addns? ( python )
- ads? ( acl gnutls ldap winbind )
- cluster? ( ads )
- gpg? ( addc )
- test? ( python )
- ?? ( system-heimdal system-mitkrb5 )
- ${PYTHON_REQUIRED_USE}
-"
-
-# the test suite is messed, it uses system-installed samba
-# bits instead of what was built, tests things disabled via use
-# flags, and generally just fails to work in a way ebuilds could
-# rely on in its current state
-RESTRICT="test"
-
-S="${WORKDIR}/${MY_P}"
-
-PATCHES=(
- "${FILESDIR}/${PN}-4.4.0-pam.patch"
- "${FILESDIR}/${PN}-4.5.1-compile_et_fix.patch"
- "${FILESDIR}/${PN}-4.9.2-timespec.patch"
- "${FILESDIR}/${PN}-4.10.0-disable_gnutls_build_fix.patch"
-)
-
-#CONFDIR="${FILESDIR}/$(get_version_component_range 1-2)"
-CONFDIR="${FILESDIR}/4.4"
-
-WAF_BINARY="${S}/buildtools/bin/waf"
-
-SHAREDMODS=""
-
-pkg_setup() {
- python-single-r1_pkg_setup
- if use cluster ; then
- SHAREDMODS="idmap_rid,idmap_tdb2,idmap_ad"
- elif use ads ; then
- SHAREDMODS="idmap_ad"
- fi
-}
-
-src_prepare() {
- default
-
- # un-bundle dnspython
- sed -i -e '/"dns.resolver":/d' "${S}"/third_party/wscript || die
-
- # unbundle iso8601 unless tests are enabled
- if ! use test ; then
- sed -i -e '/"iso8601":/d' "${S}"/third_party/wscript || die
- fi
-
- # ugly hackaround for bug #592502
- cp /usr/include/tevent_internal.h "${S}"/lib/tevent/ || die
-
- sed -e 's:<gpgme\.h>:<gpgme/gpgme.h>:' \
- -i source4/dsdb/samdb/ldb_modules/password_hash.c \
- || die
-
- # Friggin' WAF shit
- multilib_copy_sources
-}
-
-multilib_src_configure() {
- # when specifying libs for samba build you must append NONE to the end to
- # stop it automatically including things
- local bundled_libs="NONE"
- if ! use system-heimdal && ! use system-mitkrb5 ; then
- bundled_libs="heimbase,heimntlm,hdb,kdc,krb5,wind,gssapi,hcrypto,hx509,roken,asn1,com_err,NONE"
- fi
-
- local myconf=(
- --enable-fhs
- --sysconfdir="${EPREFIX}/etc"
- --localstatedir="${EPREFIX}/var"
- --with-modulesdir="${EPREFIX}/usr/$(get_libdir)/samba"
- --with-piddir="${EPREFIX}/run/${PN}"
- --bundled-libraries="${bundled_libs}"
- --builtin-libraries=NONE
- --disable-rpath
- --disable-rpath-install
- --nopyc
- --nopyo
- $(multilib_native_use_with acl acl-support)
- $(multilib_native_usex addc '' '--without-ad-dc')
- $(multilib_native_use_with addns dnsupdate)
- $(multilib_native_use_with ads)
- $(multilib_native_use_enable ceph cephfs)
- $(multilib_native_use_with cluster cluster-support)
- $(multilib_native_use_enable cups)
- $(multilib_native_use_with dmapi)
- $(multilib_native_use_with fam)
- $(multilib_native_use_with gpg gpgme)
- $(multilib_native_use_with json)
- $(multilib_native_use_enable iprint)
- $(multilib_native_use_with pam)
- $(multilib_native_usex pam "--with-pammodulesdir=${EPREFIX}/$(get_libdir)/security" '')
- $(multilib_native_use_with quota quotas)
- $(multilib_native_use_with syslog)
- $(multilib_native_use_with systemd)
- $(multilib_native_use_with winbind)
- $(multilib_native_usex python '' '--disable-python')
- $(multilib_native_use_enable zeroconf avahi)
- $(multilib_native_usex test '--enable-selftest' '')
- $(usex system-mitkrb5 "--with-system-mitkrb5 $(multilib_native_usex addc --with-experimental-mit-ad-dc '')" '')
- $(use_enable gnutls)
- $(use_with debug lttng)
- $(use_with ldap)
- $(use_with profiling-data)
- )
-
- multilib_is_native_abi && myconf+=( --with-shared-modules=${SHAREDMODS} )
-
- CPPFLAGS="-I${SYSROOT}${EPREFIX}/usr/include/et ${CPPFLAGS}" \
- waf-utils_src_configure ${myconf[@]}
-}
-
-multilib_src_compile() {
- waf-utils_src_compile
-}
-
-multilib_src_install() {
- waf-utils_src_install
-
- # Make all .so files executable
- find "${ED}" -type f -name "*.so" -exec chmod +x {} + || die
-
- if multilib_is_native_abi ; then
- # install ldap schema for server (bug #491002)
- if use ldap ; then
- insinto /etc/openldap/schema
- doins examples/LDAP/samba.schema
- fi
-
- # create symlink for cups (bug #552310)
- if use cups ; then
- dosym ../../../bin/smbspool /usr/libexec/cups/backend/smb
- fi
-
- # install example config file
- insinto /etc/samba
- doins examples/smb.conf.default
-
- # Fix paths in example file (#603964)
- sed \
- -e '/log file =/s@/usr/local/samba/var/@/var/log/samba/@' \
- -e '/include =/s@/usr/local/samba/lib/@/etc/samba/@' \
- -e '/path =/s@/usr/local/samba/lib/@/var/lib/samba/@' \
- -e '/path =/s@/usr/local/samba/@/var/lib/samba/@' \
- -e '/path =/s@/usr/spool/samba@/var/spool/samba@' \
- -i "${ED%/}"/etc/samba/smb.conf.default || die
-
- # Install init script and conf.d file
- newinitd "${CONFDIR}/samba4.initd-r1" samba
- newconfd "${CONFDIR}/samba4.confd" samba
-
- systemd_dotmpfilesd "${FILESDIR}"/samba.conf
- systemd_dounit "${FILESDIR}"/nmbd.service
- systemd_dounit "${FILESDIR}"/smbd.{service,socket}
- systemd_newunit "${FILESDIR}"/smbd_at.service 'smbd@.service'
- systemd_dounit "${FILESDIR}"/winbindd.service
- systemd_dounit "${FILESDIR}"/samba.service
- fi
-
- if use pam && use winbind ; then
- newpamd "${CONFDIR}/system-auth-winbind.pam" system-auth-winbind
- # bugs #376853 and #590374
- insinto /etc/security
- doins examples/pam_winbind/pam_winbind.conf || die
- fi
-
- keepdir /var/cache/samba
- keepdir /var/lib/ctdb
- keepdir /var/lib/samba/{bind-dns,private}
- keepdir /var/lock/samba
- keepdir /var/log/samba
- keepdir /var/run/{ctdb,samba}
-}
-
-multilib_src_test() {
- if multilib_is_native_abi ; then
- "${WAF_BINARY}" test || die "test failed"
- fi
-}
-
-pkg_postinst() {
- ewarn "Be aware the this release contains the best of all of Samba's"
- ewarn "technology parts, both a file server (that you can reasonably expect"
- ewarn "to upgrade existing Samba 3.x releases to) and the AD domain"
- ewarn "controller work previously known as 'samba4'."
-
- elog "For further information and migration steps make sure to read "
- elog "https://samba.org/samba/history/${P}.html "
- elog "https://wiki.samba.org/index.php/Samba4/HOWTO "
-}