summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorNP-Hardass <NP-Hardass@gentoo.org>2017-04-07 02:21:39 -0400
committerNP-Hardass <NP-Hardass@gentoo.org>2017-04-10 13:21:41 -0400
commitc5df9eb77cfebf99930f846ad59140f2693680c6 (patch)
tree441481604cba0a360cd38607ac827fec03ffe40f
parentgames-puzzle/sgt-puzzles: Drop old (diff)
downloadgentoo-c5df9eb77cfebf99930f846ad59140f2693680c6.tar.gz
gentoo-c5df9eb77cfebf99930f846ad59140f2693680c6.tar.bz2
gentoo-c5df9eb77cfebf99930f846ad59140f2693680c6.zip
games-puzzle/sgt-puzzles: Bump to 20170314
Package-Manager: Portage-2.3.3, Repoman-2.3.1
-rw-r--r--games-puzzle/sgt-puzzles/Manifest1
-rw-r--r--games-puzzle/sgt-puzzles/files/sgt-puzzles.menu5
-rw-r--r--games-puzzle/sgt-puzzles/sgt-puzzles-20170314.ebuild113
-rw-r--r--games-puzzle/sgt-puzzles/sgt-puzzles-99999999.ebuild4
4 files changed, 120 insertions, 3 deletions
diff --git a/games-puzzle/sgt-puzzles/Manifest b/games-puzzle/sgt-puzzles/Manifest
index 67721e6b50c..2359e3454b5 100644
--- a/games-puzzle/sgt-puzzles/Manifest
+++ b/games-puzzle/sgt-puzzles/Manifest
@@ -1,2 +1,3 @@
DIST puzzles-20170228.1f613ba.tar.gz 2898117 SHA256 e53bf0800daae37c9be25fd260b0010a44178ca7a5ccc70b29b96fe85060d80a SHA512 41d73461984c589ed18ca2a8cab3871e87a1b56b2d38a8b11c0cb95150423cecbf5ddb76a2e9db4b9109980576527ae2fa7d2663e41dceee8847efc0044766b2 WHIRLPOOL 482c88b96d97878708771ccb6aacd38de527787e0a2ca9c6ba16ef48f917d0f269022530e849cfbc5ec74a04753f0aea42dd20a76a24bbd804566b1c07131e88
+DIST puzzles-20170314.eedea41.tar.gz 2897824 SHA256 57c156fa7de2605a4ae0f18e54ce20ef4e08b8faf32d26eccf5a7fa545940fa8 SHA512 ef7d12e0e20aef487a18b572a4464f3e23b226fae599cc22fdb34348f6c3baf3dcd21207c8fedef0ac3a6c4344b13e520767efef8830aaa2ad4b914285f8aa3c WHIRLPOOL 17b069ae171497212411ed6696fafd00108064f3a28ce38925a4fc6d9040e3d072a14920b024c329e597fe1fdedc9723089ea5c17d7df9226ac45ba612a1de70
DIST sgt-puzzles-icons-20160315.tar.xz 715536 SHA256 9ddc1b6d02b3c3358a9bc6b17c7070650f794cf5f650f25b2ac7e5def6674447 SHA512 2fe2c02984eb8c36ac6fb4195be7895b336b84f40ce8baeb23dc8a32aca9937ccf1d33050b4da3cfba3c87e124ecbdd940ee4e990b37eabe8e2af897c2e23b57 WHIRLPOOL 17bdadc9519320bc88af27f2db7a9c243f04d80e524db51ad9398831185e2c66f2430006c324fa7d5b70ce156cb9df93d9405216053b32101b5f56035a60f6ac
diff --git a/games-puzzle/sgt-puzzles/files/sgt-puzzles.menu b/games-puzzle/sgt-puzzles/files/sgt-puzzles.menu
index ddcb2df5b6a..e3f3264cff9 100644
--- a/games-puzzle/sgt-puzzles/files/sgt-puzzles.menu
+++ b/games-puzzle/sgt-puzzles/files/sgt-puzzles.menu
@@ -4,13 +4,16 @@
<Name>Applications</Name>
<Menu>
<Name>Games</Name>
+ <Exclude>
+ <Category>X-sgt-puzzles</Category>
+ </Exclude>
<Menu>
<Name>Puzzles</Name>
<Directory>sgt-puzzles.directory</Directory>
<Include>
<And>
<All></All>
- <Category>sgt-puzzles</Category>
+ <Category>X-sgt-puzzles</Category>
</And>
</Include>
</Menu> <!-- End Puzzles -->
diff --git a/games-puzzle/sgt-puzzles/sgt-puzzles-20170314.ebuild b/games-puzzle/sgt-puzzles/sgt-puzzles-20170314.ebuild
new file mode 100644
index 00000000000..824c7f94307
--- /dev/null
+++ b/games-puzzle/sgt-puzzles/sgt-puzzles-20170314.ebuild
@@ -0,0 +1,113 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils gnome2-utils toolchain-funcs autotools
+
+if [[ ${PV} == "99999999" ]] ; then
+ inherit git-r3
+ EGIT_REPO_URI="git://git.tartarus.org/simon/puzzles.git"
+ GENTOO_ICONS="20160315"
+ SRC_URI="https://dev.gentoo.org/~np-hardass/distfiles/${PN}/${PN}-icons-${GENTOO_ICONS}.tar.xz"
+ KEYWORDS=""
+else
+ MAGIC=eedea41
+ SRC_URI="http://www.chiark.greenend.org.uk/~sgtatham/puzzles/puzzles-${PV}.${MAGIC}.tar.gz"
+ S=${WORKDIR}/puzzles-${PV}.${MAGIC}
+ KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Simon Tatham's Portable Puzzle Collection"
+HOMEPAGE="http://www.chiark.greenend.org.uk/~sgtatham/puzzles/"
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="+doc gtk3"
+
+COMMON_DEPEND="
+ !gtk3? ( x11-libs/gtk+:2 )
+ gtk3? ( x11-libs/gtk+:3 )"
+
+RDEPEND="${COMMON_DEPEND}
+ x11-misc/xdg-utils" # Used by builtin help patch
+
+DEPEND="${COMMON_DEPEND}
+ dev-lang/perl
+ virtual/pkgconfig
+ doc? ( >=app-doc/halibut-1.0 )"
+
+PATCHES=( "${FILESDIR}/${PN}-20161207-builtin-help.patch" )
+
+src_unpack() {
+ default
+ if [[ ${PV} == "99999999" ]]; then
+ git-r3_src_unpack
+ fi
+}
+
+src_prepare() {
+ default
+
+ sed -i \
+ -e 's/-O2 -Wall -Werror -ansi -pedantic -g//' \
+ -e "s/libstr =/libstr = '\$(LDFLAGS) ' ./" \
+ mkfiles.pl || die
+ ./mkfiles.pl || die
+ eautoreconf
+
+ # Import icons from latest Gentoo tarball for live
+ if [[ ${PV} == "99999999" ]]; then
+ cp -R ../${PN}-icons/icons . || die
+ fi
+}
+
+src_configure() {
+ econf \
+ --program-prefix="${PN}_" \
+ --with-gtk=$(usex gtk3 3 2)
+}
+
+src_compile() {
+ emake CC="$(tc-getCC)"
+ if use doc ; then
+ halibut --text --html --info --pdf --ps puzzles.but || die
+ fi
+}
+
+src_install() {
+ default
+
+ local file name
+ for file in *.R ; do
+ [[ ${file} == "nullgame.R" ]] && continue
+ name=$(awk -F: '/exe:/ { print $3 }' "${file}")
+ file=${file%.R}
+ newicon -s 48 icons/${file}-48d24.png ${PN}_${file}.png
+ make_desktop_entry "${PN}_${file}" "${name}" "${PN}_${file}" "Game;LogicGame;X-${PN};"
+ done
+
+ if use doc ; then
+ DOCS=( puzzles.{pdf,ps,txt} )
+ HTML_DOCS=( *.html )
+ einstalldocs
+ doinfo puzzles.info{,-1,-2,-3}
+ fi
+
+ insinto /etc/xdg/menus/applications-merged
+ doins "${FILESDIR}/${PN}.menu"
+ insinto /usr/share/desktop-directories
+ doins "${FILESDIR}/${PN}.directory"
+}
+
+pkg_preinst() {
+ gnome2_icon_savelist
+}
+
+pkg_postinst() {
+ gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+ gnome2_icon_cache_update
+}
diff --git a/games-puzzle/sgt-puzzles/sgt-puzzles-99999999.ebuild b/games-puzzle/sgt-puzzles/sgt-puzzles-99999999.ebuild
index d67926d4458..824c7f94307 100644
--- a/games-puzzle/sgt-puzzles/sgt-puzzles-99999999.ebuild
+++ b/games-puzzle/sgt-puzzles/sgt-puzzles-99999999.ebuild
@@ -12,7 +12,7 @@ if [[ ${PV} == "99999999" ]] ; then
SRC_URI="https://dev.gentoo.org/~np-hardass/distfiles/${PN}/${PN}-icons-${GENTOO_ICONS}.tar.xz"
KEYWORDS=""
else
- MAGIC=1f613ba
+ MAGIC=eedea41
SRC_URI="http://www.chiark.greenend.org.uk/~sgtatham/puzzles/puzzles-${PV}.${MAGIC}.tar.gz"
S=${WORKDIR}/puzzles-${PV}.${MAGIC}
KEYWORDS="~amd64 ~x86"
@@ -84,7 +84,7 @@ src_install() {
name=$(awk -F: '/exe:/ { print $3 }' "${file}")
file=${file%.R}
newicon -s 48 icons/${file}-48d24.png ${PN}_${file}.png
- make_desktop_entry "${PN}_${file}" "${name}" "${PN}_${file}" "Game;LogicGame;${PN};"
+ make_desktop_entry "${PN}_${file}" "${name}" "${PN}_${file}" "Game;LogicGame;X-${PN};"
done
if use doc ; then