summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorMichał Górny <mgorny@gentoo.org>2022-11-24 14:54:20 +0100
committerMichał Górny <mgorny@gentoo.org>2022-11-24 15:31:26 +0100
commitd52a08278ecd3aa41ffbafba6f80ad163abb7d10 (patch)
treee33564ff5bcd793f7349f1531f43bb4f6a8c9d7d
parentdev-libs/xalan-c: drop 1.12 (diff)
downloadgentoo-d52a08278ecd3aa41ffbafba6f80ad163abb7d10.tar.gz
gentoo-d52a08278ecd3aa41ffbafba6f80ad163abb7d10.tar.bz2
gentoo-d52a08278ecd3aa41ffbafba6f80ad163abb7d10.zip
dev-python/setuptools: Bump to 65.6.3
Signed-off-by: Michał Górny <mgorny@gentoo.org>
-rw-r--r--dev-python/setuptools/Manifest1
-rw-r--r--dev-python/setuptools/setuptools-65.6.3.ebuild129
2 files changed, 130 insertions, 0 deletions
diff --git a/dev-python/setuptools/Manifest b/dev-python/setuptools/Manifest
index f203dfc6e7b..f28596eb370 100644
--- a/dev-python/setuptools/Manifest
+++ b/dev-python/setuptools/Manifest
@@ -2,3 +2,4 @@ DIST setuptools-65.5.1.tar.gz 2616576 BLAKE2B 84ecb833305e06861d4e0ab5377235f6a5
DIST setuptools-65.6.0.tar.gz 2616763 BLAKE2B 76b02b8b1fb07632c8934be568337b859c24cbb6680683608c8cce5c5ba2fd5c782c7ec120712ce76ebfc00108ebfd52b9297ef3197248ee34f90a239f81d953 SHA512 2896a00f47dbc7b1661facb2b96a97349b96e5cf0d86b63cd9dcc0e190b73d0440c77d1c54b63618103ac426292ef0f27c2de1103de9004bdf7415c21b24cf7a
DIST setuptools-65.6.1.tar.gz 2617393 BLAKE2B d9d3218805a6c5d45147f3041547dc6c25a219e7b1d272ce3b6b059cdff773a45a02e16bae3dc1dd34339f04526880f7558377cd192fd096a7b496d451e6c519 SHA512 7358d9742486d4feef343ba2eebb45d40fe32eea6146d4b60d21d11f282a6c52d38b963cee25daae22c8414dcd6d56f8c567af3e3a8dabe128358361f8ed8270
DIST setuptools-65.6.2.tar.gz 2617459 BLAKE2B ecc53616bd730a49ec606b43315a8244edf7f78ba44a471bead6836183374ea9bd27def15b0f552ce5fdb64f2968a711f8a0806469b5f36f36ead9b7a68030b3 SHA512 f8f905e7cdf05f63c54bd6ebd6a1c3bb0911f7b2c00f8d0c4be454299d3c19f69baf1b12cff845c5789244b2f87ee7a777640a02d22e4e11d1b3ffe707d8c71c
+DIST setuptools-65.6.3.tar.gz 2617699 BLAKE2B 0b64efcb5280f18e9d5660a10bca34d9864255279e4747cad99e3adf99ee33c0d174f0b61ef897894e7083ecfbaea16d59a195e3572c8083a4a8d811fe0c2702 SHA512 d0acfdc838454ffedabc4cc14c745071e07cc05e0a598c8bf83824788a8630d5516009e81213ae2a709f54298e754bd391cad205e7111363b64c853bd124aef3
diff --git a/dev-python/setuptools/setuptools-65.6.3.ebuild b/dev-python/setuptools/setuptools-65.6.3.ebuild
new file mode 100644
index 00000000000..84081a4a8ab
--- /dev/null
+++ b/dev-python/setuptools/setuptools-65.6.3.ebuild
@@ -0,0 +1,129 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 7 -- sys-apps/portage dep
+EAPI=7
+
+# please bump dev-python/ensurepip-setuptools along with this package!
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_TESTED=( python3_{8..11} pypy3 )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="Collection of extensions to Distutils"
+HOMEPAGE="
+ https://github.com/pypa/setuptools/
+ https://pypi.org/project/setuptools/
+"
+SRC_URI="
+ mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos ~x64-solaris"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ >=dev-python/appdirs-1.4.4-r2[${PYTHON_USEDEP}]
+ >=dev-python/jaraco-text-3.7.0-r1[${PYTHON_USEDEP}]
+ >=dev-python/more-itertools-8.12.0-r1[${PYTHON_USEDEP}]
+ >=dev-python/nspektr-0.3.0[${PYTHON_USEDEP}]
+ >=dev-python/ordered-set-4.0.2-r1[${PYTHON_USEDEP}]
+ >=dev-python/packaging-21.3-r2[${PYTHON_USEDEP}]
+ >=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ >=dev-python/importlib_metadata-4.11.1[${PYTHON_USEDEP}]
+ ' 3.8 3.9)
+ $(python_gen_cond_dep '
+ >=dev-python/importlib_resources-5.4.0-r3[${PYTHON_USEDEP}]
+ ' 3.8)
+"
+BDEPEND="
+ ${RDEPEND}
+ >=dev-python/wheel-0.37.1-r1[${PYTHON_USEDEP}]
+ test? (
+ $(python_gen_cond_dep '
+ dev-python/build[${PYTHON_USEDEP}]
+ >=dev-python/ini2toml-0.9[${PYTHON_USEDEP}]
+ >=dev-python/filelock-3.4.0[${PYTHON_USEDEP}]
+ >=dev-python/jaraco-envs-2.2[${PYTHON_USEDEP}]
+ >=dev-python/jaraco-path-3.2.0[${PYTHON_USEDEP}]
+ dev-python/pip[${PYTHON_USEDEP}]
+ dev-python/pip-run[${PYTHON_USEDEP}]
+ dev-python/pytest[${PYTHON_USEDEP}]
+ dev-python/pytest-fixture-config[${PYTHON_USEDEP}]
+ dev-python/pytest-timeout[${PYTHON_USEDEP}]
+ dev-python/pytest-virtualenv[${PYTHON_USEDEP}]
+ dev-python/pytest-xdist[${PYTHON_USEDEP}]
+ >=dev-python/tomli-w-1.0.0[${PYTHON_USEDEP}]
+ >=dev-python/virtualenv-20[${PYTHON_USEDEP}]
+ dev-python/wheel[${PYTHON_USEDEP}]
+ ' "${PYTHON_TESTED[@]}")
+ )
+"
+PDEPEND="
+ >=dev-python/certifi-2016.9.26[${PYTHON_USEDEP}]
+ dev-python/setuptools_scm[${PYTHON_USEDEP}]
+"
+
+DOCS=( {CHANGES,README}.rst )
+
+src_prepare() {
+ local PATCHES=(
+ # TODO: remove this when we're 100% PEP517 mode
+ "${FILESDIR}"/setuptools-62.4.0-py-compile.patch
+ )
+
+ # remove bundled dependencies, setuptools will switch to system deps
+ # automatically
+ rm -r */_vendor || die
+
+ # remove the ugly */extern hack that breaks on unvendored deps
+ rm -r */extern || die
+ find -name '*.py' -exec sed \
+ -e 's:from \w*[.]\+extern ::' -e 's:\w*[.]\+extern[.]::' \
+ -i {} + || die
+
+ distutils-r1_src_prepare
+
+ export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+}
+
+python_test() {
+ local -x SETUPTOOLS_USE_DISTUTILS=stdlib
+
+ if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
+ return
+ fi
+
+ local EPYTEST_DESELECT=(
+ # network
+ # TODO: see if PRE_BUILT_SETUPTOOLS_* helps
+ setuptools/tests/config/test_apply_pyprojecttoml.py::test_apply_pyproject_equivalent_to_setupcfg
+ setuptools/tests/integration/test_pip_install_sdist.py::test_install_sdist
+ setuptools/tests/test_build_meta.py::test_legacy_editable_install
+ setuptools/tests/test_distutils_adoption.py
+ setuptools/tests/test_editable_install.py
+ setuptools/tests/test_setuptools.py::test_its_own_wheel_does_not_contain_tests
+ setuptools/tests/test_virtualenv.py::test_clean_env_install
+ setuptools/tests/test_virtualenv.py::test_no_missing_dependencies
+ setuptools/tests/test_virtualenv.py::test_test_command_install_requirements
+ # TODO
+ setuptools/tests/config/test_setupcfg.py::TestConfigurationReader::test_basic
+ setuptools/tests/config/test_setupcfg.py::TestConfigurationReader::test_ignore_errors
+ setuptools/tests/test_extern.py::test_distribution_picklable
+ # expects bundled deps in virtualenv
+ setuptools/tests/config/test_apply_pyprojecttoml.py::TestMeta::test_example_file_in_sdist
+ setuptools/tests/config/test_apply_pyprojecttoml.py::TestMeta::test_example_file_not_in_wheel
+ setuptools/tests/test_editable_install.py::test_editable_with_pyproject
+ # fails if python-xlib is installed
+ setuptools/tests/test_easy_install.py::TestSetupRequires::test_setup_requires_with_allow_hosts
+ )
+
+ epytest -n "$(makeopts_jobs)" setuptools
+}