summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorMarco Scardovi <marco@scardovi.com>2022-01-15 21:10:03 +0100
committerJakov Smolić <jsmolic@gentoo.org>2022-01-17 16:07:52 +0100
commitb94b2e74ac6995dd71878af8a21959dcd8e86818 (patch)
tree98d320117f341fee52e92cb538c7cb1d8ac7a1e6
parentdev-python/tzlocal: Keyword 4.1 for ~m68k (diff)
downloadgentoo-b94b2e74ac6995dd71878af8a21959dcd8e86818.tar.gz
gentoo-b94b2e74ac6995dd71878af8a21959dcd8e86818.tar.bz2
gentoo-b94b2e74ac6995dd71878af8a21959dcd8e86818.zip
sci-libs/silo: revbump to -r1 and add test again
See https://github.com/LLNL/Silo/issues/236 for test Closes: https://bugs.gentoo.org/656432 Closes: https://bugs.gentoo.org/718702 Closes: https://bugs.gentoo.org/741741 Package-Manager: Portage-3.0.30, Repoman-3.0.3 Signed-off-by: Marco Scardovi <marco@scardovi.com> Signed-off-by: Jakov Smolić <jsmolic@gentoo.org>
-rw-r--r--sci-libs/silo/silo-4.11-r1.ebuild53
1 files changed, 53 insertions, 0 deletions
diff --git a/sci-libs/silo/silo-4.11-r1.ebuild b/sci-libs/silo/silo-4.11-r1.ebuild
new file mode 100644
index 00000000000..f4c780ba2a3
--- /dev/null
+++ b/sci-libs/silo/silo-4.11-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic fortran-2
+
+DESCRIPTION="A mesh and field I/O library and scientific database"
+HOMEPAGE="https://wci.llnl.gov/simulation/computer-codes/silo"
+SRC_URI="https://wci.llnl.gov/sites/wci/files/2021-09/${P}-bsd.tgz"
+S="${WORKDIR}/${P}-bsd"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="browser +hdf5 +silex"
+
+# see bugs 656432 and 741741
+RDEPEND="
+ dev-qt/qtcore:5
+ dev-qt/qtgui:5
+ dev-qt/qtwidgets:5
+ net-dialup/lrzsz
+ virtual/szip
+ hdf5? ( sci-libs/hdf5 )
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+ "${FILESDIR}"/${P}-hdf5.patch
+ "${FILESDIR}"/${P}-test-disable-largefile.patch
+ "${FILESDIR}"/${P}-tests.patch
+ "${FILESDIR}"/${P}-testsuite-python-write.patch
+)
+
+src_configure() {
+ # add fflags for fixing test bug on matf77.f
+ # see https://github.com/LLNL/Silo/issues/234
+ append-fflags $(test-flags-F77 -fallow-argument-mismatch)
+
+ econf \
+ --enable-install-lite-headers \
+ --enable-shared \
+ $(use_enable silex silex ) \
+ $(use_enable browser browser ) \
+ $(use_with hdf5 hdf5 "${EPREFIX}"/usr/include,"${EPREFIX}"/usr/$(get_libdir) )
+}
+
+src_test() {
+ # see https://github.com/LLNL/Silo/issues/236
+ # some tests are skipped by default so we are gonna drop them directly
+ emake ATARGS="1-34 36-44 50-51 66-76 78-81" -C tests check
+}