summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAndreas Sturmlechner <asturm@gentoo.org>2017-12-10 00:33:44 +0100
committerAndreas Sturmlechner <asturm@gentoo.org>2017-12-10 00:51:59 +0100
commitb87dec3c2c5646b2690bb5c82f4f5736f29c5d01 (patch)
treef2b86e1ba41c54824e9bea9400d005b75de581cc
parentsci-physics: Update Manifest hashes. (diff)
downloadgentoo-b87dec3c2c5646b2690bb5c82f4f5736f29c5d01.tar.gz
gentoo-b87dec3c2c5646b2690bb5c82f4f5736f29c5d01.tar.bz2
gentoo-b87dec3c2c5646b2690bb5c82f4f5736f29c5d01.zip
dev-vcs/tortoisehg: Switch to Qt5
Bug: https://bugs.gentoo.org/634976 Package-Manager: Portage-2.3.17, Repoman-2.3.6
-rw-r--r--dev-vcs/tortoisehg/tortoisehg-4.4.1-r1.ebuild79
1 files changed, 79 insertions, 0 deletions
diff --git a/dev-vcs/tortoisehg/tortoisehg-4.4.1-r1.ebuild b/dev-vcs/tortoisehg/tortoisehg-4.4.1-r1.ebuild
new file mode 100644
index 00000000000..10ea4192888
--- /dev/null
+++ b/dev-vcs/tortoisehg/tortoisehg-4.4.1-r1.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1 eutils
+
+if [[ ${PV} != *9999* ]]; then
+ KEYWORDS="~amd64 ~x86"
+ SRC_URI="https://www.bitbucket.org/${PN}/targz/downloads/${P}.tar.gz"
+ HG_DEPEND=">=dev-vcs/mercurial-4.3 <dev-vcs/mercurial-4.5"
+else
+ inherit mercurial
+ EHG_REPO_URI="https://bitbucket.org/tortoisehg/thg"
+ EHG_REVISION="stable"
+ HG_DEPEND="dev-vcs/mercurial"
+fi
+
+DESCRIPTION="Set of graphical tools for Mercurial"
+HOMEPAGE="https://tortoisehg.bitbucket.io/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="doc"
+
+RDEPEND="${HG_DEPEND}
+ dev-python/iniparse[${PYTHON_USEDEP}]
+ dev-python/pygments[${PYTHON_USEDEP}]
+ dev-python/PyQt5[svg,${PYTHON_USEDEP}]
+ >=dev-python/qscintilla-python-2.9.4:=[qt5(+),${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+ doc? ( >=dev-python/sphinx-1.0.3 )"
+
+# Workaround race condition in build_qt
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_prepare_all() {
+ if [[ ${LINGUAS+set} ]]; then
+ cd i18n/tortoisehg || die
+ local x y keep
+ for x in *.po; do
+ keep=false
+ for y in ${LINGUAS}; do
+ if [[ ${y} == ${x%.po}* ]]; then
+ keep=true
+ break
+ fi
+ done
+ ${keep} || rm "${x}" || die
+ done
+ cd "${S}" || die
+ fi
+ distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+ use doc && emake -C doc html
+}
+
+python_install_all() {
+ distutils-r1_python_install_all
+ dodoc doc/ReadMe*.txt doc/TODO contrib/mergetools.rc
+ if use doc ; then
+ dohtml -r doc/build/html/
+ fi
+ newicon -s scalable icons/scalable/apps/thg.svg thg_logo.svg
+ domenu contrib/thg.desktop
+
+ # Remove file that collides with >=mercurial-4.0 (bug #599266).
+ rm "${ED}"/usr/$(get_libdir)/${EPYTHON}/site-packages/hgext3rd/__init__.py \
+ || die
+}
+
+pkg_postinst() {
+ elog "When startup of ${PN} fails with an API version mismatch error"
+ elog "between dev-python/sip and dev-python/PyQt5 please rebuild"
+ elog "dev-python/qscintilla-python."
+}