summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorJohannes Huber <johu@gentoo.org>2018-04-24 21:31:05 +0200
committerJohannes Huber <johu@gentoo.org>2018-04-24 21:43:48 +0200
commitb0a071f5a9927a03d91b853610dbbe3c7e767d73 (patch)
tree191965e1a4adbef3e217a8db78565b5d6f07e9e7
parentmail-mta/netqmail: arm stable wrt bug #504392 (diff)
downloadgentoo-b0a071f5a9927a03d91b853610dbbe3c7e767d73.tar.gz
gentoo-b0a071f5a9927a03d91b853610dbbe3c7e767d73.tar.bz2
gentoo-b0a071f5a9927a03d91b853610dbbe3c7e767d73.zip
net-irc/quassel: Version bump 0.12.5
Bug: https://bugs.gentoo.org/653834 Package-Manager: Portage-2.3.31, Repoman-2.3.9
-rw-r--r--net-irc/quassel/Manifest1
-rw-r--r--net-irc/quassel/quassel-0.12.5.ebuild182
2 files changed, 183 insertions, 0 deletions
diff --git a/net-irc/quassel/Manifest b/net-irc/quassel/Manifest
index 06198ad4ee5..5e3ff2980df 100644
--- a/net-irc/quassel/Manifest
+++ b/net-irc/quassel/Manifest
@@ -1 +1,2 @@
DIST quassel-0.12.4.tar.bz2 3742639 BLAKE2B 855caaf3eb5373008dc3c6f673b68aa1bbb601541ba5eb6c9402f421ec6b1dc933c58785181ca8b3f2fd899ba91a873458ede06f0fda2a3e970980f395742be2 SHA512 66bc12a9634534e6492787172a199c774ef1642d1ddb268c24ed96608698628bca7b278021a006a4db76783b19b1e1dead9d019bb8a6cbe1e12b8857792e7b92
+DIST quassel-0.12.5.tar.bz2 3747392 BLAKE2B 624cd18c2a5e1c480f701072bfeeeb18589cdbd2f2b7ab0d524f32e384ac4feb7328b23b60c3005340d53e4bf3a209f75a5d673a8d5d3f659825f0ef21bd3f9f SHA512 3a0263d7bec9ef4b0d8ef6ea53784f95e0efbadc0f03b49005908411b0b53543ebc66189fb4100c117d87264b648f2a1b01be48c371f926b9f326b1ffc870685
diff --git a/net-irc/quassel/quassel-0.12.5.ebuild b/net-irc/quassel/quassel-0.12.5.ebuild
new file mode 100644
index 00000000000..83888e7a7d3
--- /dev/null
+++ b/net-irc/quassel/quassel-0.12.5.ebuild
@@ -0,0 +1,182 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils gnome2-utils pax-utils systemd user versionator
+
+if [[ ${PV} != *9999* ]]; then
+ SRC_URI="http://quassel-irc.org/pub/${P}.tar.bz2"
+ KEYWORDS="~amd64 ~arm ~ppc ~x86 ~amd64-linux ~sparc-solaris"
+else
+ EGIT_REPO_URI=( "https://github.com/${PN}/${PN}" "git://git.${PN}-irc.org/${PN}" )
+ inherit git-r3
+fi
+
+DESCRIPTION="Qt/KDE IRC client supporting a remote daemon for 24/7 connectivity"
+HOMEPAGE="http://quassel-irc.org/"
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="crypt dbus debug kde monolithic phonon postgres +server
+snorenotify +ssl syslog webkit X"
+
+SERVER_RDEPEND="
+ dev-qt/qtscript:5
+ crypt? ( app-crypt/qca:2[qt5(+),ssl] )
+ postgres? ( dev-qt/qtsql:5[postgres] )
+ !postgres? ( dev-qt/qtsql:5[sqlite] dev-db/sqlite:3[threadsafe(+),-secure-delete] )
+ syslog? ( virtual/logger )
+"
+
+GUI_RDEPEND="
+ dev-qt/qtgui:5
+ dev-qt/qtwidgets:5
+ dbus? (
+ >=dev-libs/libdbusmenu-qt-0.9.3_pre20140619[qt5(+)]
+ dev-qt/qtdbus:5
+ )
+ kde? (
+ kde-frameworks/kconfigwidgets:5
+ kde-frameworks/kcoreaddons:5
+ kde-frameworks/knotifications:5
+ kde-frameworks/knotifyconfig:5
+ kde-frameworks/ktextwidgets:5
+ kde-frameworks/kwidgetsaddons:5
+ kde-frameworks/kxmlgui:5
+ kde-frameworks/sonnet:5
+ )
+ phonon? ( media-libs/phonon[qt5(+)] )
+ snorenotify? ( >=x11-libs/snorenotify-0.7.0 )
+ webkit? ( dev-qt/qtwebkit:5 )
+"
+
+RDEPEND="
+ dev-qt/qtcore:5
+ dev-qt/qtnetwork:5[ssl?]
+ sys-libs/zlib
+ monolithic? (
+ ${SERVER_RDEPEND}
+ ${GUI_RDEPEND}
+ )
+ !monolithic? (
+ server? ( ${SERVER_RDEPEND} )
+ X? ( ${GUI_RDEPEND} )
+ )
+"
+DEPEND="${RDEPEND}
+ dev-qt/linguist-tools:5
+ kde-frameworks/extra-cmake-modules
+"
+
+DOCS=( AUTHORS ChangeLog README.md )
+
+REQUIRED_USE="
+ || ( X server monolithic )
+ crypt? ( || ( server monolithic ) )
+ dbus? ( || ( X monolithic ) )
+ kde? ( || ( X monolithic ) dbus phonon )
+ phonon? ( || ( X monolithic ) )
+ postgres? ( || ( server monolithic ) )
+ snorenotify? ( || ( X monolithic ) )
+ syslog? ( || ( server monolithic ) )
+ webkit? ( || ( X monolithic ) )
+"
+
+pkg_setup() {
+ if use server; then
+ QUASSEL_DIR=/var/lib/${PN}
+ QUASSEL_USER=${PN}
+ # create quassel:quassel user
+ enewgroup "${QUASSEL_USER}"
+ enewuser "${QUASSEL_USER}" -1 -1 "${QUASSEL_DIR}" "${QUASSEL_USER}"
+ fi
+}
+
+src_configure() {
+ local mycmakeargs=(
+ -DUSE_QT5=ON
+ -DEMBED_DATA=OFF
+ -DCMAKE_SKIP_RPATH=ON
+ $(cmake-utils_use_find_package crypt QCA2-QT5)
+ $(cmake-utils_use_find_package dbus dbusmenu-qt5)
+ $(cmake-utils_use_find_package dbus Qt5DBus)
+ -DWITH_KDE=$(usex kde)
+ -DWITH_OXYGEN=$(usex !kde)
+ -DWANT_MONO=$(usex monolithic)
+ $(cmake-utils_use_find_package phonon Phonon4Qt5)
+ -DWANT_CORE=$(usex server)
+ $(cmake-utils_use_find_package snorenotify LibsnoreQt5)
+ -DWITH_WEBKIT=$(usex webkit)
+ -DWANT_QTCLIENT=$(usex X)
+ )
+
+ # Something broke upstream detection since Qt 5.5
+ if use ssl ; then
+ mycmakeargs+=( "-DHAVE_SSL=TRUE" )
+ fi
+
+ cmake-utils_src_configure
+}
+
+src_install() {
+ cmake-utils_src_install
+
+ if use server ; then
+ # needs PAX marking wrt bug#346255
+ pax-mark m "${ED}/usr/bin/quasselcore"
+
+ # prepare folders in /var/
+ keepdir "${QUASSEL_DIR}"
+ fowners "${QUASSEL_USER}":"${QUASSEL_USER}" "${QUASSEL_DIR}"
+
+ # init scripts & systemd unit
+ newinitd "${FILESDIR}"/quasselcore.init-r1 quasselcore
+ newconfd "${FILESDIR}"/quasselcore.conf-r1 quasselcore
+ systemd_dounit "${FILESDIR}"/quasselcore.service
+
+ # logrotate
+ insinto /etc/logrotate.d
+ newins "${FILESDIR}/quassel.logrotate" quassel
+ fi
+}
+
+pkg_postinst() {
+ if use monolithic && use ssl ; then
+ elog "Information on how to enable SSL support for client/core connections"
+ elog "is available at http://bugs.quassel-irc.org/projects/quassel-irc/wiki/Client-Core_SSL_support."
+ fi
+
+ if use server; then
+ einfo "If you want to generate SSL certificate remember to run:"
+ einfo " emerge --config =${CATEGORY}/${PF}"
+ fi
+
+ if use server || use monolithic ; then
+ einfo "Quassel can use net-misc/oidentd package if installed on your system."
+ einfo "Consider installing it if you want to run quassel within identd daemon."
+ fi
+
+ gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+ gnome2_icon_cache_update
+}
+
+pkg_config() {
+ if use server && use ssl; then
+ # generate the pem file only when it does not already exist
+ if [ ! -f "${QUASSEL_DIR}/quasselCert.pem" ]; then
+ einfo "Generating QUASSEL SSL certificate to: \"${QUASSEL_DIR}/quasselCert.pem\""
+ openssl req -x509 -nodes -days 365 -newkey rsa:2048 \
+ -keyout "${QUASSEL_DIR}/quasselCert.pem" \
+ -out "${QUASSEL_DIR}/quasselCert.pem"
+ # permissions for the key
+ chown ${QUASSEL_USER}:${QUASSEL_USER} "${QUASSEL_DIR}/quasselCert.pem"
+ chmod 400 "${QUASSEL_DIR}/quasselCert.pem"
+ else
+ einfo "Certificate \"${QUASSEL_DIR}/quasselCert.pem\" already exists."
+ einfo "Remove it if you want to create new one."
+ fi
+ fi
+}