summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorLars Wendler <polynomial-c@gentoo.org>2019-08-13 21:13:23 +0200
committerLars Wendler <polynomial-c@gentoo.org>2019-08-13 21:13:23 +0200
commitab8d2f6bbf9b807bff5e5acf662a70b0a80660b8 (patch)
treea7eb5bbe77fa607a80ce225907958c7064feb773
parentmedia-sound/murmur: Re-added acct-{group,user}/murmur to RDEPEND (diff)
downloadgentoo-ab8d2f6bbf9b807bff5e5acf662a70b0a80660b8.tar.gz
gentoo-ab8d2f6bbf9b807bff5e5acf662a70b0a80660b8.tar.bz2
gentoo-ab8d2f6bbf9b807bff5e5acf662a70b0a80660b8.zip
media-libs/libraw: Bump to version 0.19.4
Package-Manager: Portage-2.3.71, Repoman-2.3.17 Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>
-rw-r--r--media-libs/libraw/Manifest1
-rw-r--r--media-libs/libraw/libraw-0.19.4.ebuild61
2 files changed, 62 insertions, 0 deletions
diff --git a/media-libs/libraw/Manifest b/media-libs/libraw/Manifest
index 9d9f377af44..22eea45c6c4 100644
--- a/media-libs/libraw/Manifest
+++ b/media-libs/libraw/Manifest
@@ -1 +1,2 @@
DIST LibRaw-0.19.3.tar.gz 1302745 BLAKE2B 3db3a07c5535a325c69d65ccc75e6a8c7d04e7b1c1d87506fd1c56a0d8f4a7c581467f6350922a4c62d4bc49372f31c86ae2a26a087c4ec11c3ab69763403a0b SHA512 e025695fb7f0016aeec76c0843a94387633457eee838cc48e65d1e84e703c8530b3fdd1e31d85dc322d3f2f6092b7c313fa6d1c3009fe1257c3d9411128b6fe2
+DIST LibRaw-0.19.4.tar.gz 1303047 BLAKE2B daa65c86ca81bee80ced5fcc3a048ef54cc5256b4b80bdda006a2b3d64c8c10436b906a238dd22c8623465288df5a86d65a4d6e2668ba5fc3ef3ad23c7e205d2 SHA512 e9f0b18b8be52119ff504d2645a011eca391a62bf651064dcbec4b6e16b3b09fda49e632453b051d3aae2ac3a8be021e5b71d7202913759ad1d61641d3318c4c
diff --git a/media-libs/libraw/libraw-0.19.4.ebuild b/media-libs/libraw/libraw-0.19.4.ebuild
new file mode 100644
index 00000000000..053b22516ab
--- /dev/null
+++ b/media-libs/libraw/libraw-0.19.4.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools multilib-minimal toolchain-funcs
+
+MY_PN=LibRaw
+MY_PV="${PV/_b/-B}"
+MY_P="${MY_PN}-${MY_PV}"
+
+DESCRIPTION="LibRaw is a library for reading RAW files obtained from digital photo cameras"
+HOMEPAGE="https://www.libraw.org/ https://github.com/LibRaw/LibRaw"
+SRC_URI="https://www.libraw.org/data/${MY_P}.tar.gz"
+
+LICENSE="LGPL-2.1 CDDL"
+SLOT="0/19" # subslot = libraw soname version
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="examples jpeg jpeg2k +lcms openmp"
+
+RDEPEND="jpeg? ( >=virtual/jpeg-0-r2:0[${MULTILIB_USEDEP}] )
+ jpeg2k? ( >=media-libs/jasper-1.900.1-r6:=[${MULTILIB_USEDEP}] )
+ lcms? ( >=media-libs/lcms-2.5:2[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}
+ virtual/pkgconfig"
+
+S="${WORKDIR}/${MY_P}"
+
+DOCS=( Changelog.txt README.md )
+
+pkg_pretend() {
+ [[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+ [[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_prepare() {
+ default
+ eautoreconf
+}
+
+multilib_src_configure() {
+ local myeconfargs=(
+ --disable-static
+ $(use_enable examples)
+ $(use_enable jpeg)
+ $(use_enable jpeg2k jasper)
+ $(use_enable lcms)
+ $(use_enable openmp)
+ )
+ ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_install_all() {
+ einstalldocs
+
+ # package installs .pc files
+ find "${D}" -name '*.la' -delete || die
+}