net-vpn/networkmanager-sstp: add 1.3.1

Closes: https://bugs.gentoo.org/904845
Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 89 insertions, 0 deletions

diff --git a/net-vpn/networkmanager-sstp/Manifest b/net-vpn/networkmanager-sstp/Manifest
index bf82371c62e3..a738245b131b 100644
--- a/net-vpn/networkmanager-sstp/Manifest
+++ b/net-vpn/networkmanager-sstp/Manifest
@@ -1 +1,3 @@
 DIST NetworkManager-sstp-1.3.0.tar.bz2 548907 BLAKE2B 97248268a781033bc960f930c5a55102e9fa76efa4be6477ffd277fd334649625b6c88418f00d678afa4412fb088cd201ef6711ef6f48b516daaa38fac02caa9 SHA512 9a26c737601990b913d9506ecaac957c4f6d2a4c64a3a0eb8beaf93eaef797ed134b2ddfe2421006a7ffe0dbd18800d49501836f3671f798132a1df707da138a
+DIST NetworkManager-sstp-1.3.1.tar.xz 508392 BLAKE2B 1ead40fa9c8f5bb48b8f7d6d7f6593812849cc26778c531c17a247f60969dbb8d72f477057e4ec7ec838425c3bd21a922b1a65235b72da0bee813f75540a928b SHA512 10247931a2b951b1126a6d7b9bd396fe2eab58d575888c409430f311baeaab85468f23a6c5b6afb7bef90bf73d1e2dbc2f5750cfb126dd365db23b3f79dd7ca6
+DIST networkmanager-sstp-1.3.1-ppp-2.5.0-patches.tar.xz 6792 BLAKE2B 58470f9e04be67029ad57cb2bddb3c80dd503ac5bfc2916683e7d6b4a9332aedb58883bc364a2317c31a8d871888662dbf6431c92753b6fd20b6ae873e45d96e SHA512 ee41eb9aba27e457ba5a8cba9ba27a98991f33750b8202c42ce8be2227bd6c1491bf8861b9e05cc1b3f97ea1bf93d60f5b5f83db3eefbed82ef8aff104ecba95
diff --git a/net-vpn/networkmanager-sstp/networkmanager-sstp-1.3.1.ebuild b/net-vpn/networkmanager-sstp/networkmanager-sstp-1.3.1.ebuild
new file mode 100644
index 000000000000..298583848ed7
--- /dev/null
+++ b/net-vpn/networkmanager-sstp/networkmanager-sstp-1.3.1.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN="NetworkManager-sstp"
+MY_P="${MY_PN}-${PV}"
+
+inherit autotools
+
+DESCRIPTION="Client for the proprietary Microsoft Secure Socket Tunneling Protocol(SSTP)"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/network-manager-sstp https://sourceforge.net/projects/sstp-client/"
+SRC_URI="https://gitlab.gnome.org/GNOME/network-manager-sstp/-/releases/release-${PV}/downloads/dist/${MY_P}.tar.xz"
+SRC_URI+=" https://dev.gentoo.org/~sam/distfiles/${CATEGORY}/${PN}/${P}-ppp-2.5.0-patches.tar.xz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gui gtk4"
+
+# As of 1.3.0, if want GUI support, GTK 3 is always needed, even with GTK 4.
+# atk/graphene/harfbuzz/cairo/gdk-pixbuf/pango are all standard "dragged in by gtk/glib"
+# deps.
+RDEPEND=">=dev-libs/glib-2.32:2
+	net-misc/sstp-client
+	>=net-misc/networkmanager-1.1.0
+	net-dialup/ppp:=
+	net-libs/gnutls:=
+	gui? (
+		>=net-libs/libnma-1.2.0
+		>=app-crypt/libsecret-0.18
+		>=x11-libs/gtk+-3.4:3
+
+		gtk4? (
+			dev-libs/atk
+			media-libs/graphene
+			media-libs/harfbuzz:=
+			x11-libs/cairo
+			x11-libs/gdk-pixbuf:2
+			x11-libs/pango
+
+			gui-libs/gtk:4
+		)
+	)"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/gdbus-codegen
+	sys-apps/file
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${WORKDIR}"/${P}-ppp-2.5.0-patches
+)
+
+src_prepare() {
+	default
+
+	# Bug #741108
+	sed -i 's|/appdata|/metainfo|g' Makefile.{in,am} || die
+
+	eautoreconf
+}
+
+src_configure() {
+	local PPPD_VER="$(best_version net-dialup/ppp)"
+	# Reduce it to ${PV}-${PR}
+	PPPD_VER=${PPPD_VER#*/*-}
+	# Main version without beta/pre/patch/revision
+	PPPD_VER=${PPPD_VER%%[_-]*}
+
+	econf \
+		--disable-more-warnings \
+		--with-dist-version=Gentoo \
+		--with-pppd-plugin-dir="${EPREFIX}/usr/$(get_libdir)/pppd/${PPPD_VER}" \
+		$(use_with gui gnome) \
+		$(use_with gtk4) \
+		--without-libnm-glib
+}
+
+src_install() {
+	default
+
+	find "${ED}" -type f -name '*.la' -delete || die
+}