summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorMatthew Thode <prometheanfire@gentoo.org>2018-10-09 22:02:50 -0500
committerMatthew Thode <prometheanfire@gentoo.org>2018-10-09 22:03:09 -0500
commitaf0dc7853a6947509f1f2ae999ff4aa2cfc61c02 (patch)
tree1a3c05f2f8e4460c34057ee0e808ec0ab0c847b3
parentapp-backup/snapper: x86 stable (bug #660680) (diff)
downloadgentoo-af0dc7853a6947509f1f2ae999ff4aa2cfc61c02.tar.gz
gentoo-af0dc7853a6947509f1f2ae999ff4aa2cfc61c02.tar.bz2
gentoo-af0dc7853a6947509f1f2ae999ff4aa2cfc61c02.zip
sys-cluster/cinder: 12.0.4 bump
Signed-off-by: Matthew Thode <prometheanfire@gentoo.org> Package-Manager: Portage-2.3.49, Repoman-2.3.11
-rw-r--r--sys-cluster/cinder/Manifest1
-rw-r--r--sys-cluster/cinder/cinder-12.0.4.ebuild217
2 files changed, 218 insertions, 0 deletions
diff --git a/sys-cluster/cinder/Manifest b/sys-cluster/cinder/Manifest
index 3f87a489951..0ae4590a3f1 100644
--- a/sys-cluster/cinder/Manifest
+++ b/sys-cluster/cinder/Manifest
@@ -1,5 +1,6 @@
DIST cinder-11.1.1.tar.gz 5808526 BLAKE2B 1b773e45673c35faff1a327d73608949e088f3635adb6dd6c7e779e708dd8f2270b85086378d48042b86e60ad7ca94754d56c1d0193f1d715112a03cf3163c77 SHA512 10ecf0068c57077a24bb0445a0901e07e7ad211cd7fac67ed016b770b477e9ba0e9954de70f165aae69e079f6b2e9416d8292ec701db4c97b987c7dac8f69a43
DIST cinder-12.0.3.tar.gz 5333501 BLAKE2B a2ee71f1e35813162e5f37abdf7a3b1fd2bc7fe283422e07ad4506d7d0d6d322d7488876b1d4a8966ad357d8439f4f8e8322926c66810ed76210caa077d94910 SHA512 51b151d0fff6f2983ab0d0f90fb2e29bf04e54f51925d2b8acdda715f6a1eb83cd44f6e2a42243298ce4e8e8d23cdeedbf902d778e259960d56f8bccfd8420a2
+DIST cinder-12.0.4.tar.gz 5349921 BLAKE2B 168beb53879656956a97a4e787aba200b119e80e3b787fa94534c7ca8a68fb641df47069e19759ef022103a3f306402711ec315bc61d6387b427c6f5672919fc SHA512 0a139c25458020a869ab9395f42cd31b83cbfb65640a41ef0039aef48a92fd641a0084c5fd8fbdc35b6c8b6e9250e1d0a845816b92a882358acf4e2793be536c
DIST cinder-13.0.0.tar.gz 5515802 BLAKE2B 9893e3cef0f14684ac6e1dff2a33cc96dd8f47a403e1d8a9a993be3be38f8c76f239535ef5faed72c991c88b51de106f54a5741688d457da654cfaa4a2c1843e SHA512 842e6cd858910cabc99bed874f5bd6b7234da0f676e91b83a767ba357b0eb7f4409dd383a9c64896dc6346a87399296399954af96f13b21cd655be5c89b3e978
DIST cinder.conf.sample-13.0.0 185527 BLAKE2B c53c017c5cacf2fb604840e14adf3b1db36bf8dd2c79d29f1c6b35da843640f97efcfd97d6f68a40a2f928ce864a3e221d7138d7cac977c0d544817e2826ebb2 SHA512 1dc850bebd66d90e2950795337a78ea8aea69ead0aeb3e5b7f97c7b12f33a3afc483f3bde2942a34539fbc048fa5b589b3c7d2df53314180f64094569bb81b15
DIST cinder.conf.sample-2018.2.9999 185527 BLAKE2B c53c017c5cacf2fb604840e14adf3b1db36bf8dd2c79d29f1c6b35da843640f97efcfd97d6f68a40a2f928ce864a3e221d7138d7cac977c0d544817e2826ebb2 SHA512 1dc850bebd66d90e2950795337a78ea8aea69ead0aeb3e5b7f97c7b12f33a3afc483f3bde2942a34539fbc048fa5b589b3c7d2df53314180f64094569bb81b15
diff --git a/sys-cluster/cinder/cinder-12.0.4.ebuild b/sys-cluster/cinder/cinder-12.0.4.ebuild
new file mode 100644
index 00000000000..03e6d85f8fe
--- /dev/null
+++ b/sys-cluster/cinder/cinder-12.0.4.ebuild
@@ -0,0 +1,217 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+
+inherit distutils-r1 eutils linux-info user
+
+DESCRIPTION="Cinder is the OpenStack Block storage service, a spin out of nova-volumes"
+HOMEPAGE="https://launchpad.net/cinder"
+
+if [[ ${PV} == *9999 ]];then
+ inherit git-r3
+ SRC_URI="https://dev.gentoo.org/~prometheanfire/dist/openstack/cinder/queens/cinder.conf.sample -> queens-cinder.conf.sample"
+ EGIT_REPO_URI="https://github.com/openstack/cinder.git"
+ EGIT_BRANCH="stable/queens"
+else
+ SRC_URI="https://dev.gentoo.org/~prometheanfire/dist/openstack/cinder/queens/cinder.conf.sample -> queens-cinder.conf.sample
+ https://tarballs.openstack.org/${PN}/${P}.tar.gz"
+ KEYWORDS="~amd64 ~arm64 ~x86"
+fi
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="+api +scheduler +volume infiniband iscsi lvm mysql +memcached postgres rdma sqlite +tcp test +tgt"
+REQUIRED_USE="|| ( mysql postgres sqlite ) iscsi? ( tgt ) infiniband? ( rdma )"
+
+CDEPEND=">=dev-python/pbr-2.0.0[${PYTHON_USEDEP}]
+ !~dev-python/pbr-2.1.0"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+ ${CDEPEND}
+ app-admin/sudo"
+
+RDEPEND="
+ ${CDEPEND}
+ >=dev-python/Babel-2.3.4[${PYTHON_USEDEP}]
+ !~dev-python/Babel-2.4.0[${PYTHON_USEDEP}]
+ >=dev-python/decorator-3.4.0[${PYTHON_USEDEP}]
+ >=dev-python/defusedxml-0.5.0[${PYTHON_USEDEP}]
+ dev-python/enum34[$(python_gen_usedep 'python2_7')]
+ >=dev-python/eventlet-0.18.4[${PYTHON_USEDEP}]
+ !~dev-python/eventlet-0.20.1[${PYTHON_USEDEP}]
+ <dev-python/eventlet-0.21.0[${PYTHON_USEDEP}]
+ >=dev-python/greenlet-0.4.1[${PYTHON_USEDEP}]
+ >=dev-python/httplib2-0.9.1[${PYTHON_USEDEP}]
+ >=dev-python/iso8601-0.1.11[${PYTHON_USEDEP}]
+ >=dev-python/jsonschema-2.6.0[${PYTHON_USEDEP}]
+ <dev-python/jsonschema-3.0.0[${PYTHON_USEDEP}]
+ virtual/python-ipaddress[${PYTHON_USEDEP}]
+ >=dev-python/keystoneauth-3.3.0[${PYTHON_USEDEP}]
+ >=dev-python/keystonemiddleware-4.17.0[${PYTHON_USEDEP}]
+ >=dev-python/lxml-3.4.1[${PYTHON_USEDEP}]
+ !~dev-python/lxml-3.7.0[${PYTHON_USEDEP}]
+ >=dev-python/oauth2client-1.5.0[${PYTHON_USEDEP}]
+ >=dev-python/oslo-config-5.1.0[${PYTHON_USEDEP}]
+ >=dev-python/oslo-concurrency-3.25.0[${PYTHON_USEDEP}]
+ >=dev-python/oslo-context-2.19.2[${PYTHON_USEDEP}]
+ >=dev-python/oslo-db-4.27.0[${PYTHON_USEDEP}]
+ >=dev-python/oslo-log-3.36.0[${PYTHON_USEDEP}]
+ >=dev-python/oslo-messaging-5.29.0[${PYTHON_USEDEP}]
+ >=dev-python/oslo-middleware-3.31.0[${PYTHON_USEDEP}]
+ >=dev-python/oslo-policy-1.30.0[${PYTHON_USEDEP}]
+ >=dev-python/oslo-privsep-1.23.0[${PYTHON_USEDEP}]
+ >=dev-python/oslo-reports-1.18.0[${PYTHON_USEDEP}]
+ >=dev-python/oslo-rootwrap-5.8.0[${PYTHON_USEDEP}]
+ >=dev-python/oslo-serialization-2.18.0[${PYTHON_USEDEP}]
+ !~dev-python/oslo-serialization-2.19.1[${PYTHON_USEDEP}]
+ >=dev-python/oslo-service-1.24.0[${PYTHON_USEDEP}]
+ !~dev-python/oslo-service-1.28.1[${PYTHON_USEDEP}]
+ >=dev-python/oslo-utils-3.33.0[${PYTHON_USEDEP}]
+ >=dev-python/oslo-versionedobjects-1.31.2[${PYTHON_USEDEP}]
+ >=dev-python/osprofiler-1.4.0[${PYTHON_USEDEP}]
+ >=dev-python/paramiko-2.0.0[${PYTHON_USEDEP}]
+ >=dev-python/paste-2.0.2[${PYTHON_USEDEP}]
+ >=dev-python/pastedeploy-1.5.0[${PYTHON_USEDEP}]
+ >=dev-python/prettytable-0.7.1[${PYTHON_USEDEP}]
+ <dev-python/prettytable-0.8[${PYTHON_USEDEP}]
+ >=dev-python/psutil-3.2.2[${PYTHON_USEDEP}]
+ >=dev-python/pyparsing-2.1.0[${PYTHON_USEDEP}]
+ >=dev-python/python-barbicanclient-4.0.0[${PYTHON_USEDEP}]
+ !~dev-python/python-barbicanclient-4.5.0[${PYTHON_USEDEP}]
+ !~dev-python/python-barbicanclient-4.5.1[${PYTHON_USEDEP}]
+ >=dev-python/python-glanceclient-2.8.0[${PYTHON_USEDEP}]
+ >=dev-python/python-keystoneclient-3.8.0[${PYTHON_USEDEP}]
+ >=dev-python/python-novaclient-9.1.0[${PYTHON_USEDEP}]
+ >=dev-python/python-swiftclient-3.2.0[${PYTHON_USEDEP}]
+ >=dev-python/pytz-2013.6[${PYTHON_USEDEP}]
+ >=dev-python/requests-2.14.2[${PYTHON_USEDEP}]
+ >=dev-python/retrying-1.2.3[${PYTHON_USEDEP}]
+ !~dev-python/retrying-1.3.0[${PYTHON_USEDEP}]
+ >=dev-python/routes-2.3.1[${PYTHON_USEDEP}]
+ >=dev-python/taskflow-2.16.0[${PYTHON_USEDEP}]
+ >=dev-python/rtslib-fb-2.1.43[${PYTHON_USEDEP}]
+ !~dev-python/rtslib-fb-2.1.60[${PYTHON_USEDEP}]
+ !~dev-python/rtslib-fb-2.1.61[${PYTHON_USEDEP}]
+ !~dev-python/rtslib-fb-2.1.64[${PYTHON_USEDEP}]
+ >=dev-python/simplejson-3.5.1[${PYTHON_USEDEP}]
+ >=dev-python/six-1.10.0[${PYTHON_USEDEP}]
+ sqlite? (
+ >=dev-python/sqlalchemy-1.0.10[sqlite,${PYTHON_USEDEP}]
+ !~dev-python/sqlalchemy-1.1.5[sqlite,${PYTHON_USEDEP}]
+ !~dev-python/sqlalchemy-1.1.6[sqlite,${PYTHON_USEDEP}]
+ !~dev-python/sqlalchemy-1.1.7[sqlite,${PYTHON_USEDEP}]
+ !~dev-python/sqlalchemy-1.1.8[sqlite,${PYTHON_USEDEP}]
+ )
+ mysql? (
+ >=dev-python/pymysql-0.7.6[${PYTHON_USEDEP}]
+ !~dev-python/pymysql-0.7.7[${PYTHON_USEDEP}]
+ >=dev-python/sqlalchemy-1.0.10[${PYTHON_USEDEP}]
+ !~dev-python/sqlalchemy-1.1.5[${PYTHON_USEDEP}]
+ !~dev-python/sqlalchemy-1.1.6[${PYTHON_USEDEP}]
+ !~dev-python/sqlalchemy-1.1.7[${PYTHON_USEDEP}]
+ !~dev-python/sqlalchemy-1.1.8[${PYTHON_USEDEP}]
+ )
+ postgres? (
+ >=dev-python/psycopg-2.5.0[${PYTHON_USEDEP}]
+ >=dev-python/sqlalchemy-1.0.10[${PYTHON_USEDEP}]
+ !~dev-python/sqlalchemy-1.1.5[${PYTHON_USEDEP}]
+ !~dev-python/sqlalchemy-1.1.6[${PYTHON_USEDEP}]
+ !~dev-python/sqlalchemy-1.1.7[${PYTHON_USEDEP}]
+ !~dev-python/sqlalchemy-1.1.8[${PYTHON_USEDEP}]
+ )
+ >=dev-python/sqlalchemy-migrate-0.11.0[${PYTHON_USEDEP}]
+ >=dev-python/stevedore-1.20.0[${PYTHON_USEDEP}]
+ ~dev-python/suds-0.6[${PYTHON_USEDEP}]
+ >=dev-python/webob-1.7.1[${PYTHON_USEDEP}]
+ >=dev-python/oslo-i18n-3.15.3[${PYTHON_USEDEP}]
+ >=dev-python/oslo-vmware-2.17.0[${PYTHON_USEDEP}]
+ >=dev-python/os-brick-2.2.0[${PYTHON_USEDEP}]
+ >=dev-python/os-win-3.0.0[${PYTHON_USEDEP}]
+ >=dev-python/tooz-1.58.0[${PYTHON_USEDEP}]
+ >=dev-python/google-api-python-client-1.4.2[${PYTHON_USEDEP}]
+ >=dev-python/castellan-0.16.0[${PYTHON_USEDEP}]
+ >=dev-python/cryptography-1.9[${PYTHON_USEDEP}]
+ !~dev-python/cryptography-2.0[${PYTHON_USEDEP}]
+ iscsi? (
+ tgt? ( sys-block/tgt )
+ sys-block/open-iscsi
+ )
+ lvm? ( sys-fs/lvm2 )
+ memcached? ( net-misc/memcached )
+ app-emulation/qemu
+ sys-fs/sysfsutils"
+# qemu is needed for image conversion
+
+#PATCHES=(
+#)
+
+pkg_pretend() {
+ linux-info_pkg_setup
+ CONFIG_CHECK_MODULES=""
+ if use tcp; then
+ CONFIG_CHECK_MODULES+="SCSI_ISCSI_ATTRS ISCSI_TCP "
+ fi
+ if use rdma; then
+ CONFIG_CHECK_MODULES+="INFINIBAND_ISER "
+ fi
+ if use infiniband; then
+ CONFIG_CHECK_MODULES+="INFINIBAND_IPOIB INFINIBAND_USER_MAD INFINIBAND_USER_ACCESS"
+ fi
+ if linux_config_exists; then
+ for module in ${CONFIG_CHECK_MODULES}; do
+ linux_chkconfig_present ${module} || ewarn "${module} needs to be enabled"
+ done
+ fi
+}
+
+pkg_setup() {
+ enewgroup cinder
+ enewuser cinder -1 -1 /var/lib/cinder cinder
+}
+
+python_prepare_all() {
+ sed -i '/^hacking/d' test-requirements.txt || die
+ distutils-r1_python_prepare_all
+}
+
+python_test() {
+ # Let's track progress of this # https://bugs.launchpad.net/swift/+bug/1249727
+ nosetests -I test_wsgi.py cinder/tests/ || die "tests failed under python2.7"
+}
+
+python_install_all() {
+ distutils-r1_python_install_all
+ keepdir /etc/cinder
+ dodir /etc/cinder/rootwrap.d
+
+ for svc in api scheduler volume; do
+ newinitd "${FILESDIR}/cinder.initd" cinder-${svc}
+ done
+
+ insinto /etc/cinder
+ insopts -m0640 -o cinder -g cinder
+ doins "etc/cinder/api-httpd.conf"
+ doins "etc/cinder/logging_sample.conf"
+ doins "etc/cinder/rootwrap.conf"
+ doins "etc/cinder/api-paste.ini"
+ doins "etc/cinder/resource_filters.json"
+ newins "${DISTDIR}/queens-cinder.conf.sample" "cinder.conf.sample"
+ insinto /etc/cinder/rootwrap.d
+ doins "etc/cinder/rootwrap.d/volume.filters"
+
+ dodir /var/log/cinder
+ fowners cinder:cinder /var/log/cinder
+
+ #add sudoers definitions for user nova
+ insinto /etc/sudoers.d/
+ insopts -m 0440 -o root -g root
+ newins "${FILESDIR}/cinder.sudoersd" cinder
+}
+
+pkg_postinst() {
+ if use iscsi ; then
+ elog "Cinder needs tgtd to be installed and running to work with iscsi"
+ elog "it also needs 'include /var/lib/cinder/volumes/*' in /etc/tgt/targets.conf"
+ fi
+}