summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorLouis Sautier <sbraz@gentoo.org>2020-09-05 01:59:31 +0200
committerLouis Sautier <sbraz@gentoo.org>2020-09-05 02:18:53 +0200
commite20b809b1f876fed3dff306e2c0269220611f8f5 (patch)
tree477dd9dc8c9fd154cc590b8a2f55da39642149cb
parentsys-auth/nss-pam-ldapd-0.9.11-r3: EAPI=7, py38 (bug #718520) (diff)
downloadgentoo-e20b809b1f876fed3dff306e2c0269220611f8f5.tar.gz
gentoo-e20b809b1f876fed3dff306e2c0269220611f8f5.tar.bz2
gentoo-e20b809b1f876fed3dff306e2c0269220611f8f5.zip
media-video/gaupol: support Python 3.9, remove dep. on setuptools
Also move dependencies to BDEPEND. Package-Manager: Portage-3.0.3, Repoman-2.3.23 Signed-off-by: Louis Sautier <sbraz@gentoo.org>
-rw-r--r--media-video/gaupol/gaupol-1.8-r2.ebuild68
1 files changed, 68 insertions, 0 deletions
diff --git a/media-video/gaupol/gaupol-1.8-r2.ebuild b/media-video/gaupol/gaupol-1.8-r2.ebuild
new file mode 100644
index 000000000000..e08179fb61d3
--- /dev/null
+++ b/media-video/gaupol/gaupol-1.8-r2.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9} )
+DISTUTILS_USE_SETUPTOOLS=no
+
+inherit distutils-r1 virtualx xdg-utils
+
+DESCRIPTION="A subtitle editor for text-based subtitles"
+HOMEPAGE="https://otsaloma.io/gaupol/"
+SRC_URI="https://github.com/otsaloma/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="spell test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ app-text/iso-codes
+ dev-python/chardet[${PYTHON_USEDEP}]
+ dev-python/pygobject:3[${PYTHON_USEDEP}]
+ x11-libs/gtk+:3[introspection]
+ spell? ( app-text/gspell[introspection] )
+"
+BDEPEND="
+ sys-devel/gettext
+ test? (
+ ${RDEPEND}
+ app-dicts/myspell-en
+ app-text/enchant[hunspell]
+ app-text/gspell[introspection]
+ dev-python/pytest[${PYTHON_USEDEP}]
+ )
+"
+
+DOCS=( AUTHORS.md NEWS.md TODO.md README.md README.aeidon.md )
+
+PATCHES=( "${FILESDIR}/${P}-fix-audio-tracks-order.patch" )
+
+python_test() {
+ virtx pytest -vv
+}
+
+pkg_postinst() {
+ xdg_desktop_database_update
+ xdg_icon_cache_update
+ if [[ -z ${REPLACING_VERSIONS} ]]; then
+ elog "The integrated video player requires media-plugins/gst-plugins-gtk."
+ elog ""
+ elog "External video previewing support requires MPV, MPlayer or VLC."
+ if use spell; then
+ elog ""
+ elog "Spell-checking requires a dictionary, any of app-dicts/myspell-*"
+ elog "or app-text/aspell with the appropriate L10N variable."
+ elog ""
+ elog "Additionally, make sure that app-text/enchant has the correct flags enabled:"
+ elog "USE=hunspell for myspell dictionaries and USE=aspell for aspell dictionaries."
+ fi
+ fi
+}
+
+pkg_postrm() {
+ xdg_desktop_database_update
+ xdg_icon_cache_update
+}