summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorArfrever Frehtes Taifersar Arahesis <Arfrever@Apache.Org>2018-06-08 04:44:57 +0200
committerMike Gilbert <floppym@gentoo.org>2018-06-13 10:36:20 -0400
commitb9ccc946c815cd7c710577cc48e2979400f33318 (patch)
tree53002e94d7e229a942a1521c3ba3693a9c105e6a
parentnet-irc/kvirc: Use EAPI="6". (diff)
downloadgentoo-b9ccc946c815cd7c710577cc48e2979400f33318.tar.gz
gentoo-b9ccc946c815cd7c710577cc48e2979400f33318.tar.bz2
gentoo-b9ccc946c815cd7c710577cc48e2979400f33318.zip
net-irc/kvirc: Version bump (5.0_pre20180605072059).
-rw-r--r--net-irc/kvirc/Manifest1
-rw-r--r--net-irc/kvirc/kvirc-5.0_pre20180605072059.ebuild148
2 files changed, 149 insertions, 0 deletions
diff --git a/net-irc/kvirc/Manifest b/net-irc/kvirc/Manifest
index 57a1b4e07ab..d831b116a4e 100644
--- a/net-irc/kvirc/Manifest
+++ b/net-irc/kvirc/Manifest
@@ -1 +1,2 @@
DIST kvirc-5.0_pre20180401054732.tar.gz 6040980 BLAKE2B fa023ef84f5c84e92b11ed043be0a2e52316fc92f206c41bcb7216760e0473e13e118398445137aeafd657c856cdccfa2f5202f9534904771d8a049d5139f41a SHA512 6d3a9bb06018e2d54369139bbf0a768d3c4e39754b908c1e4294c79707c8b5b751141ae10bdf8456465bd9bf6e4e426a91bc6bef5a1c3563bf32adecc10582eb
+DIST kvirc-5.0_pre20180605072059.tar.gz 6048634 BLAKE2B db2a7a5ff0fa10a1eea6f011b6ea83301d434b08ba3ee61656ddd136ca027c8ce57a2565b491a69f6f1dff138e984ba76f81dc30ed25b6a0e54bb27821448f05 SHA512 f0da384990fc4a9cdf2727abdcc68cfc9c35e925379635acf02e91dc7d83d5ed584798a3d6ac41d259724993b48a67f8bfdae5e0a8d869f0189fbec3c6a652cf
diff --git a/net-irc/kvirc/kvirc-5.0_pre20180605072059.ebuild b/net-irc/kvirc/kvirc-5.0_pre20180605072059.ebuild
new file mode 100644
index 00000000000..cf4358a57af
--- /dev/null
+++ b/net-irc/kvirc/kvirc-5.0_pre20180605072059.ebuild
@@ -0,0 +1,148 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+PYTHON_COMPAT=(python2_7)
+
+inherit cmake-utils flag-o-matic gnome2-utils python-single-r1 xdg-utils
+
+if [[ "${PV}" == "9999" ]]; then
+ inherit git-r3
+
+ EGIT_REPO_URI="https://github.com/kvirc/KVIrc"
+ KVIRC_GIT_REVISION=""
+ KVIRC_GIT_SOURCES_DATE=""
+else
+ inherit vcs-snapshot
+
+ KVIRC_GIT_REVISION="8db61929facd9bfed245752c538b51d0242c3e2e"
+ KVIRC_GIT_SOURCES_DATE="${PV#*_pre}"
+ KVIRC_GIT_SOURCES_DATE="${KVIRC_GIT_SOURCES_DATE:0:4}-${KVIRC_GIT_SOURCES_DATE:4:2}-${KVIRC_GIT_SOURCES_DATE:6:2}"
+fi
+
+DESCRIPTION="Advanced IRC Client"
+HOMEPAGE="http://www.kvirc.net/ https://github.com/kvirc/KVIrc"
+if [[ "${PV}" == "9999" ]]; then
+ SRC_URI=""
+else
+ SRC_URI="https://github.com/kvirc/KVIrc/archive/${KVIRC_GIT_REVISION}.tar.gz -> ${P}.tar.gz"
+fi
+
+LICENSE="kvirc"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="audiofile +dbus dcc_video debug doc gsm kde +nls oss +perl +phonon profile +python spell +ssl theora webkit"
+REQUIRED_USE="audiofile? ( oss ) python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="dev-qt/qtcore:5
+ dev-qt/qtgui:5
+ dev-qt/qtmultimedia:5
+ dev-qt/qtnetwork:5
+ dev-qt/qtprintsupport:5
+ dev-qt/qtsql:5
+ dev-qt/qtwidgets:5
+ dev-qt/qtx11extras:5
+ dev-qt/qtxml:5
+ sys-libs/zlib:0=
+ x11-libs/libX11
+ x11-libs/libXScrnSaver
+ audiofile? ( media-libs/audiofile )
+ dbus? ( dev-qt/qtdbus:5 )
+ dcc_video? ( dev-qt/qtmultimedia:5[widgets] )
+ kde? (
+ kde-frameworks/kcoreaddons:5
+ kde-frameworks/ki18n:5
+ kde-frameworks/knotifications:5
+ kde-frameworks/kservice:5
+ kde-frameworks/kwindowsystem:5
+ kde-frameworks/kxmlgui:5
+ )
+ perl? ( dev-lang/perl:0= )
+ phonon? ( media-libs/phonon[qt5(+)] )
+ python? ( ${PYTHON_DEPS} )
+ spell? ( app-text/enchant:0= )
+ ssl? ( dev-libs/openssl:0= )
+ theora? (
+ media-libs/libogg
+ media-libs/libtheora
+ media-libs/libvorbis
+ )
+ webkit? ( dev-qt/qtwebkit:5 )"
+DEPEND="${RDEPEND}
+ virtual/pkgconfig
+ doc? ( app-doc/doxygen )
+ kde? ( kde-frameworks/extra-cmake-modules:5 )
+ nls? ( sys-devel/gettext )"
+RDEPEND="${RDEPEND}
+ gsm? ( media-sound/gsm )"
+
+DOCS=()
+
+pkg_setup() {
+ if use python; then
+ python-single-r1_pkg_setup
+ fi
+}
+
+src_prepare() {
+ cmake-utils_src_prepare
+
+ if [[ "${PV}" == "9999" ]]; then
+ KVIRC_GIT_REVISION="$(git show -s --format=%H)"
+ KVIRC_GIT_SOURCES_DATE="$(git show -s --format=%cd --date=short)"
+ fi
+ einfo "Setting of revision number to ${KVIRC_GIT_REVISION} ${KVIRC_GIT_SOURCES_DATE}"
+ sed -e "/#define KVI_DEFAULT_FRAME_CAPTION/s/KVI_VERSION/& \" (${KVIRC_GIT_REVISION} ${KVIRC_GIT_SOURCES_DATE})\"/" -i src/kvirc/ui/KviMainWindow.cpp || die "Setting of revision number failed"
+}
+
+src_configure() {
+ append-flags -fno-strict-aliasing
+
+ local libdir="$(get_libdir)"
+ local mycmakeargs=(
+ -DLIB_SUFFIX=${libdir#lib}
+ -DMANUAL_REVISION=${KVIRC_GIT_REVISION}
+ -DMANUAL_SOURCES_DATE=${KVIRC_GIT_SOURCES_DATE//-/}
+ -DWANT_ENV_FLAGS=yes
+ -DWANT_VERBOSE=yes
+
+ -DWANT_CRYPT=yes
+ -DWANT_DCC_VOICE=yes
+ -DWANT_IPC=yes
+ -DWANT_IPV6=yes
+ -DWANT_TRANSPARENCY=yes
+
+ -DWANT_AUDIOFILE=$(usex audiofile)
+ -DWANT_DCC_VIDEO=$(usex dcc_video)
+ -DWANT_DEBUG=$(usex debug)
+ -DWANT_DOXYGEN=$(usex doc)
+ -DWANT_GETTEXT=$(usex nls)
+ -DWANT_GSM=$(usex gsm)
+ -DWANT_KDE=$(usex kde)
+ -DWANT_MEMORY_PROFILE=$(usex profile)
+ -DWANT_OGG_THEORA=$(usex theora)
+ -DWANT_OPENSSL=$(usex ssl)
+ -DWANT_OSS=$(usex oss)
+ -DWANT_PERL=$(usex perl)
+ -DWANT_PHONON=$(usex phonon)
+ -DWANT_PYTHON=$(usex python)
+ -DWANT_QTDBUS=$(usex dbus)
+ -DWANT_QTWEBKIT=$(usex webkit)
+ -DWANT_SPELLCHECKER=$(usex spell)
+
+ # COMPILE_SVG_SUPPORT not used in source code.
+ -DWANT_QTSVG=no
+ )
+
+ cmake-utils_src_configure
+}
+
+pkg_postinst() {
+ gnome2_icon_cache_update
+ xdg_desktop_database_update
+}
+
+pkg_postrm() {
+ gnome2_icon_cache_update
+ xdg_desktop_database_update
+}